CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 project(QuasselIRC)
  10
  11 # Versions
  12 set(QUASSEL_MAJOR  0)
  13 set(QUASSEL_MINOR 13)
  14 set(QUASSEL_PATCH  0)
  15 set(QUASSEL_VERSION_STRING "0.13-pre")
  16
  17 # We want to know CMake's version for debug reasons
  18 message(STATUS "Using CMake ${CMAKE_VERSION}")
  19
  20 # Tell CMake about or own modules
  21 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  22
  23 # General conveniences
  24 set(CMAKE_AUTOMOC ON)
  25 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  26
  27 # Include various CMake modules...
  28 include(CMakePushCheckState)
  29 include(CheckFunctionExists)
  30 include(CheckIncludeFile)
  31 include(CheckCXXSourceCompiles)
  32 include(CMakeDependentOption)
  33 include(FeatureSummary)
  34
  35 # ... and our own stuff
  36 include(QuasselCompileSettings)
  37 include(QuasselMacros)
  38
  39
  40 # Options and variables that can be set on the command line
  41 #####################################################################
  42
  43 # First, choose a Qt version. We support USE_QT4 and USE_QT5; if neither is set, prefer Qt4 for now
  44 option(USE_QT5 "Enable support for Qt5 (disables KDE integration)" OFF)
  45 if (USE_QT4) # takes precedence
  46     set(USE_QT5 OFF)
  47 else()
  48     if (NOT USE_QT5)
  49         set(USE_QT4 ON)
  50     endif()
  51 endif()
  52
  53 # Select the binaries to build
  54 option(WANT_CORE     "Build the core (server) binary"           ON)
  55 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  56 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  57 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  58 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  59 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  60
  61 # Whether to enable KDE integration (work in progress for Qt5 / KDE Frameworks)
  62 # Note that when building with Qt5, WITH_KDE enables integration with higher-tier KDE frameworks that
  63 # require runtime support. We still optionally make use of certain Tier 1 frameworks even if WITH_KDE
  64 # is disabled.
  65 if (USE_QT4)
  66     option(WITH_KDE "KDE4 integration" OFF)
  67     add_feature_info(WITH_KDE WITH_KDE "Enable KDE4 integration")
  68 else()
  69     option(WITH_KDE "Integration with the KDE Frameworks runtime environment")
  70     add_feature_info(WITH_KDE WITH_KDE "Integrate with the KDE Frameworks runtime environment")
  71 endif()
  72
  73 cmake_dependent_option(WITH_OXYGEN "Install Oxygen icon set (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
  74 if (NOT WITH_KDE)
  75     add_feature_info(WITH_OXYGEN WITH_OXYGEN "Install Oxygen icon set")
  76 endif()
  77
  78 # For this, the feature info is added after we know if QtWebkit is installed
  79 option(WITH_WEBKIT "WebKit support (for link previews)" ON)
  80
  81 if (APPLE)
  82     # Notification Center is only available in > 10.8, which is Darwin v12
  83     if (CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  84         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
  85         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
  86     endif()
  87 endif()
  88
  89 # Always embed on Windows, OSX or for a static build; never embed when enabling KDE integration
  90 set(EMBED_DEFAULT OFF)
  91 if (STATIC OR WIN32 OR APPLE)
  92     set(EMBED_DEFAULT ON)
  93 endif()
  94 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
  95                                    "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
  96 if (NOT EMBED_DEFAULT)
  97     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
  98 endif()
  99
 100 # The following options are not for end-user consumption, so don't list them in the feature summary
 101 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
 102
 103 # Handle with care
 104 set(QT_PATH "" CACHE PATH "Path to a Qt4 installation to use instead of the system Qt (e.g. for static builds)")
 105
 106 # Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
 107 cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
 108
 109 # For static builds, arbitrary extra libs might need to be linked
 110 # Define a comma-separated list here
 111 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 112 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 113 if (LINK_EXTRA)
 114     string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 115     link_libraries(${LINK_EXTRA})
 116 endif()
 117
 118
 119 # Setup CMake
 120 #####################################################################
 121
 122 if (USE_QT5 AND WITH_KDE)
 123     cmake_minimum_required(VERSION 2.8.12)
 124 else()
 125     cmake_minimum_required(VERSION 2.8.9)
 126 endif()
 127
 128 # Setting COMPILE_DEFINITIONS_<CONFIG> is deprecated since CMake 3.0 in favor of generator expressions.
 129 # These have existed since CMake 2.8.10; until we depend on that, we have to explicitly enable the old policy.
 130 if (CMAKE_MAJOR_VERSION GREATER 2)
 131     cmake_policy(SET CMP0043 OLD)
 132 endif()
 133
 134
 135 # Simplify later checks
 136 #####################################################################
 137
 138 if (WANT_MONO OR WANT_QTCLIENT)
 139     set(BUILD_GUI true)
 140 endif()
 141 if (WANT_MONO OR WANT_CORE)
 142     set(BUILD_CORE true)
 143 endif()
 144
 145
 146 # Set up Qt
 147 #####################################################################
 148
 149 if (USE_QT5)
 150     message(STATUS "Building for Qt5...")
 151     set(QT_MIN_VERSION "5.2.0")
 152     add_definitions(-DHAVE_QT5)
 153 else()
 154     message(STATUS "Building for Qt4...")
 155     set(QT_MIN_VERSION "4.8.0")
 156
 157     # Select a Qt installation here, if you don't want to use system Qt
 158     if(QT_PATH)
 159         # FindQt4 will look for the qmake binary in $PATH, so we just prepend QT_PATH
 160         set(ENV{PATH} ${QT_PATH}/bin:$ENV{PATH})
 161     endif()
 162 endif()
 163
 164
 165 # Find package dependencies
 166 #
 167 # Note that you can forcefully disable optional packages
 168 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 169 #####################################################################
 170
 171 if (USE_QT5)
 172     find_package(Qt5Core ${QT_MIN_VERSION} QUIET)
 173     set_package_properties(Qt5Core PROPERTIES TYPE REQUIRED
 174         URL "http://qt.digia.com"
 175         DESCRIPTION "contains core functionality for Qt"
 176     )
 177     # find_package without REQUIRED won't check for the version properly; also, older Qt5 versions
 178     # used Qt5Core_VERSION_STRING... let's just make sure here that we bail out here if our Qt5 is not new enough.
 179     if (NOT Qt5Core_VERSION OR Qt5Core_VERSION VERSION_LESS ${QT_MIN_VERSION})
 180         message(FATAL_ERROR "Could NOT find Qt5 >= version ${QT_MIN_VERSION}!")
 181     endif()
 182
 183     find_package(Qt5Network QUIET)
 184     set_package_properties(Qt5Network PROPERTIES TYPE REQUIRED
 185         DESCRIPTION "the network module for Qt5"
 186     )
 187
 188     if (BUILD_GUI)
 189         find_package(Qt5Gui QUIET)
 190         set_package_properties(Qt5Gui PROPERTIES TYPE REQUIRED
 191             DESCRIPTION "the GUI module for Qt5"
 192         )
 193         find_package(Qt5Widgets QUIET)
 194         set_package_properties(Qt5Widgets PROPERTIES TYPE REQUIRED
 195             DESCRIPTION "the widgets module for Qt5"
 196         )
 197
 198         find_package(Qt5DBus QUIET)
 199         set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 200             URL "http://qt.digia.com"
 201             DESCRIPTION "D-Bus support for Qt5"
 202             PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 203         )
 204         if (Qt5DBus_FOUND)
 205             find_package(dbusmenu-qt5 QUIET CONFIG)
 206             set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 207                 URL "https://launchpad.net/libdbusmenu-qt"
 208                 DESCRIPTION "a library implementing the DBusMenu specification"
 209                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 210             )
 211         endif()
 212
 213         find_package(Phonon4Qt5 QUIET)
 214         set_package_properties(Phonon4Qt5 PROPERTIES TYPE RECOMMENDED
 215             URL "https://projects.kde.org/projects/kdesupport/phonon"
 216             DESCRIPTION "a multimedia abstraction library"
 217             PURPOSE     "Required for audio notifications"
 218         )
 219
 220         find_package(LibsnoreQt5 0.7.0 QUIET)
 221         set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
 222             URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 223             DESCRIPTION "a cross-platform notification framework"
 224             PURPOSE     "Enable support for the snorenotify framework"
 225         )
 226         if(LibsnoreQt5_FOUND)
 227             find_package(LibsnoreSettingsQt5)
 228             set_package_properties(LibsnoreSettingsQt5 PROPERTIES TYPE REQUIRED
 229                 URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 230                 DESCRIPTION "a cross-platform notification framework"
 231                 PURPOSE     "Enable support for the snorenotify framework"
 232             )
 233         endif()
 234
 235
 236         if (WITH_WEBKIT)
 237             find_package(Qt5WebKit QUIET)
 238             set_package_properties(Qt5WebKit PROPERTIES TYPE RECOMMENDED
 239                 URL "http://qt.digia.com"
 240                 DESCRIPTION "a WebKit implementation for Qt"
 241                 PURPOSE     "Needed for displaying previews for URLs in chat"
 242             )
 243             if (Qt5WebKit_FOUND)
 244                 find_package(Qt5WebKitWidgets QUIET)
 245                 set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE RECOMMENDED
 246                     URL "http://qt.digia.com"
 247                     DESCRIPTION "widgets for Qt's WebKit implementation"
 248                     PURPOSE     "Needed for displaying previews for URLs in chat"
 249                 )
 250             endif()
 251         endif()
 252
 253         if (WITH_WEBKIT AND Qt5WebKitWidgets_FOUND)
 254             set(HAVE_WEBKIT true)
 255         endif()
 256         add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" HAVE_WEBKIT "Support showing previews for URLs in chat")
 257
 258         # KDE Frameworks
 259         ################
 260
 261         if (WITH_KDE)
 262             set(ecm_find_type "REQUIRED")
 263         else()
 264             # Even with KDE integration disabled, we optionally use tier1 frameworks if we find them
 265             set(ecm_find_type "RECOMMENDED")
 266         endif()
 267
 268         # extra-cmake-modules
 269         find_package(ECM NO_MODULE QUIET)
 270         set_package_properties(ECM PROPERTIES TYPE ${ecm_find_type}
 271             URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules"
 272             DESCRIPTION "extra modules for CMake, maintained by the KDE project"
 273             PURPOSE     "Required to find KDE Frameworks components"
 274         )
 275
 276         if (ECM_FOUND)
 277             list(APPEND CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
 278         endif()
 279
 280         if (WITH_KDE)
 281             find_package(KF5 COMPONENTS ConfigWidgets CoreAddons Notifications NotifyConfig TextWidgets WidgetsAddons XmlGui QUIET)
 282             set_package_properties(KF5 PROPERTIES TYPE REQUIRED
 283                 URL "http://www.kde.org"
 284                 DESCRIPTION "KDE Frameworks"
 285                 PURPOSE     "Required for integration into the Plasma desktop"
 286             )
 287
 288         endif()
 289
 290     endif(BUILD_GUI)
 291
 292     if (BUILD_CORE)
 293         find_package(Qt5Script QUIET)
 294         set_package_properties(Qt5Script PROPERTIES TYPE REQUIRED
 295             DESCRIPTION "provides scripting support for Qt5"
 296         )
 297         find_package(Qt5Sql QUIET)
 298         set_package_properties(Qt5Sql PROPERTIES TYPE REQUIRED
 299             DESCRIPTION "the database support module for Qt5"
 300         )
 301
 302         find_package(QCA2-QT5)
 303         set_package_properties(QCA2-QT5 PROPERTIES TYPE RECOMMENDED
 304             URL "https://projects.kde.org/projects/kdesupport/qca"
 305             DESCRIPTION "Qt Cryptographic Architecture"
 306             PURPOSE "Required for encryption support"
 307         )
 308
 309     endif(BUILD_CORE)
 310
 311     find_package(Qt5LinguistTools QUIET)
 312     set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 313                            DESCRIPTION "contains tools for handling translation files"
 314                            PURPOSE "Required for having translations"
 315     )
 316
 317     # Some Qt5 versions do not define a target for lconvert, so we need to find it ourselves
 318     if (Qt5LinguistTools_FOUND)
 319         if (NOT TARGET Qt5::lconvert AND TARGET Qt5::lrelease)
 320             get_target_property(_lrelease_location Qt5::lrelease LOCATION)
 321             get_filename_component(_lrelease_path ${_lrelease_location} PATH)
 322             find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 323         elseif(TARGET Qt5::lconvert AND NOT Qt5_LCONVERT_EXECUTABLE)
 324             # Newer Qt5 versions define the target, but not the Qt5_LCONVERT_EXECUTABLE variable for some reason
 325             get_target_property(QT_LCONVERT_EXECUTABLE Qt5::lconvert LOCATION)
 326         endif()
 327
 328         # Compatibility with the Qt4 variables
 329         set(QT_LRELEASE_EXECUTABLE ${Qt5_LRELEASE_EXECUTABLE})
 330         set(QT_LUPDATE_EXECUTABLE ${Qt5_LUPDATE_EXECUTABLE})
 331         if (Qt5_LCONVERT_EXECUTABLE)
 332             set(QT_LCONVERT_EXECUTABLE ${Qt5_LCONVERT_EXECUTABLE})
 333         endif()
 334     endif()
 335
 336 else(USE_QT5)
 337     find_package(Qt4 ${QT_MIN_VERSION} QUIET REQUIRED)
 338
 339     if (BUILD_GUI)
 340         add_feature_info("QtDBus module" QT_QTDBUS_FOUND "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments")
 341         if (QT_QTDBUS_FOUND)
 342             find_package(dbusmenu-qt QUIET CONFIG)
 343             set_package_properties(dbusmenu-qt PROPERTIES TYPE RECOMMENDED
 344                 URL "https://launchpad.net/libdbusmenu-qt"
 345                 DESCRIPTION "a library implementing the DBusMenu specification"
 346                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 347             )
 348         endif()
 349
 350         if (WITH_WEBKIT AND QT_QTWEBKIT_FOUND)
 351             set(HAVE_WEBKIT true)
 352         endif()
 353         add_feature_info("WITH_WEBKIT and QtWebKit module" HAVE_WEBKIT "Support showing previews for URLs in chat")
 354
 355         if (WITH_KDE)
 356             # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 357             set(_cflags ${CMAKE_C_FLAGS})
 358             find_package(KDE4 4.4 QUIET)
 359             set_package_properties(KDE4 PROPERTIES TYPE REQUIRED
 360                 URL "http://www.kde.org"
 361                 DESCRIPTION "a world-class desktop environment"
 362                 PURPOSE "Enables various bits for improving integration with KDE"
 363             )
 364             set(CMAKE_C_FLAGS ${_cflags})
 365
 366         else(WITH_KDE)
 367             find_package(Phonon QUIET)
 368             set_package_properties(Phonon PROPERTIES TYPE RECOMMENDED
 369                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 370                 DESCRIPTION "a multimedia abstraction library"
 371                 PURPOSE     "Required for audio notifications"
 372             )
 373         endif(WITH_KDE)
 374
 375         find_package(IndicateQt QUIET)
 376         set_package_properties(IndicateQt PROPERTIES TYPE OPTIONAL
 377             URL "https://launchpad.net/libindicate-qt/"
 378             DESCRIPTION "a library to raise flags on DBus for other components of the desktop to pick up and visualize"
 379             PURPOSE     "Provides integration into the Ayatana notification system used by e.g. Ubuntu"
 380         )
 381
 382     endif(BUILD_GUI)
 383
 384     if (BUILD_CORE)
 385
 386         find_package(QCA2 QUIET)
 387         set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 388             URL "https://projects.kde.org/projects/kdesupport/qca"
 389             DESCRIPTION "Qt Cryptographic Architecture"
 390             PURPOSE     "Required for encryption support"
 391         )
 392
 393
 394     endif()
 395
 396     # Qt4 does not consider lconvert relevant, so they don't support finding it...
 397     # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 398     if (QT_LRELEASE_EXECUTABLE)
 399         get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 400         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 401     endif()
 402 endif()
 403
 404
 405 # Non-Qt-based packages
 406
 407 # zlib for compression, however we can always fall back to miniz
 408 find_package(ZLIB QUIET)
 409 set_package_properties(ZLIB PROPERTIES TYPE RECOMMENDED
 410     URL "http://www.zlib.net"
 411     DESCRIPTION "a popular compression library"
 412     PURPOSE     "Use the most common library for protocol compression, instead of the bundled miniz implementation"
 413 )
 414
 415
 416 if (NOT WIN32)
 417     # Execinfo is needed for generating backtraces
 418     find_package(ExecInfo QUIET)
 419     set_package_properties(ExecInfo PROPERTIES TYPE OPTIONAL
 420         DESCRIPTION "a library for inspecting backtraces"
 421         PURPOSE "Used for generating backtraces in case of a crash"
 422     )
 423 endif()
 424
 425 # Check for SSL support in Qt
 426 # As there's no easy way to get Qt's configuration in particular for Qt5, let's just compile
 427 # a small test program checking the defines. This works for both Qt4 and Qt5.
 428 cmake_push_check_state(RESET)
 429 set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES} ${Qt5Core_INCLUDE_DIRS})
 430 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Core_EXECUTABLE_COMPILE_FLAGS}")
 431 check_cxx_source_compiles("
 432     #include \"qglobal.h\"
 433     #if defined QT_NO_OPENSSL || defined QT_NO_SSL
 434     #  error \"No SSL support\"
 435     #endif
 436     int main() {}"
 437     HAVE_SSL)
 438 cmake_pop_check_state()
 439
 440 # Additional compile settings
 441 #####################################################################
 442
 443 # This sets -fPIC and friends if required by the installed Qt5 library
 444 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 445     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 446 endif()
 447
 448 # Needed to compile with mingw without kde
 449 if (MINGW AND NOT KDE4_FOUND)
 450     add_definitions(-D_WIN32_WINNT=0x0500)
 451     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 452     # workaround for bug in mingw gcc 4.0
 453     add_definitions(-U__STRICT_ANSI__)
 454 endif()
 455
 456 # Sanitize compiler flags - old versions of KDE set -ansi, which breaks -std=c++11
 457 if (CMAKE_COMPILER_IS_GNUCXX)
 458     string(REPLACE "-ansi" "" CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS})
 459 endif()
 460
 461
 462 # Setup KDE / KDE Frameworks
 463 #####################################################################
 464
 465 # We want to do this up here, so we have the necessary variables and defines set before
 466 # compiling anything
 467
 468 if (KDE4_FOUND)
 469     # We always use external icons for KDE4 support, since we use its iconloader rather than Qt's
 470     set(EMBED_DATA OFF)
 471
 472     # Better have the compile flags global, even for the core, to avoid problems with linking the mono client
 473     add_definitions(-DHAVE_KDE -DHAVE_KDE4 ${KDE4_DEFINITIONS})
 474     set(WITH_KDE4 TRUE)
 475 endif()
 476
 477 if (USE_QT5 AND WITH_KDE)
 478     # If KDE Frameworks are present, they're most probably providing Qt5 integration including icon loading
 479     set(EMBED_DATA OFF)
 480
 481     include(KDEInstallDirs)
 482     include(KDECompilerSettings)
 483     include(KDECMakeSettings)
 484
 485     add_definitions(-DHAVE_KDE -DHAVE_KF5)
 486     set(WITH_KF5 TRUE)
 487 endif()
 488
 489 # This needs to come after setting up KDE integration, so we can use KDE-specific paths
 490 include(QuasselInstallDirs)
 491
 492 # Various config-dependent checks and settings
 493 #####################################################################
 494
 495 if (NOT ZLIB_FOUND)
 496     message(STATUS "zlib NOT found, using bundled miniz for compression")
 497     if (${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 498         message(STATUS "WARNING: This may be slow on 32 bit systems!")
 499     endif()
 500 endif()
 501
 502 if (HAVE_SSL)
 503     add_definitions(-DHAVE_SSL)
 504 endif()
 505 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 506
 507 # Check for syslog support
 508 if (NOT WIN32)
 509     check_include_file(syslog.h HAVE_SYSLOG)
 510     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 511 endif()
 512
 513 add_feature_info("Qt Linguist Tools" QT_LCONVERT_EXECUTABLE "Translation support for Quassel")
 514
 515 if (EMBED_DATA)
 516     message(STATUS "Embedding data files into the binary")
 517 else()
 518     message(STATUS "Installing data files separately")
 519 endif()
 520
 521 if (INDICATEQT_FOUND)
 522     add_definitions(-DXDG_APPS_INSTALL_DIR=${CMAKE_INSTALL_APPDIR})
 523 endif()
 524
 525 if (NOT WIN32)
 526     check_function_exists(umask HAVE_UMASK)
 527     if(HAVE_UMASK)
 528         add_definitions(-DHAVE_UMASK)
 529     endif(HAVE_UMASK)
 530 endif()
 531
 532
 533 # Windows-specific stuff
 534 #####################################################################
 535
 536 if (WIN32)
 537     link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 538     if (MSVC)
 539         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /DNOMINMAX")
 540         set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 541         set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 542         set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 543         link_libraries(Version dwmapi shlwapi)
 544         if (USE_QT5)
 545             set(QT_QTMAIN_LIBRARY Qt5::WinMain)
 546         endif()
 547     endif()
 548     if(HAVE_SSL AND STATIC)
 549         find_package(OpenSSL REQUIRED)
 550         link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 551     endif()
 552 endif()
 553
 554
 555 # Static builds (very much non-portable, so don't use -DSTATIC
 556 # unless you know what you do!)
 557 #####################################################################
 558
 559 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 560     set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 561     link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 562     if (HAVE_SSL)
 563         set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 564     endif()
 565 endif()
 566
 567
 568 # Generate version information from Git
 569 #####################################################################
 570
 571 include(GetGitRevisionDescription)
 572 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 573 git_describe(GIT_DESCRIBE --long)
 574
 575 # If not in a Git repo try to read GIT_HEAD and GIT_DESCRIBE from
 576 # enviroment
 577 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 578   if (DEFINED ENV{GIT_HEAD})
 579       set(GIT_HEAD $ENV{GIT_HEAD})
 580   endif ()
 581   if (DEFINED ENV{GIT_DESCRIBE})
 582      set(GIT_DESCRIBE $ENV{GIT_DESCRIBE})
 583   endif()
 584 endif()
 585
 586 # Sanitize things if we're not in a Git repo
 587 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 588     set(GIT_HEAD "")
 589     set(GIT_DESCRIBE "")
 590 endif()
 591
 592 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 593
 594 # Prepare the build
 595 #####################################################################
 596
 597 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 598 set(COMMON_DEPS ${RC_WIN32})
 599 set(CORE_DEPS )
 600 set(CLIENT_DEPS )
 601
 602 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 603 add_subdirectory(data)
 604 add_subdirectory(icons)
 605 add_subdirectory(pics)
 606 add_subdirectory(po)
 607
 608
 609 # Set up and display feature summary
 610 #####################################################################
 611
 612 feature_summary(WHAT ALL
 613                 INCLUDE_QUIET_PACKAGES
 614                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 615 )
 616
 617 # Finally, compile the sources
 618 # We want this after displaying the feature summary to avoid ugly
 619 # CMake backtraces in case a required Qt5 module is missing
 620 #####################################################################
 621
 622 add_subdirectory(src)