build/modules/module.pri

   1 TEMPLATE = lib
   2 CONFIG += staticlib
   3
   4 SRCPATH = ../../src  # Path to sources relative to this file
   5
   6 # Set paths according to MODULE
   7 # We need to handle MODULE definitions like contrib/foo
   8
   9 MODNAME = $$basename(MODULE)
  10 MODPATH_PREFIX = $$dirname(MODULE)
  11 !isEmpty(MODPATH_PREFIX) {
  12   MODPATH_PREFIX ~= s,[^/]+,..
  13   #sprintf($$MODPATH_PREFIX%1
  14   SRCPATH = $$MODPATH_PREFIX/$$SRCPATH
  15 }
  16
  17 MODPATH = $$SRCPATH/$$MODULE  # Path to the module files
  18
  19 # Define build directories
  20
  21 OBJECTS_DIR = $${MODNAME}.tmp
  22 MOC_DIR = $${MODNAME}.tmp
  23 UI_DIR = $${MODNAME}.tmp
  24
  25 # Load module settings (files etc.)
  26
  27 include($$MODPATH/$${MODNAME}.pri)
  28
  29 # Define needed Qt modules
  30
  31 QT -= gui
  32 for(qtmod, QT_MOD) {
  33   QT *= $$qtmod
  34 }
  35
  36 # Set includepath for needed Quassel modules
  37
  38 for(dep, DEPMOD) {
  39   INCLUDEPATH *= $$SRCPATH/$$dep
  40 }
  41 INCLUDEPATH *= $$MODPATH  # and don't forget our own dir
  42
  43 # Now prefix all filenames with the correct dirname
  44
  45 for(src, SRCS) {
  46   SOURCES *= $$MODPATH/$$src
  47 }
  48
  49 for(hdr, HDRS) {
  50   HEADERS *= $$MODPATH/$$hdr
  51 }
  52
  53 for(frm, FRMS) {
  54   FORMS *= $$MODPATH/$$frm
  55 }