cmake/modules/Qt4ConfigDependentSettings.cmake

   1 # This file is included by FindQt4.cmake, don't include it directly.
   2
   3 #=============================================================================
   4 # Copyright 2005-2009 Kitware, Inc.
   5 #
   6 # Distributed under the OSI-approved BSD License (the "License");
   7 # see accompanying file Copyright.txt for details.
   8 #
   9 # This software is distributed WITHOUT ANY WARRANTY; without even the
  10 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  11 # See the License for more information.
  12 #=============================================================================
  13 # (To distributed this file outside of CMake, substitute the full
  14 #  License text for the above reference.)
  15
  16
  17 ###############################################
  18 #
  19 #       configuration/system dependent settings
  20 #
  21 ###############################################
  22
  23 # this check for X11 and threads may not be necessary, since it is not
  24 # contained in the cmake version of FindQt4.cmake:
  25
  26 # for unix add X11 stuff
  27 IF(UNIX)
  28   # on OS X X11 may not be required
  29   IF (Q_WS_X11)
  30     FIND_PACKAGE(X11 REQUIRED)
  31   ENDIF (Q_WS_X11)
  32   FIND_PACKAGE(Threads)
  33   SET(QT_QTCORE_LIBRARY ${QT_QTCORE_LIBRARY} ${CMAKE_THREAD_LIBS_INIT})
  34 ENDIF(UNIX)
  35
  36
  37 # find dependencies for some Qt modules
  38 # when doing builds against a static Qt, they are required
  39 # when doing builds against a shared Qt, they are not required
  40 # if a user needs the dependencies, and they couldn't be found, they can set
  41 # the variables themselves.
  42
  43 SET(QT_QTGUI_LIB_DEPENDENCIES "")
  44 SET(QT_QTCORE_LIB_DEPENDENCIES "")
  45 SET(QT_QTNETWORK_LIB_DEPENDENCIES "")
  46 SET(QT_QTOPENGL_LIB_DEPENDENCIES "")
  47 SET(QT_QTDBUS_LIB_DEPENDENCIES "")
  48 SET(QT_QTHELP_LIB_DEPENDENCIES ${QT_QTCLUCENE_LIBRARY})
  49
  50
  51 IF(WIN32)
  52   # On Windows, qconfig.pri has "static" for static library builds
  53   IF(QT_CONFIG MATCHES "static")
  54     SET(QT_IS_STATIC 1)
  55   ENDIF(QT_CONFIG MATCHES "static")
  56 ELSE(WIN32)
  57   # On other platforms, check file extension to know if its static
  58   IF(QT_QTCORE_LIBRARY_RELEASE)
  59     GET_FILENAME_COMPONENT(qtcore_lib_ext "${QT_QTCORE_LIBRARY_RELEASE}" EXT)
  60     IF(${qtcore_lib_ext} STREQUAL ${CMAKE_STATIC_LIBRARY_SUFFIX})
  61       SET(QT_IS_STATIC 1)
  62     ENDIF(${qtcore_lib_ext} STREQUAL ${CMAKE_STATIC_LIBRARY_SUFFIX})
  63   ENDIF(QT_QTCORE_LIBRARY_RELEASE)
  64   IF(QT_QTCORE_LIBRARY_DEBUG)
  65     GET_FILENAME_COMPONENT(qtcore_lib_ext "${QT_QTCORE_LIBRARY_DEBUG}" EXT)
  66     IF(${qtcore_lib_ext} STREQUAL ${CMAKE_STATIC_LIBRARY_SUFFIX})
  67       SET(QT_IS_STATIC 1)
  68     ENDIF(${qtcore_lib_ext} STREQUAL ${CMAKE_STATIC_LIBRARY_SUFFIX})
  69   ENDIF(QT_QTCORE_LIBRARY_DEBUG)
  70 ENDIF(WIN32)
  71
  72 # build using shared Qt needs -DQT_DLL on Windows
  73 IF(WIN32  AND  NOT QT_IS_STATIC)
  74   SET(QT_DEFINITIONS ${QT_DEFINITIONS} -DQT_DLL)
  75 ENDIF(WIN32  AND  NOT QT_IS_STATIC)
  76
  77
  78 # QtOpenGL dependencies
  79 QT_QUERY_QMAKE(QMAKE_LIBS_OPENGL "QMAKE_LIBS_OPENGL")
  80 SEPARATE_ARGUMENTS(QMAKE_LIBS_OPENGL)
  81 SET (QT_QTOPENGL_LIB_DEPENDENCIES ${QT_QTOPENGL_LIB_DEPENDENCIES} ${QMAKE_LIBS_OPENGL})
  82
  83
  84 ## system png
  85 IF(QT_QCONFIG MATCHES "system-png")
  86   FIND_LIBRARY(QT_PNG_LIBRARY NAMES png)
  87   MARK_AS_ADVANCED(QT_PNG_LIBRARY)
  88   IF(QT_PNG_LIBRARY)
  89     SET(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} ${QT_PNG_LIBRARY})
  90   ENDIF(QT_PNG_LIBRARY)
  91 ENDIF(QT_QCONFIG MATCHES "system-png")
  92
  93
  94 # for X11, get X11 library directory
  95 IF(Q_WS_X11)
  96   QT_QUERY_QMAKE(QMAKE_LIBDIR_X11 "QMAKE_LIBDIR_X11")
  97 ENDIF(Q_WS_X11)
  98
  99
 100 ## X11 SM
 101 IF(QT_QCONFIG MATCHES "x11sm")
 102   # ask qmake where the x11 libs are
 103   FIND_LIBRARY(QT_X11_SM_LIBRARY NAMES SM PATHS ${QMAKE_LIBDIR_X11})
 104   FIND_LIBRARY(QT_X11_ICE_LIBRARY NAMES ICE PATHS ${QMAKE_LIBDIR_X11})
 105   MARK_AS_ADVANCED(QT_X11_SM_LIBRARY)
 106   MARK_AS_ADVANCED(QT_X11_ICE_LIBRARY)
 107   IF(QT_X11_SM_LIBRARY AND QT_X11_ICE_LIBRARY)
 108     SET(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} ${QT_X11_SM_LIBRARY} ${QT_X11_ICE_LIBRARY})
 109   ENDIF(QT_X11_SM_LIBRARY AND QT_X11_ICE_LIBRARY)
 110 ENDIF(QT_QCONFIG MATCHES "x11sm")
 111
 112
 113 ## Xi
 114 IF(QT_QCONFIG MATCHES "tablet")
 115   FIND_LIBRARY(QT_XI_LIBRARY NAMES Xi PATHS ${QMAKE_LIBDIR_X11})
 116   MARK_AS_ADVANCED(QT_XI_LIBRARY)
 117   IF(QT_XI_LIBRARY)
 118     SET(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} ${QT_XI_LIBRARY})
 119   ENDIF(QT_XI_LIBRARY)
 120 ENDIF(QT_QCONFIG MATCHES "tablet")
 121
 122
 123 ## Xrender
 124 IF(QT_QCONFIG MATCHES "xrender")
 125   FIND_LIBRARY(QT_XRENDER_LIBRARY NAMES Xrender PATHS ${QMAKE_LIBDIR_X11})
 126   MARK_AS_ADVANCED(QT_XRENDER_LIBRARY)
 127   IF(QT_XRENDER_LIBRARY)
 128     SET(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} ${QT_XRENDER_LIBRARY})
 129   ENDIF(QT_XRENDER_LIBRARY)
 130 ENDIF(QT_QCONFIG MATCHES "xrender")
 131
 132
 133 ## Xrandr
 134 IF(QT_QCONFIG MATCHES "xrandr")
 135   FIND_LIBRARY(QT_XRANDR_LIBRARY NAMES Xrandr PATHS ${QMAKE_LIBDIR_X11})
 136   MARK_AS_ADVANCED(QT_XRANDR_LIBRARY)
 137   IF(QT_XRANDR_LIBRARY)
 138     SET(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} ${QT_XRANDR_LIBRARY})
 139   ENDIF(QT_XRANDR_LIBRARY)
 140 ENDIF(QT_QCONFIG MATCHES "xrandr")
 141
 142
 143 ## Xcursor
 144 IF(QT_QCONFIG MATCHES "xcursor")
 145   FIND_LIBRARY(QT_XCURSOR_LIBRARY NAMES Xcursor PATHS ${QMAKE_LIBDIR_X11})
 146   MARK_AS_ADVANCED(QT_XCURSOR_LIBRARY)
 147   IF(QT_XCURSOR_LIBRARY)
 148     SET(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} ${QT_XCURSOR_LIBRARY})
 149   ENDIF(QT_XCURSOR_LIBRARY)
 150 ENDIF(QT_QCONFIG MATCHES "xcursor")
 151
 152
 153 ## Xinerama
 154 IF(QT_QCONFIG MATCHES "xinerama")
 155   FIND_LIBRARY(QT_XINERAMA_LIBRARY NAMES Xinerama PATHS ${QMAKE_LIBDIR_X11})
 156   MARK_AS_ADVANCED(QT_XINERAMA_LIBRARY)
 157   IF(QT_XINERAMA_LIBRARY)
 158     SET(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} ${QT_XINERAMA_LIBRARY})
 159   ENDIF(QT_XINERAMA_LIBRARY)
 160 ENDIF(QT_QCONFIG MATCHES "xinerama")
 161
 162
 163 ## Xfixes
 164 IF(QT_QCONFIG MATCHES "xfixes")
 165   FIND_LIBRARY(QT_XFIXES_LIBRARY NAMES Xfixes PATHS ${QMAKE_LIBDIR_X11})
 166   MARK_AS_ADVANCED(QT_XFIXES_LIBRARY)
 167   IF(QT_XFIXES_LIBRARY)
 168     SET(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} ${QT_XFIXES_LIBRARY})
 169   ENDIF(QT_XFIXES_LIBRARY)
 170 ENDIF(QT_QCONFIG MATCHES "xfixes")
 171
 172
 173 ## system-freetype
 174 IF(QT_QCONFIG MATCHES "system-freetype")
 175   FIND_LIBRARY(QT_FREETYPE_LIBRARY NAMES freetype)
 176   MARK_AS_ADVANCED(QT_FREETYPE_LIBRARY)
 177   IF(QT_FREETYPE_LIBRARY)
 178     SET(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} ${QT_FREETYPE_LIBRARY})
 179   ENDIF(QT_FREETYPE_LIBRARY)
 180 ENDIF(QT_QCONFIG MATCHES "system-freetype")
 181
 182
 183 ## fontconfig
 184 IF(QT_QCONFIG MATCHES "fontconfig")
 185   FIND_LIBRARY(QT_FONTCONFIG_LIBRARY NAMES fontconfig)
 186   MARK_AS_ADVANCED(QT_FONTCONFIG_LIBRARY)
 187   IF(QT_FONTCONFIG_LIBRARY)
 188     SET(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} ${QT_FONTCONFIG_LIBRARY})
 189   ENDIF(QT_FONTCONFIG_LIBRARY)
 190 ENDIF(QT_QCONFIG MATCHES "fontconfig")
 191
 192
 193 ## system-zlib
 194 IF(QT_QCONFIG MATCHES "system-zlib")
 195   FIND_LIBRARY(QT_ZLIB_LIBRARY NAMES z)
 196   MARK_AS_ADVANCED(QT_ZLIB_LIBRARY)
 197   IF(QT_ZLIB_LIBRARY)
 198     SET(QT_QTCORE_LIB_DEPENDENCIES ${QT_QTCORE_LIB_DEPENDENCIES} ${QT_ZLIB_LIBRARY})
 199   ENDIF(QT_ZLIB_LIBRARY)
 200 ENDIF(QT_QCONFIG MATCHES "system-zlib")
 201
 202
 203 ## openssl
 204 IF(NOT Q_WS_WIN)
 205   SET(_QT_NEED_OPENSSL 0)
 206   IF(QT_VERSION_MINOR LESS 4 AND QT_QCONFIG MATCHES "openssl")
 207     SET(_QT_NEED_OPENSSL 1)
 208   ENDIF(QT_VERSION_MINOR LESS 4 AND QT_QCONFIG MATCHES "openssl")
 209   IF(QT_VERSION_MINOR GREATER 3 AND QT_QCONFIG MATCHES "openssl-linked")
 210     SET(_QT_NEED_OPENSSL 1)
 211   ENDIF(QT_VERSION_MINOR GREATER 3 AND QT_QCONFIG MATCHES "openssl-linked")
 212   IF(_QT_NEED_OPENSSL)
 213     FIND_PACKAGE(OpenSSL)
 214     IF(OPENSSL_LIBRARIES)
 215       SET(QT_QTNETWORK_LIB_DEPENDENCIES ${QT_QTNETWORK_LIB_DEPENDENCIES} ${OPENSSL_LIBRARIES})
 216     ENDIF(OPENSSL_LIBRARIES)
 217   ENDIF(_QT_NEED_OPENSSL)
 218 ENDIF(NOT Q_WS_WIN)
 219
 220 ## dbus
 221 IF(QT_QCONFIG MATCHES "dbus")
 222
 223   # if the dbus library isn't found, we'll assume its not required to build
 224   # shared Qt on Linux doesn't require it
 225   IF(NOT QT_DBUS_LIBRARY)
 226     EXECUTE_PROCESS(COMMAND pkg-config --libs-only-L dbus-1
 227       OUTPUT_VARIABLE _dbus_query_output
 228       RESULT_VARIABLE _dbus_result
 229       ERROR_VARIABLE _dbus_query_output )
 230
 231     IF(_dbus_result MATCHES 0)
 232       STRING(REPLACE "-L" "" _dbus_query_output "${_dbus_query_output}")
 233       SEPARATE_ARGUMENTS(_dbus_query_output)
 234     ELSE(_dbus_result MATCHES 0)
 235       SET(_dbus_query_output)
 236     ENDIF(_dbus_result MATCHES 0)
 237
 238     FIND_LIBRARY(QT_DBUS_LIBRARY NAMES dbus-1 PATHS ${_dbus_query_output} )
 239
 240     IF(QT_DBUS_LIBRARY)
 241       SET(QT_QTDBUS_LIB_DEPENDENCIES ${QT_QTDBUS_LIB_DEPENDENCIES} ${QT_DBUS_LIBRARY})
 242     ENDIF(QT_DBUS_LIBRARY)
 243
 244     MARK_AS_ADVANCED(QT_DBUS_LIBRARY)
 245   ENDIF(NOT QT_DBUS_LIBRARY)
 246
 247 ENDIF(QT_QCONFIG MATCHES "dbus")
 248
 249
 250 ## glib
 251 IF(QT_QCONFIG MATCHES "glib")
 252
 253   # if the glib libraries aren't found, we'll assume its not required to build
 254   # shared Qt on Linux doesn't require it
 255
 256   # Qt 4.2.0+ uses glib-2.0
 257   IF(NOT QT_GLIB_LIBRARY OR NOT QT_GTHREAD_LIBRARY)
 258     EXECUTE_PROCESS(COMMAND pkg-config --libs-only-L glib-2.0 gthread-2.0
 259       OUTPUT_VARIABLE _glib_query_output
 260       RESULT_VARIABLE _glib_result
 261       ERROR_VARIABLE _glib_query_output )
 262
 263     IF(_glib_result MATCHES 0)
 264       STRING(REPLACE "-L" "" _glib_query_output "${_glib_query_output}")
 265       SEPARATE_ARGUMENTS(_glib_query_output)
 266     ELSE(_glib_result MATCHES 0)
 267       SET(_glib_query_output)
 268     ENDIF(_glib_result MATCHES 0)
 269
 270     FIND_LIBRARY(QT_GLIB_LIBRARY NAMES glib-2.0 PATHS ${_glib_query_output} )
 271     FIND_LIBRARY(QT_GTHREAD_LIBRARY NAMES gthread-2.0 PATHS ${_glib_query_output} )
 272
 273     MARK_AS_ADVANCED(QT_GLIB_LIBRARY)
 274     MARK_AS_ADVANCED(QT_GTHREAD_LIBRARY)
 275   ENDIF(NOT QT_GLIB_LIBRARY OR NOT QT_GTHREAD_LIBRARY)
 276
 277   IF(QT_GLIB_LIBRARY AND QT_GTHREAD_LIBRARY)
 278     SET(QT_QTCORE_LIB_DEPENDENCIES ${QT_QTCORE_LIB_DEPENDENCIES}
 279         ${QT_GTHREAD_LIBRARY} ${QT_GLIB_LIBRARY})
 280   ENDIF(QT_GLIB_LIBRARY AND QT_GTHREAD_LIBRARY)
 281
 282
 283   # Qt 4.5+ also links to gobject-2.0
 284   IF(QT_VERSION_MINOR GREATER 4)
 285      IF(NOT QT_GOBJECT_LIBRARY)
 286        EXECUTE_PROCESS(COMMAND pkg-config --libs-only-L gobject-2.0
 287          OUTPUT_VARIABLE _glib_query_output
 288          RESULT_VARIABLE _glib_result
 289          ERROR_VARIABLE _glib_query_output )
 290
 291        IF(_glib_result MATCHES 0)
 292          STRING(REPLACE "-L" "" _glib_query_output "${_glib_query_output}")
 293          SEPARATE_ARGUMENTS(_glib_query_output)
 294        ELSE(_glib_result MATCHES 0)
 295          SET(_glib_query_output)
 296        ENDIF(_glib_result MATCHES 0)
 297
 298        FIND_LIBRARY(QT_GOBJECT_LIBRARY NAMES gobject-2.0 PATHS ${_glib_query_output} )
 299
 300        MARK_AS_ADVANCED(QT_GOBJECT_LIBRARY)
 301      ENDIF(NOT QT_GOBJECT_LIBRARY)
 302
 303      IF(QT_GOBJECT_LIBRARY)
 304        SET(QT_QTCORE_LIB_DEPENDENCIES ${QT_QTCORE_LIB_DEPENDENCIES}
 305            ${QT_GOBJECT_LIBRARY})
 306      ENDIF(QT_GOBJECT_LIBRARY)
 307   ENDIF(QT_VERSION_MINOR GREATER 4)
 308
 309 ENDIF(QT_QCONFIG MATCHES "glib")
 310
 311
 312 ## clock-monotonic, just see if we need to link with rt
 313 IF(QT_QCONFIG MATCHES "clock-monotonic")
 314   SET(CMAKE_REQUIRED_LIBRARIES_SAVE ${CMAKE_REQUIRED_LIBRARIES})
 315   SET(CMAKE_REQUIRED_LIBRARIES rt)
 316   CHECK_SYMBOL_EXISTS(_POSIX_TIMERS "unistd.h;time.h" QT_POSIX_TIMERS)
 317   SET(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES_SAVE})
 318   IF(QT_POSIX_TIMERS)
 319     FIND_LIBRARY(QT_RT_LIBRARY NAMES rt)
 320     MARK_AS_ADVANCED(QT_RT_LIBRARY)
 321     IF(QT_RT_LIBRARY)
 322       SET(QT_QTCORE_LIB_DEPENDENCIES ${QT_QTCORE_LIB_DEPENDENCIES} ${QT_RT_LIBRARY})
 323     ENDIF(QT_RT_LIBRARY)
 324   ENDIF(QT_POSIX_TIMERS)
 325 ENDIF(QT_QCONFIG MATCHES "clock-monotonic")
 326
 327
 328 IF(Q_WS_X11)
 329   # X11 libraries Qt absolutely depends on
 330   QT_QUERY_QMAKE(QT_LIBS_X11 "QMAKE_LIBS_X11")
 331   SEPARATE_ARGUMENTS(QT_LIBS_X11)
 332   FOREACH(QT_X11_LIB ${QT_LIBS_X11})
 333     STRING(REGEX REPLACE "-l" "" QT_X11_LIB "${QT_X11_LIB}")
 334     SET(QT_TMP_STR "QT_X11_${QT_X11_LIB}_LIBRARY")
 335     FIND_LIBRARY(${QT_TMP_STR} NAMES "${QT_X11_LIB}" PATHS ${QMAKE_LIBDIR_X11})
 336     MARK_AS_ADVANCED(${QT_TMP_STR})
 337     IF(${QT_TMP_STR})
 338       SET(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} ${${QT_TMP_STR}})
 339     ENDIF(${QT_TMP_STR})
 340   ENDFOREACH(QT_X11_LIB)
 341
 342   QT_QUERY_QMAKE(QT_LIBS_THREAD "QMAKE_LIBS_THREAD")
 343   SET(QT_QTCORE_LIB_DEPENDENCIES ${QT_QTCORE_LIB_DEPENDENCIES} ${QT_LIBS_THREAD})
 344
 345   QT_QUERY_QMAKE(QMAKE_LIBS_DYNLOAD "QMAKE_LIBS_DYNLOAD")
 346   SET (QT_QTCORE_LIB_DEPENDENCIES ${QT_QTCORE_LIB_DEPENDENCIES} ${QMAKE_LIBS_DYNLOAD})
 347
 348 ENDIF(Q_WS_X11)
 349
 350
 351 IF(Q_WS_WIN)
 352   SET(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} imm32 winmm)
 353   SET(QT_QTCORE_LIB_DEPENDENCIES ${QT_QTCORE_LIB_DEPENDENCIES} ws2_32)
 354 ENDIF(Q_WS_WIN)
 355
 356
 357 IF(Q_WS_MAC)
 358   SET(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} "-framework Carbon")
 359
 360   # Qt 4.0, 4.1, 4.2 use QuickTime
 361   IF(QT_VERSION_MINOR LESS 3)
 362     SET(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} "-framework QuickTime")
 363   ENDIF(QT_VERSION_MINOR LESS 3)
 364
 365   # Qt 4.2+ use AppKit
 366   IF(QT_VERSION_MINOR GREATER 1)
 367     SET(QT_QTGUI_LIB_DEPENDENCIES ${QT_QTGUI_LIB_DEPENDENCIES} "-framework AppKit")
 368   ENDIF(QT_VERSION_MINOR GREATER 1)
 369
 370   SET(QT_QTCORE_LIB_DEPENDENCIES ${QT_QTCORE_LIB_DEPENDENCIES} "-framework ApplicationServices")
 371 ENDIF(Q_WS_MAC)
 372