CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 cmake_minimum_required(VERSION 2.8.9)
  10 project(QuasselIRC)
  11
  12 # Versions
  13 set(QUASSEL_MAJOR  0)
  14 set(QUASSEL_MINOR 12)
  15 set(QUASSEL_PATCH  0)
  16 set(QUASSEL_VERSION_STRING "0.12-pre")
  17
  18 # Tell CMake about or own modules
  19 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  20
  21 # General conveniences
  22 set(CMAKE_AUTOMOC ON)
  23 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  24
  25 # Include various CMake modules...
  26 include(CMakePushCheckState)
  27 include(CheckFunctionExists)
  28 include(CheckIncludeFile)
  29 include(CheckCXXSourceCompiles)
  30 include(CMakeDependentOption)
  31 include(FeatureSummary)
  32
  33 # ... and our own stuff
  34 include(QuasselCompileSettings)
  35 include(QuasselMacros)
  36
  37 # Setting COMPILE_DEFINITIONS_<CONFIG> is deprecated since CMake 3.0 in favor of generator expressions.
  38 # These have existed since CMake 2.8.10; until we depend on that, we have to explicitly enable the old policy.
  39 if (CMAKE_MAJOR_VERSION GREATER 2)
  40     cmake_policy(SET CMP0043 OLD)
  41 endif()
  42
  43 # Options and variables that can be set on the command line
  44 #####################################################################
  45
  46 # First, choose a Qt version. We support USE_QT4 and USE_QT5; if neither is set, prefer Qt4 for now
  47 option(USE_QT5 "Enable support for Qt5 (disables KDE integration)" OFF)
  48 if (USE_QT4) # takes precedence
  49     set(USE_QT5 OFF)
  50 else()
  51     if (NOT USE_QT5)
  52         set(USE_QT4 ON)
  53     endif()
  54 endif()
  55
  56 # Select the binaries to build
  57 option(WANT_CORE     "Build the core (server) binary"           ON)
  58 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  59 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  60 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  61 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  62 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  63
  64 # Whether to enable KDE integration (pulls in kdelibs and friends as a dependency); requires Qt4 for now
  65 cmake_dependent_option(WITH_KDE "KDE4 integration" OFF "USE_QT4" OFF)
  66 add_feature_info(WITH_KDE WITH_KDE "Enable KDE4 integration")
  67
  68 cmake_dependent_option(WITH_OXYGEN "Install Oxygen icon set (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
  69 if (NOT WITH_KDE)
  70     add_feature_info(WITH_OXYGEN WITH_OXYGEN "Install Oxygen icon set")
  71 endif()
  72
  73 # For this, the feature info is added after we know if QtWebkit is installed
  74 option(WITH_WEBKIT "WebKit support (for link previews)" ON)
  75
  76 if (APPLE)
  77     # Notification Center is only available in > 10.8, which is Darwin v12
  78     if (CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  79         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
  80         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
  81     endif()
  82 endif()
  83
  84 # Always embed on Windows, OSX or for a static build; never embed when enabling KDE integration
  85 set(EMBED_DEFAULT OFF)
  86 if (STATIC OR WIN32 OR APPLE)
  87     set(EMBED_DEFAULT ON)
  88 endif()
  89 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
  90                                    "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
  91 if (NOT EMBED_DEFAULT)
  92     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
  93 endif()
  94
  95 # The following options are not for end-user consumption, so don't list them in the feature summary
  96 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
  97
  98 # Handle with care
  99 set(QT_PATH "" CACHE PATH "Path to a Qt4 installation to use instead of the system Qt (e.g. for static builds)")
 100
 101 # Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
 102 cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
 103
 104 # For static builds, arbitrary extra libs might need to be linked
 105 # Define a comma-separated list here
 106 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 107 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 108 if (LINK_EXTRA)
 109     string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 110     link_libraries(${LINK_EXTRA})
 111 endif()
 112
 113
 114 # Simplify later checks
 115 #####################################################################
 116
 117 if (WANT_MONO OR WANT_QTCLIENT)
 118     set(BUILD_GUI true)
 119 endif()
 120 if (WANT_MONO OR WANT_CORE)
 121     set(BUILD_CORE true)
 122 endif()
 123
 124
 125 # Set up Qt
 126 #####################################################################
 127
 128 if (USE_QT5)
 129     message(STATUS "Building for Qt5...")
 130     set(QT_MIN_VERSION "5.2.0")
 131     add_definitions(-DHAVE_QT5)
 132 else()
 133     message(STATUS "Building for Qt4...")
 134     if (BUILD_GUI)
 135         set(QT_MIN_VERSION "4.6.0")
 136     else()
 137         set(QT_MIN_VERSION "4.4.0")
 138     endif()
 139
 140     # Select a Qt installation here, if you don't want to use system Qt
 141     if(QT_PATH)
 142         # FindQt4 will look for the qmake binary in $PATH, so we just prepend QT_PATH
 143         set(ENV{PATH} ${QT_PATH}/bin:$ENV{PATH})
 144     endif()
 145 endif()
 146
 147 # Find package dependencies
 148 #
 149 # Note that you can forcefully disable optional packages
 150 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 151 #####################################################################
 152
 153 if (USE_QT5)
 154     find_package(Qt5Core ${QT_MIN_VERSION} QUIET)
 155     set_package_properties(Qt5Core PROPERTIES TYPE REQUIRED
 156         URL "http://qt.digia.com"
 157         DESCRIPTION "contains core functionality for Qt"
 158     )
 159     # find_package without REQUIRED won't check for the version properly; also, older Qt5 versions
 160     # used Qt5Core_VERSION_STRING... let's just make sure here that we bail out here if our Qt5 is not new enough.
 161     if (NOT Qt5Core_VERSION OR Qt5Core_VERSION VERSION_LESS ${QT_MIN_VERSION})
 162         message(FATAL_ERROR "Could NOT find Qt5 >= version ${QT_MIN_VERSION}!")
 163     endif()
 164
 165     find_package(Qt5Network QUIET)
 166     set_package_properties(Qt5Network PROPERTIES TYPE REQUIRED
 167         DESCRIPTION "the network module for Qt5"
 168     )
 169
 170     if (BUILD_GUI)
 171         find_package(Qt5Gui QUIET)
 172         set_package_properties(Qt5Gui PROPERTIES TYPE REQUIRED
 173             DESCRIPTION "the GUI module for Qt5"
 174         )
 175         find_package(Qt5Widgets QUIET)
 176         set_package_properties(Qt5Widgets PROPERTIES TYPE REQUIRED
 177             DESCRIPTION "the widgets module for Qt5"
 178         )
 179
 180         find_package(Qt5DBus QUIET)
 181         set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 182             URL "http://qt.digia.com"
 183             DESCRIPTION "D-Bus support for Qt5"
 184             PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 185         )
 186         if (Qt5DBus_FOUND)
 187             find_package(dbusmenu-qt5 QUIET CONFIG)
 188             set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 189                 URL "https://launchpad.net/libdbusmenu-qt"
 190                 DESCRIPTION "a library implementing the DBusMenu specification"
 191                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 192             )
 193         endif()
 194
 195         find_package(Phonon4Qt5 QUIET)
 196         set_package_properties(Phonon4Qt5 PROPERTIES TYPE RECOMMENDED
 197             URL "https://projects.kde.org/projects/kdesupport/phonon"
 198             DESCRIPTION "a multimedia abstraction library"
 199             PURPOSE     "Required for audio notifications"
 200         )
 201
 202         find_package(LibsnoreQt5 QUIET)
 203         set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
 204             URL "https://github.com/TheOneRing/Snorenotify"
 205             DESCRIPTION "a cross-platform notification framework"
 206             PURPOSE     "Enable support for the snorenotify framework"
 207         )
 208
 209         if (WITH_WEBKIT)
 210             find_package(Qt5WebKit QUIET)
 211             set_package_properties(Qt5WebKit PROPERTIES TYPE RECOMMENDED
 212                 URL "http://qt.digia.com"
 213                 DESCRIPTION "a WebKit implementation for Qt"
 214                 PURPOSE     "Needed for displaying previews for URLs in chat"
 215             )
 216             if (Qt5WebKit_FOUND)
 217                 find_package(Qt5WebKitWidgets QUIET)
 218                 set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE RECOMMENDED
 219                     URL "http://qt.digia.com"
 220                     DESCRIPTION "widgets for Qt's WebKit implementation"
 221                     PURPOSE     "Needed for displaying previews for URLs in chat"
 222                 )
 223             endif()
 224         endif()
 225         add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" Qt5WebKitWidgets_FOUND "Support showing previews for URLs in chat")
 226
 227     endif(BUILD_GUI)
 228     if (BUILD_CORE)
 229         find_package(Qt5Script QUIET)
 230         set_package_properties(Qt5Script PROPERTIES TYPE REQUIRED
 231             DESCRIPTION "provides scripting support for Qt5"
 232         )
 233         find_package(Qt5Sql QUIET)
 234         set_package_properties(Qt5Sql PROPERTIES TYPE REQUIRED
 235             DESCRIPTION "the database support module for Qt5"
 236         )
 237
 238         # While QCA2 seems to support Qt5, it is not actually co-installable or distinguishable from the Qt4 version...
 239         # In order to avoid linking against the Qt4 version (which is probably the one installed), disable this for now
 240         #find_package(QCA2 QUIET)
 241         #set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 242         #    URL "https://projects.kde.org/projects/kdesupport/qca"
 243         #    DESCRIPTION "Qt Cryptographic Architecture"
 244         #    PURPOSE "Required for encryption support"
 245         #)
 246
 247     endif(BUILD_CORE)
 248
 249     find_package(Qt5LinguistTools QUIET)
 250     set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 251                            DESCRIPTION "contains tools for handling translation files"
 252                            PURPOSE "Required for having translations"
 253     )
 254     # Some Qt5 versions do not define a target for lconvert, so we need to find it ourselves
 255     if (Qt5LinguistTools_FOUND)
 256         if (NOT TARGET Qt5::lconvert AND TARGET Qt5::lrelease)
 257             get_target_property(_lrelease_location Qt5::lrelease LOCATION)
 258             get_filename_component(_lrelease_path ${_lrelease_location} PATH)
 259             find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 260         elseif(TARGET Qt5::lconvert AND NOT Qt5_LCONVERT_EXECUTABLE)
 261             # Newer Qt5 versions define the target, but not the Qt5_LCONVERT_EXECUTABLE variable for some reason
 262             get_target_property(QT_LCONVERT_EXECUTABLE Qt5::lconvert LOCATION)
 263         endif()
 264
 265         # Compatibility with the Qt4 variables
 266         set(QT_LRELEASE_EXECUTABLE ${Qt5_LRELEASE_EXECUTABLE})
 267         set(QT_LUPDATE_EXECUTABLE ${Qt5_LUPDATE_EXECUTABLE})
 268         if (Qt5_LCONVERT_EXECUTABLE)
 269             set(QT_LCONVERT_EXECUTABLE ${Qt5_LCONVERT_EXECUTABLE})
 270         endif()
 271     endif()
 272
 273 else(USE_QT5)
 274     find_package(Qt4 ${QT_MIN_VERSION} QUIET REQUIRED)
 275
 276     if (BUILD_GUI)
 277         add_feature_info("QtDBus module" QT_QTDBUS_FOUND "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments")
 278         if (QT_QTDBUS_FOUND)
 279             find_package(dbusmenu-qt QUIET CONFIG)
 280             set_package_properties(dbusmenu-qt PROPERTIES TYPE RECOMMENDED
 281                 URL "https://launchpad.net/libdbusmenu-qt"
 282                 DESCRIPTION "a library implementing the DBusMenu specification"
 283                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 284             )
 285         endif()
 286
 287         if (WITH_WEBKIT AND QT_QTWEBKIT_FOUND)
 288             set(HAVE_WEBKIT true)
 289         endif()
 290         add_feature_info("WITH_WEBKIT and QtWebKit module" HAVE_WEBKIT "Support showing previews for URLs in chat")
 291
 292         if (WITH_KDE)
 293             # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 294             set(_cflags ${CMAKE_C_FLAGS})
 295             find_package(KDE4 4.4 QUIET)
 296             set_package_properties(KDE4 PROPERTIES TYPE REQUIRED
 297                 URL "http://www.kde.org"
 298                 DESCRIPTION "a world-class desktop environment"
 299                 PURPOSE "Enables various bits for improving integration with KDE"
 300             )
 301             set(CMAKE_C_FLAGS ${_cflags})
 302
 303         else(WITH_KDE)
 304             find_package(Phonon QUIET)
 305             set_package_properties(Phonon PROPERTIES TYPE RECOMMENDED
 306                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 307                 DESCRIPTION "a multimedia abstraction library"
 308                 PURPOSE     "Required for audio notifications"
 309             )
 310
 311             find_package(Libsnore QUIET)
 312             set_package_properties(Libsnore PROPERTIES TYPE OPTIONAL
 313                 URL "https://github.com/TheOneRing/Snorenotify"
 314                 DESCRIPTION "a cross-platform notification framework"
 315                 PURPOSE     "Enable support for the snorenotify framework"
 316             )
 317         endif(WITH_KDE)
 318
 319         find_package(IndicateQt QUIET)
 320         set_package_properties(IndicateQt PROPERTIES TYPE OPTIONAL
 321             URL "https://launchpad.net/libindicate-qt/"
 322             DESCRIPTION "a library to raise flags on DBus for other components of the desktop to pick up and visualize"
 323             PURPOSE     "Provides integration into the Ayatana notification system used by e.g. Ubuntu"
 324         )
 325
 326     endif(BUILD_GUI)
 327     if (BUILD_CORE)
 328
 329         find_package(QCA2 QUIET)
 330         set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 331             URL "https://projects.kde.org/projects/kdesupport/qca"
 332             DESCRIPTION "Qt Cryptographic Architecture"
 333             PURPOSE     "Required for encryption support"
 334         )
 335
 336
 337     endif()
 338
 339     # Qt4 does not consider lconvert relevant, so they don't support finding it...
 340     # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 341     if (QT_LRELEASE_EXECUTABLE)
 342         get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 343         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 344     endif()
 345 endif()
 346
 347
 348 # Non-Qt-based packages
 349
 350 # zlib for compression, however we can always fall back to miniz
 351 find_package(ZLIB QUIET)
 352 set_package_properties(ZLIB PROPERTIES TYPE RECOMMENDED
 353     URL "http://www.zlib.net"
 354     DESCRIPTION "a popular compression library"
 355     PURPOSE     "Use the most common library for protocol compression, instead of the bundled miniz implementation"
 356 )
 357
 358
 359 if (NOT WIN32)
 360     # Execinfo is needed for generating backtraces
 361     find_package(ExecInfo QUIET)
 362     set_package_properties(ExecInfo PROPERTIES TYPE OPTIONAL
 363         DESCRIPTION "a library for inspecting backtraces"
 364         PURPOSE "Used for generating backtraces in case of a crash"
 365     )
 366 endif()
 367
 368
 369 # Various checks
 370 #####################################################################
 371
 372 if (NOT ZLIB_FOUND)
 373     message(STATUS "zlib NOT found, using bundled miniz for compression")
 374     if (${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 375         message(STATUS "WARNING: This may be slow on 32 bit systems!")
 376     endif()
 377 endif()
 378
 379 if (KDE4_FOUND)
 380     # We always use external icons for KDE4 support, since we use its iconloader rather than our own
 381     set(EMBED_DATA OFF)
 382
 383     # Better have the compile flags global, even for the core, to avoid problems with linking the mono client
 384     add_definitions(-DHAVE_KDE ${KDE4_DEFINITIONS})
 385 endif()
 386
 387 # Check for SSL support in Qt
 388 # As there's no easy way to get Qt's configuration in particular for Qt5, let's just compile
 389 # a small test program checking the defines. This works for both Qt4 and Qt5.
 390 cmake_push_check_state(RESET)
 391 if (Qt5_POSITION_INDEPENDENT_CODE)
 392     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 393 endif()
 394 set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES} ${Qt5Core_INCLUDE_DIRS})
 395 check_cxx_source_compiles("
 396     #include \"qglobal.h\"
 397     #if defined QT_NO_OPENSSL || defined QT_NO_SSL
 398     #  error \"No SSL support\"
 399     #endif
 400     int main() {}"
 401     HAVE_SSL)
 402 cmake_pop_check_state()
 403
 404 if (HAVE_SSL)
 405     add_definitions(-DHAVE_SSL)
 406 endif()
 407 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 408
 409 # Check for syslog support
 410 if (NOT WIN32)
 411     check_include_file(syslog.h HAVE_SYSLOG)
 412     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 413 endif()
 414
 415 add_feature_info("Qt Linguist Tools" QT_LCONVERT_EXECUTABLE "Translation support for Quassel")
 416
 417 # Various settings
 418 ##################
 419
 420 # needed to compile with mingw without kde
 421 if (MINGW AND NOT KDE4_FOUND)
 422     add_definitions(-D_WIN32_WINNT=0x0500)
 423     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 424 # workaround for bug in mingw gcc 4.0
 425     add_definitions(-U__STRICT_ANSI__)
 426 endif()
 427
 428 # Now set up install locations; those are set by KDE if integration is enabled
 429 if(NOT KDE4_FOUND)
 430   if(WIN32)
 431     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX} CACHE FILEPATH "Install path for binaries")
 432     set(DATA_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/apps CACHE FILEPATH "Install path for data files")
 433     set(ICON_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/icons CACHE FILEPATH "Global icon install path")
 434     set(XDG_APPS_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/applications CACHE FILEPATH "Install path for .desktop files")
 435   else(WIN32)
 436     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin CACHE FILEPATH "Install path for binaries")
 437     set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps CACHE FILEPATH "Install path for data files")
 438     set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons CACHE FILEPATH "Global icon install path")
 439     set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications CACHE FILEPATH "Install path for .desktop files")
 440   endif(WIN32)
 441 endif()
 442
 443 if(EMBED_DATA)
 444   message(STATUS "Embedding data files into the binary")
 445 else(EMBED_DATA)
 446   message(STATUS "Installing data files separately")
 447 endif(EMBED_DATA)
 448
 449 # RPATH needs to be set correctly
 450 # Do this down here, since otherwise KDE wants to handle it itself, and fails
 451 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
 452 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
 453
 454 # Set global buildflags
 455 # This is very much non-portable, so don't use -DSTATIC until you know what
 456 # you do.
 457 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 458   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 459   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 460   if(HAVE_SSL)
 461     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 462   endif(HAVE_SSL)
 463 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 464
 465 if(WIN32)
 466   link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 467   if(MSVC)
 468     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /DNOMINMAX")
 469     set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 470     set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 471     set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 472     link_libraries(Version dwmapi shlwapi)
 473     if(USE_QT5)
 474       set(QT_QTMAIN_LIBRARY Qt5::WinMain)
 475     endif(USE_QT5)
 476   endif(MSVC)
 477   if(HAVE_SSL AND STATIC)
 478      find_package(OpenSSL REQUIRED)
 479      link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 480   endif(HAVE_SSL AND STATIC)
 481 endif(WIN32)
 482
 483 if(INDICATEQT_FOUND)
 484   add_definitions(-DXDG_APPS_INSTALL_DIR=${XDG_APPS_INSTALL_DIR})
 485 endif()
 486
 487 if(NOT WIN32)
 488   check_function_exists(umask HAVE_UMASK)
 489   if(HAVE_UMASK)
 490     add_definitions(-DHAVE_UMASK)
 491   endif(HAVE_UMASK)
 492 endif(NOT WIN32)
 493
 494 # Generate version information from Git
 495 include(GetGitRevisionDescription)
 496 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 497 git_describe(GIT_DESCRIBE --long)
 498
 499 # Sanitize things if we're not in a Git repo
 500 if(NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 501     set(GIT_HEAD "")
 502     set(GIT_DESCRIBE "")
 503 endif()
 504
 505 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 506
 507 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 508 set(COMMON_DEPS ${RC_WIN32})
 509 set(CORE_DEPS )
 510 set(CLIENT_DEPS )
 511
 512 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 513 add_subdirectory(data)
 514 add_subdirectory(icons)
 515 add_subdirectory(pics)
 516 add_subdirectory(po)
 517
 518 # Set up and display feature summary
 519 #####################################################################
 520
 521 feature_summary(WHAT ALL
 522                 INCLUDE_QUIET_PACKAGES
 523                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 524 )
 525
 526 # Finally, compile the sources
 527 # We want this after displaying the feature summary to avoid ugly
 528 # CMake backtraces in case a required Qt5 modules misses
 529 #####################################################################
 530
 531 add_subdirectory(src)