i18n/CMakeLists.txt

   1 # Generate and add translations
   2 # The LINGUAS variable can be used to limit that set
   3
   4 if(QT_LRELEASE_EXECUTABLE)
   5   # We always include quassel.ts
   6   generate_qm(QM quassel)
   7   set(qm_files ${QM})
   8
   9   # Find more languages
  10   file(GLOB avail_tsfiles quassel_*.ts)
  11   foreach(TS_FILE ${avail_tsfiles})
  12     get_filename_component(basename ${TS_FILE} NAME_WE)
  13     string(REGEX REPLACE "quassel_(.+)$" "\\1" lang ${basename})
  14     # test if we want this
  15     set(flg 1)
  16     if(LINGUAS)
  17       string(REGEX MATCH "${lang}" flg ${LINGUAS})
  18     endif(LINGUAS)
  19     if(flg)
  20       generate_qm(QM ${basename})
  21       set(qm_files ${qm_files} ${QM})
  22       set(gen_linguas "${gen_linguas} ${lang}")
  23     endif(flg)
  24   endforeach(TS_FILE ${avail_tsfiles})
  25
  26   # Write resource file
  27   set(resfile ${CMAKE_CURRENT_BINARY_DIR}/i18n.qrc)
  28   file(WRITE ${resfile} "<!DOCTYPE RCC><RCC version=\"1.0\">\n"
  29                         "<qresource prefix=\"/i18n\">\n")
  30   foreach(file ${qm_files})
  31     get_filename_component(file ${file} NAME)
  32     file(APPEND ${resfile} "    <file>${file}</file>\n")
  33   endforeach(file ${qm_files})
  34   file(APPEND ${resfile} "</qresource>\n</RCC>\n")
  35   add_custom_command(OUTPUT ${resfile} DEPENDS ${qm_files})
  36   #set_directory_properties(PROPERTIES
  37   #      ADDITIONAL_MAKE_CLEAN_FILES "${outfiles} i18n.qrc")
  38   qt4_add_resources(RC_I18N ${resfile})
  39   add_custom_target(i18n DEPENDS ${RC_I18N})
  40   message(STATUS "Including languages:${gen_linguas}")
  41 else(QT_LRELEASE_EXECUTABLE)
  42   message(STATUS "WARNING: lrelease not found, you won't have translations!")
  43 endif(QT_LRELEASE_EXECUTABLE)