cmake/QuasselCompileSettings.cmake

   1 # This file contains compile flags and general build configuration for Quassel
   2 #
   3 # (C) 2014-2018 by the Quassel Project <devel@quassel-irc.org>
   4 #
   5 # Redistribution and use is allowed according to the terms of the BSD license.
   6 # For details see the accompanying COPYING-CMAKE-SCRIPTS file.
   7
   8 include(QuasselMacros)
   9
  10 # Helper function to check for linker flag support
  11 include(CheckCXXCompilerFlag)
  12 function(check_and_set_linker_flag flag name outvar)
  13     cmake_push_check_state(RESET)
  14     set(CMAKE_REQUIRED_FLAGS "${flag}")
  15     check_cxx_compiler_flag("" LINKER_SUPPORTS_${name})
  16     if (LINKER_SUPPORTS_${name})
  17         set(${outvar} "${${outvar}} ${flag}" PARENT_SCOPE)
  18     endif()
  19     cmake_pop_check_state()
  20 endfunction()
  21
  22 # General compile settings
  23 set(CMAKE_CXX_STANDARD 14)
  24 set(CMAKE_CXX_STANDARD_REQUIRED OFF)    # Rely on compile features if standard is not supported
  25 set(CMAKE_CXX_EXTENSIONS OFF)           # We like to be standard conform
  26
  27 set(CMAKE_CXX_VISIBILITY_PRESET hidden)
  28 set(CMAKE_VISIBILITY_INLINES_HIDDEN ON)
  29 set(CMAKE_POSITION_INDEPENDENT_CODE ON)
  30
  31 # For GCC and Clang, enable a whole bunch of warnings
  32 if (CMAKE_CXX_COMPILER_ID MATCHES "GNU|Clang")
  33     add_compile_options(
  34         -fdiagnostics-color=always
  35         -fexceptions
  36         -fno-common
  37         -fstack-protector-strong
  38         -Wall
  39         -Wextra
  40         -Wcast-align
  41         -Wformat-security
  42         -Wnon-virtual-dtor
  43         -Woverloaded-virtual
  44         -Wpedantic
  45         -Wundef
  46         -Wvla
  47         -Werror=return-type
  48         -Wno-unknown-pragmas
  49         "$<$<NOT:$<CONFIG:Debug>>:-U_FORTIFY_SOURCE;-D_FORTIFY_SOURCE=2>"
  50     )
  51
  52     # Check for and set linker flags
  53     check_and_set_linker_flag("-Wl,-z,relro"            RELRO            LINKER_FLAGS)
  54     check_and_set_linker_flag("-Wl,-z,now"              NOW              LINKER_FLAGS)
  55     check_and_set_linker_flag("-Wl,--as-needed"         AS_NEEDED        LINKER_FLAGS)
  56     check_and_set_linker_flag("-Wl,--enable-new-dtags"  ENABLE_NEW_DTAGS LINKER_FLAGS)
  57     check_and_set_linker_flag("-Wl,--no-undefined"      NO_UNDEFINED     LINKER_FLAGS)
  58
  59     set(CMAKE_EXE_LINKER_FLAGS    "${LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
  60     set(CMAKE_MODULE_LINKER_FLAGS "${LINKER_FLAGS} ${CMAKE_MODULE_LINKER_FLAGS}")
  61     set(CMAKE_SHARED_LINKER_FLAGS "${LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
  62
  63 elseif(MSVC)
  64     # Target Windows Vista
  65     add_definitions(-D_WIN32_WINNT=0x0600 -DWINVER=0x0600 -D_WIN32_IE=0x0600)
  66
  67     # Various settings for the Windows API
  68     add_definitions(-DWIN32_LEAN_AND_MEAN -DUNICODE -D_UNICODE -D_USE_MATH_DEFINES -DNOMINMAX)
  69
  70     # Compile options
  71     add_compile_options(-EHsc -W3)
  72
  73     # Link against the correct version of the C runtime
  74     set(CMAKE_EXE_LINKER_FLAGS_RELEASE "/NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt ${CMAKE_EXE_LINKER_FLAGS_RELEASE}")
  75     set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "/NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt ${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO}")
  76     set(CMAKE_EXE_LINKER_FLAGS_MINSIZEREL "/NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt ${CMAKE_EXE_LINKER_FLAGS_MINSIZEREL}")
  77     set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/NODEFAULTLIB:libcmtd /DEFAULTLIB:msvcrtd ${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
  78
  79 else()
  80     # For other compilers, we rely on default settings (unless someone provides a good set of options; patches welcome!)
  81     message(WARNING "${CMAKE_CXX_COMPILER_ID} is not a supported C++ compiler.")
  82 endif()
  83
  84 # Mac build stuff
  85 if (APPLE)
  86     set(CMAKE_OSX_ARCHITECTURES "x86_64")
  87     add_compile_options(
  88         -mmacosx-version-min=10.9
  89         -stdlib=libc++
  90     )
  91     add_definitions(-DQT_MAC_USE_COCOA -D_DARWIN_C_SOURCE)
  92 endif()
  93
  94 # Optionally, produce clazy warnings
  95 if(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
  96     option(ENABLE_CLAZY "Enable Clazy warnings" OFF)
  97
  98     if(ENABLE_CLAZY)
  99         set(CMAKE_CXX_COMPILE_OBJECT "${CMAKE_CXX_COMPILE_OBJECT} -Xclang -load -Xclang ClangLazy${CMAKE_SHARED_LIBRARY_SUFFIX} -Xclang -add-plugin -Xclang clang-lazy")
 100     endif()
 101 endif()
 102
 103 # Append CMAKE_CXX_FLAGS, so our flags can be overwritten externally.
 104 process_cmake_cxx_flags()