po/CMakeLists.txt

   1 # Generate and add translations
   2 # The LINGUAS variable can be used to limit that set
   3
   4 if(QT_LCONVERT_EXECUTABLE)
   5   # get environment variable for translations
   6   set(LINGUAS "$ENV{LINGUAS}")
   7   string(REGEX REPLACE "[ \t]+" \; output "${LINGUAS}")
   8   # Find more languages
   9   file(GLOB avail_pofiles quassel_*.po qt_*.po)
  10   foreach(PO_FILE ${avail_pofiles})
  11     get_filename_component(basename ${PO_FILE} NAME_WE)
  12     string(REGEX REPLACE "q[^_]+_([a-zA-Z]+)(_.+)?$" "\\1" lang ${basename})
  13     # test if we want this
  14     set(flg 1)
  15     if(LINGUAS)
  16       string(REGEX MATCH "${lang}" flg ${LINGUAS})
  17     endif(LINGUAS)
  18     if(flg)
  19       generate_qm(QM ${basename})
  20       list(APPEND qm_files ${QM})
  21       list(APPEND gen_linguas ${lang})
  22     endif(flg)
  23   endforeach(PO_FILE ${avail_pofiles})
  24   if(gen_linguas)
  25     list(REMOVE_DUPLICATES gen_linguas)
  26   endif(gen_linguas)
  27   message(STATUS "Including languages: ${gen_linguas}")
  28 else(QT_LCONVERT_EXECUTABLE)
  29   message(STATUS "WARNING: lconvert not found, you won't have translations!")
  30 endif(QT_LCONVERT_EXECUTABLE)
  31
  32 # For a static build, we need to include Qt translations if available
  33 if(STATIC AND QT_TRANSLATIONS_DIR)
  34   foreach(LANG ${gen_linguas})
  35     file(GLOB lang_files ${QT_TRANSLATIONS_DIR}/qt_${LANG}*.qm)
  36     foreach(absfile ${lang_files})
  37       get_filename_component(filename ${absfile} NAME)
  38       message(STATUS "Importing ${filename}")
  39       configure_file(${absfile} ${CMAKE_CURRENT_BINARY_DIR}/${filename} COPYONLY)
  40       list(APPEND qm_files ${CMAKE_CURRENT_BINARY_DIR}/${filename})
  41     endforeach(absfile ${lang_files})
  42   endforeach(LANG ${gen_linguas})
  43 endif(STATIC AND QT_TRANSLATIONS_DIR)
  44
  45 # Write resource file
  46 set(resfile ${CMAKE_CURRENT_BINARY_DIR}/i18n.qrc)
  47 file(WRITE ${resfile} "<!DOCTYPE RCC><RCC version=\"1.0\">\n"
  48                       "<qresource prefix=\"/i18n\">\n")
  49 foreach(file ${qm_files})
  50   get_filename_component(file ${file} NAME)
  51   file(APPEND ${resfile} "    <file>${file}</file>\n")
  52 endforeach(file ${qm_files})
  53 file(APPEND ${resfile} "</qresource>\n</RCC>\n")
  54
  55 #add_custom_command(OUTPUT ${resfile} DEPENDS ${qm_files})
  56 set_directory_properties(PROPERTIES ADDITIONAL_MAKE_CLEAN_FILES "${qm_files};i18n.qrc")
  57
  58 if(EMBED_DATA)
  59   set(COMMON_RCS ${COMMON_RCS} ${resfile} PARENT_SCOPE)
  60 else(EMBED_DATA)
  61   install(FILES ${qm_files} DESTINATION ${DATA_INSTALL_DIR}/quassel/translations)
  62 endif(EMBED_DATA)
  63
  64 add_custom_target(po DEPENDS ${qm_files})