cmake/QuasselCompileSettings.cmake

   1 # This file contains compile flags and general build configuration for Quassel
   2 #
   3 # (C) 2014-2018 by the Quassel Project <devel@quassel-irc.org>
   4 #
   5 # Redistribution and use is allowed according to the terms of the BSD license.
   6 # For details see the accompanying COPYING-CMAKE-SCRIPTS file.
   7
   8 include(QuasselMacros)
   9
  10 # Helper function to check for linker flag support
  11 include(CheckCXXCompilerFlag)
  12 function(check_and_set_linker_flag flag name outvar)
  13     cmake_push_check_state(RESET)
  14     set(CMAKE_REQUIRED_FLAGS "${flag}")
  15     check_cxx_compiler_flag("" LINKER_SUPPORTS_${name})
  16     if (LINKER_SUPPORTS_${name})
  17         set(${outvar} "${${outvar}} ${flag}" PARENT_SCOPE)
  18     endif()
  19     cmake_pop_check_state()
  20 endfunction()
  21
  22 # General compile settings
  23 set(CMAKE_CXX_STANDARD 14)
  24 set(CMAKE_CXX_STANDARD_REQUIRED OFF)    # Rely on compile features if standard is not supported
  25 set(CMAKE_CXX_EXTENSIONS OFF)           # We like to be standard conform
  26
  27 set(CMAKE_CXX_VISIBILITY_PRESET hidden)
  28 set(CMAKE_VISIBILITY_INLINES_HIDDEN ON)
  29 set(CMAKE_POSITION_INDEPENDENT_CODE ON)
  30
  31 # For GCC and Clang, enable a whole bunch of warnings
  32 if (CMAKE_CXX_COMPILER_ID MATCHES "GNU|Clang")
  33     add_compile_options(
  34         -fdiagnostics-color=always
  35         -fexceptions
  36         -fno-common
  37         -fstack-protector-strong
  38         -Wall
  39         -Wextra
  40         -Wcast-align
  41         -Wformat-security
  42         -Wnon-virtual-dtor
  43         -Woverloaded-virtual
  44         -Wpedantic
  45         -Wundef
  46         -Wvla
  47         -Werror=return-type
  48         -Wno-unknown-pragmas
  49         "$<$<NOT:$<CONFIG:Debug>>:-U_FORTIFY_SOURCE;-D_FORTIFY_SOURCE=2>"
  50     )
  51
  52     # Check for and set linker flags
  53     check_and_set_linker_flag("-Wl,-z,relro"            RELRO            LINKER_FLAGS)
  54     check_and_set_linker_flag("-Wl,-z,now"              NOW              LINKER_FLAGS)
  55     check_and_set_linker_flag("-Wl,--as-needed"         AS_NEEDED        LINKER_FLAGS)
  56     check_and_set_linker_flag("-Wl,--enable-new-dtags"  ENABLE_NEW_DTAGS LINKER_FLAGS)
  57     check_and_set_linker_flag("-Wl,--no-undefined"      NO_UNDEFINED     LINKER_FLAGS)
  58
  59     set(CMAKE_EXE_LINKER_FLAGS    "${LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
  60     set(CMAKE_MODULE_LINKER_FLAGS "${LINKER_FLAGS} ${CMAKE_MODULE_LINKER_FLAGS}")
  61     set(CMAKE_SHARED_LINKER_FLAGS "${LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
  62
  63 elseif(MSVC)
  64     # Target Windows Vista
  65     add_definitions(-D_WIN32_WINNT=0x0600 -DWINVER=0x0600 -D_WIN32_IE=0x0600)
  66
  67     # Various settings for the Windows API
  68     add_definitions(-DWIN32_LEAN_AND_MEAN -DUNICODE -D_UNICODE -D_USE_MATH_DEFINES -DNOMINMAX)
  69
  70     # Compile options
  71     add_compile_options(/EHsc)
  72
  73     # Increase warning level on MSVC
  74     # CMake puts /W3 in CMAKE_CXX_FLAGS which will be appended later, so we need to replace
  75     message(STATUS "CXX ${CMAKE_CXX_FLAGS} REL ${CMAKE_CXX_FLAGS_RELEASE} DEB ${CMAKE_CXX_FLAGS_DEBUG}")
  76     string(REPLACE "/W3" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
  77
  78     # Silence annoying/useless warnings
  79     #   C4127: conditional expression is constant
  80     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4127")
  81     #   C4244: 'identifier': conversion from 't1' to 't2', possible loss of data
  82     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4244")
  83     #   C4456: declaration of 'identifier' hides previous local declaration
  84     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4456")
  85     #   C4458: declaration of 'identifier' hides class member
  86     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4458")
  87
  88     # Link against the correct version of the C runtime
  89     set(CMAKE_EXE_LINKER_FLAGS_RELEASE "/NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt ${CMAKE_EXE_LINKER_FLAGS_RELEASE}")
  90     set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "/NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt ${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO}")
  91     set(CMAKE_EXE_LINKER_FLAGS_MINSIZEREL "/NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt ${CMAKE_EXE_LINKER_FLAGS_MINSIZEREL}")
  92     set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/NODEFAULTLIB:libcmtd /DEFAULTLIB:msvcrtd ${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
  93
  94 else()
  95     # For other compilers, we rely on default settings (unless someone provides a good set of options; patches welcome!)
  96     message(WARNING "${CMAKE_CXX_COMPILER_ID} is not a supported C++ compiler.")
  97 endif()
  98
  99 # Mac build stuff
 100 if (APPLE)
 101     set(CMAKE_OSX_ARCHITECTURES "x86_64")
 102     add_compile_options(
 103         -mmacosx-version-min=10.9
 104         -stdlib=libc++
 105     )
 106     add_definitions(-DQT_MAC_USE_COCOA -D_DARWIN_C_SOURCE)
 107 endif()
 108
 109 # Optionally, produce clazy warnings
 110 if(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 111     option(ENABLE_CLAZY "Enable Clazy warnings" OFF)
 112
 113     if(ENABLE_CLAZY)
 114         set(CMAKE_CXX_COMPILE_OBJECT "${CMAKE_CXX_COMPILE_OBJECT} -Xclang -load -Xclang ClangLazy${CMAKE_SHARED_LIBRARY_SUFFIX} -Xclang -add-plugin -Xclang clang-lazy")
 115     endif()
 116 endif()
 117
 118 # Append CMAKE_CXX_FLAGS, so our flags can be overwritten externally.
 119 process_cmake_cxx_flags()