CMakeLists.txt

   1 # This is the cmake-based build system for Quassel IRC.
   2 #
   3 # You may pass various options to cmake:
   4 # -DWANT_(CORE|QTCLIENT|MONO)=(ON|OFF)
   5 #                     : select binaries to build
   6 # -DWITH_OPENSSL=OFF  : Disable OpenSSL support
   7 # -DWITH_DBUS=OFF     : Disable D-Bus support (dbus notifications)
   8 # -DWITH_WEBKIT=OFF   : Disable WebKit support (link previews)
   9 # -DWITH_PHONON=OFF   : Disable Phonon support (audio notifications)
  10 # -DWITH_KDE=ON       : Enable KDE4 support
  11 #
  12 # -DEMBED_DATA=ON     : Embed all data files in icons the binary, rather than installing them separately
  13 #
  14 # -DQT=/path/to/qt    : Choose a Qt4 installation to use instead of the system Qt4
  15 # -DSTATIC=ON         : Enable static building of Quassel. Use with care.
  16 # -DDEPLOY=ON         : Mac OS X only. Use only for creating Quassel Packages!
  17 #
  18 # NOTE: You should remove CMakeCache.txt if you plan to change any of these values!
  19
  20 project(QuasselIRC)
  21
  22 cmake_minimum_required(VERSION 2.6.0 FATAL_ERROR)
  23
  24 if(COMMAND cmake_policy)
  25    cmake_policy(SET CMP0003 NEW)
  26 endif(COMMAND cmake_policy)
  27
  28 # Use our own (well, and KDE's) version of some modules
  29 # In particular cmake's own FindQt4 and FindOpenSSL are quite buggy
  30 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  31 include(QuasselMacros)
  32
  33 # Various options and variables that can be set on the command line
  34 option(WANT_CORE     "Build the core (server) binary"           ON)
  35 option(WANT_QTCLIENT "Build the Qt4 GUI client binary"          ON)
  36 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  37
  38 option(WITH_OPENSSL  "Enable OpenSSL support if present on the system"  ON)
  39 option(WITH_DBUS     "Enable D-Bus support if present on the system"    ON)
  40 option(WITH_WEBKIT   "Enable WebKit support (for link previews)"        ON)
  41 option(WITH_PHONON   "Enable Phonon support (for audio notifications)"  ON)
  42 option(WITH_KDE      "Enable KDE4 integration"                          OFF)
  43
  44 # We use icon paths from KDE 4.3 trunk, which are partially invalid on older and possibly
  45 # even on newer KDE versions. Do not disable this unless you are sure that your Quassel will
  46 # run on a matching KDE version only.
  47 option(WITH_OXYGEN   "Install Oxygen icons. Heavily recommended unless you use KDE 4.3" ON)
  48
  49 option(STATIC        "Enable static building (might not be portable)" OFF)
  50
  51 if(APPLE)
  52   option(DEPLOY        "Mac OS X only! Adds required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF)
  53 endif(APPLE)
  54
  55 # Default to embedding data in the static case
  56 if(STATIC OR WIN32)
  57   set(EMBED_DEFAULT ON)
  58 else(STATIC OR WIN32)
  59   set(EMBED_DEFAULT ON) # should be OFF as soon as everything works
  60 endif(STATIC OR WIN32)
  61
  62 option(EMBED_DATA    "Embed all data files in the binary (rather than installing them separately)"   ${EMBED_DEFAULT})
  63
  64 set(QT "" CACHE STRING "Path to a Qt installation to use instead of the system Qt (e.g. for static builds)")
  65 set(LINGUAS "" CACHE STRING "Comma-separated list of locales specifying languages that should be compiled")
  66
  67 # Some settings imply others
  68 if(STATIC)
  69   add_definitions(-DSTATIC)
  70   set(WITH_KDE OFF CACHE BOOL "Static building with KDE is not supported")
  71 endif(STATIC)
  72
  73 if(WIN32)
  74   # We don't support separately installed resources yet on Win32
  75   set(EMBED_DATA ON)
  76 endif(WIN32)
  77
  78 # Build Type
  79 # We need to make sure it's not empty
  80 # Supported: Release, RelWithDebugInfo, Debug, Debugfull
  81
  82 # On WIN32, only Release seems to work correctly (?)
  83 if(WIN32)
  84   set(DEFAULT_BUILD_TYPE "Release")
  85 else(WIN32)
  86   set(DEFAULT_BUILD_TYPE "RelWithDebugInfo")
  87 endif(WIN32)
  88
  89 set(CMAKE_BUILD_TYPE ${DEFAULT_BUILD_TYPE} CACHE STRING "CMake Build Type")
  90 if(NOT CMAKE_BUILD_TYPE)
  91   set(CMAKE_BUILD_TYPE ${DEFAULT_BUILD_TYPE} CACHE STRING "CMake Build Type" FORCE)
  92 endif(NOT CMAKE_BUILD_TYPE)
  93
  94 # Enable various flags on gcc
  95 if(CMAKE_COMPILER_IS_GNUCXX)
  96   # Let's just hope that all gccs support these options and skip the tests...
  97   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -ansi -Wall -Wextra -Wnon-virtual-dtor")
  98   set(CMAKE_CXX_FLAGS_RELWITHDEBUGINFO "-O2")
  99   set(CMAKE_CXX_FLAGS_DEBUG "-g -fno-reorder-blocks -fno-schedule-insns -fno-inline")
 100   set(CMAKE_CXX_FLAGS_DEBUGFULL "-g3")
 101 endif(CMAKE_COMPILER_IS_GNUCXX)
 102
 103 set(QT_MIN_VERSION "4.4.0")
 104
 105 if(APPLE AND DEPLOY)
 106   set(CMAKE_OSX_ARCHITECTURES "i386;ppc")
 107   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.4")
 108   set(CMAKE_OSX_SYSROOT "/Developer/SDKs/MacOSX10.4u.sdk/")
 109   add_definitions(-DMAC_10_4_SDK)
 110 endif(APPLE AND DEPLOY)
 111
 112 # Execinfo is needed for generating backtraces
 113 find_package(ExecInfo)
 114 if(EXECINFO_FOUND)
 115   add_definitions(-DHAVE_EXECINFO)
 116   include_directories(${EXECINFO_INCLUDES})
 117   link_libraries(${EXECINFO_LIBRARIES})
 118 endif(EXECINFO_FOUND)
 119
 120 # Select a Qt installation here, if you don't want to use system Qt
 121 if(QT)
 122   # FindQt4 will look for the qmake binary in $PATH, so we just prepend the Qt dir
 123   set(ENV{PATH} ${QT}/bin:$ENV{PATH})
 124 endif(QT)
 125
 126 # Now that we have the correct $PATH, lets find Qt!
 127 find_package(Qt4 REQUIRED)
 128
 129 set(QT_DONT_USE_QTGUI 1)
 130 include(${QT_USE_FILE})
 131 include_directories(${QT_INCLUDES})
 132
 133 # Setup OpenSSL
 134 if(WITH_OPENSSL)
 135   find_package(OpenSSL)
 136 else(WITH_OPENSSL)
 137   message(STATUS "Disabling OpenSSL support")
 138 endif(WITH_OPENSSL)
 139
 140 if(OPENSSL_FOUND)
 141   if(NOT QT_DEFINITIONS MATCHES "QT_NO_OPENSSL")
 142     message(STATUS "Found OpenSSL support in Qt")
 143     add_definitions(-DHAVE_SSL)
 144     set(HAVE_SSL true)
 145     set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_SSL)
 146   else(NOT QT_DEFINITIONS MATCHES "QT_NO_OPENSSL")
 147     message(STATUS "No OpenSSL support found in Qt, disabling")
 148   endif(NOT QT_DEFINITIONS MATCHES "QT_NO_OPENSSL")
 149 else(OPENSSL_FOUND)
 150   add_definitions(-DQT_NO_OPENSSL)
 151 endif(OPENSSL_FOUND)
 152
 153 # Setup D-Bus support
 154 if(WITH_DBUS)
 155   if(QT_QTDBUS_FOUND)
 156     message(STATUS "Found QtDBus, enabling D-Bus support")
 157     add_definitions(-DHAVE_DBUS)
 158     set(LINK_DBUS DBUS)
 159     set(HAVE_DBUS true)
 160     set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_DBUS)
 161   else(QT_QTDBUS_FOUND)
 162     message(STATUS "QtDBus not found, disabling D-Bus support")
 163   endif(QT_QTDBUS_FOUND)
 164 else(WITH_DBUS)
 165   message(STATUS "Disabling D-Bus support")
 166 endif(WITH_DBUS)
 167
 168 # Setup QtWebKit support
 169 if(WITH_WEBKIT)
 170   if(QT_QTWEBKIT_FOUND)
 171     message(STATUS "Found QtWebKit, enabling WebKit support")
 172     add_definitions(-DHAVE_WEBKIT)
 173     set(LINK_WEBKIT WEBKIT)
 174     set(HAVE_WEBKIT true)
 175     set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_WEBKIT)
 176   else(QT_QTWEBKIT_FOUND)
 177     message(STATUS "QtWebKit not found, disabling WebKit support")
 178   endif(QT_QTWEBKIT_FOUND)
 179 else(WITH_WEBKIT)
 180   message(STATUS "Disabling WebKit support")
 181 endif(WITH_WEBKIT)
 182
 183 # Setup KDE4 support
 184 if(WITH_KDE)
 185   find_package(KDE4)
 186   if(KDE4_FOUND)
 187     message(STATUS "Enabling KDE4 integration")
 188     include_directories(${KDE4_INCLUDES})
 189     add_definitions(-DHAVE_KDE ${KDE4_DEFINITIONS})
 190     set(HAVE_KDE 1)
 191     set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_KDE)
 192     set(QUASSEL_KDE_LIBRARIES ${KDE4_KDECORE_LIBS} ${KDE4_KDEUI_LIBRARY} knotifyconfig)
 193     # We always use external icons for KDE4 support, since we use its iconloader rather than our own
 194     set(EMBED_DATA OFF)
 195   else(KDE4_FOUND)
 196     message(STATUS "KDE4 not found, disabling KDE integration")
 197   endif(KDE4_FOUND)
 198 else(WITH_KDE)
 199   message(STATUS "Disabling KDE4 integration")
 200 endif(WITH_KDE)
 201
 202 # Setup Phonon support - we only need this if we don't have or want KDE4
 203 if(NOT HAVE_KDE)
 204   if(WITH_PHONON)
 205     find_package(Phonon)
 206     if(PHONON_FOUND)
 207       message(STATUS "Enabling Phonon support")
 208       add_definitions(-DHAVE_PHONON)
 209       set(HAVE_PHONON true)
 210       set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_PHONON)
 211     else(PHONON_FOUND)
 212       message(STATUS "Phonon not found, disabling audio notifications")
 213     endif(PHONON_FOUND)
 214   else(WITH_PHONON)
 215     message(STATUS "Disabling Phonon support")
 216   endif(WITH_PHONON)
 217 endif(NOT HAVE_KDE)
 218
 219 # Now set up install locations; those are set by KDE if integration is enabled
 220 if(NOT HAVE_KDE)
 221   if(WIN32)
 222     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX} CACHE FILEPATH "Install path for binaries")
 223     set(DATA_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/apps CACHE FILEPATH "Install path for data files")
 224     set(ICON_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/icons CACHE FILEPATH "Global icon install path")
 225     set(XDG_APPS_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/applications CACHE FILEPATH "Install path for .desktop files")
 226   else(WIN32)
 227     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin CACHE FILEPATH "Install path for binaries")
 228     set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps CACHE FILEPATH "Install path for data files")
 229     set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons CACHE FILEPATH "Global icon install path")
 230     set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications CACHE FILEPATH "Install path for .desktop files")
 231   endif(WIN32)
 232 endif(NOT HAVE_KDE)
 233
 234 # RPATH needs to be set correctly
 235 # Do this down here, since otherwise KDE wants to handle it itself, and fails
 236 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
 237 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
 238
 239 # Set global buildflags
 240 # This is very much non-portable, so don't use -DSTATIC until you know what
 241 # you do.
 242 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 243   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 244   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 245   if(HAVE_SSL)
 246     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 247   endif(HAVE_SSL)
 248 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 249
 250 if(WIN32)
 251   link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 252
 253   if(HAVE_SSL)
 254      link_libraries(${OPENSSL_LIBRARIES} libeay32MD)
 255   endif(HAVE_SSL)
 256
 257   set(RC_WIN32 ../pics/win32.rc)  # for app icons on windows
 258 endif(WIN32)
 259
 260 if(STATIC)
 261   link_directories(${QT_PLUGINS_DIR}/imageformats)
 262   link_libraries(qjpeg qgif)
 263 endif(STATIC)
 264
 265 # We need to create a version.gen
 266 # For this, we create our genversion binary and make sure it is run every time.
 267 add_executable(genversion ${CMAKE_SOURCE_DIR}/src/common/genversion.cpp)
 268 target_link_libraries(genversion ${QT_LIBRARIES} ${QT_CORE_LIB_DEPENDENCIES})
 269
 270 get_target_property(GENVERSION_EXECUTABLE genversion LOCATION)
 271 add_custom_target(genversion_run ALL ${GENVERSION_EXECUTABLE}
 272                   ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR}/src/version.gen)
 273 add_dependencies(genversion_run genversion)
 274
 275 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 276 set(COMMON_DEPS ${RC_WIN32})
 277 set(CORE_DEPS )
 278 set(CLIENT_DEPS )
 279
 280 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 281 add_subdirectory(data)
 282 add_subdirectory(icons)
 283 add_subdirectory(pics)
 284 add_subdirectory(i18n)
 285 add_subdirectory(src)