CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 project(QuasselIRC)
  10
  11 # Versions
  12 set(QUASSEL_MAJOR  0)
  13 set(QUASSEL_MINOR 13)
  14 set(QUASSEL_PATCH  0)
  15 set(QUASSEL_VERSION_STRING "0.13-pre")
  16
  17 # We want to know CMake's version for debug reasons
  18 message(STATUS "Using CMake ${CMAKE_VERSION}")
  19
  20 # Tell CMake about or own modules
  21 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  22
  23 # General conveniences
  24 set(CMAKE_AUTOMOC ON)
  25 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  26
  27 # Include various CMake modules...
  28 include(CMakePushCheckState)
  29 include(CheckFunctionExists)
  30 include(CheckIncludeFile)
  31 include(CheckCXXSourceCompiles)
  32 include(CMakeDependentOption)
  33 include(FeatureSummary)
  34
  35 # ... and our own stuff
  36 include(QuasselCompileSettings)
  37 include(QuasselMacros)
  38
  39
  40 # Options and variables that can be set on the command line
  41 #####################################################################
  42
  43 # First, choose a Qt version. We support USE_QT5 and USE_QT4; if neither is set, Qt5 will be used
  44 option(USE_QT5 "Enable support for Qt5" OFF)
  45 if (USE_QT5) # takes precedence
  46     set(USE_QT4 OFF)
  47 else()
  48     if (NOT USE_QT4)
  49         set(USE_QT5 ON)
  50     endif()
  51 endif()
  52
  53 # Select the binaries to build
  54 option(WANT_CORE     "Build the core (server) binary"           ON)
  55 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  56 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  57 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  58 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  59 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  60
  61 # Whether to enable KDE integration (work in progress for Qt5 / KDE Frameworks)
  62 # Note that when building with Qt5, WITH_KDE enables integration with higher-tier KDE frameworks that
  63 # require runtime support. We still optionally make use of certain Tier 1 frameworks even if WITH_KDE
  64 # is disabled.
  65 if (USE_QT4)
  66     option(WITH_KDE "KDE4 integration" OFF)
  67     add_feature_info(WITH_KDE WITH_KDE "Enable KDE4 integration")
  68 else()
  69     option(WITH_KDE "Integration with the KDE Frameworks runtime environment")
  70     add_feature_info(WITH_KDE WITH_KDE "Integrate with the KDE Frameworks runtime environment")
  71 endif()
  72
  73 cmake_dependent_option(WITH_BREEZE "Install Breeze icon theme (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
  74 cmake_dependent_option(WITH_BREEZE_DARK "Install Dark Breeze icon theme (usually shipped with KDE)" OFF "NOT WITH_KDE" OFF)
  75 cmake_dependent_option(WITH_OXYGEN "Install Oxygen icon theme (usually shipped with KDE)" OFF "NOT WITH_KDE" OFF)
  76 if (NOT WITH_KDE)
  77     add_feature_info(WITH_BREEZE WITH_BREEZE "Install Breeze icon theme")
  78     add_feature_info(WITH_BREEZE_DARK WITH_BREEZE_DARK "Install Dark Breeze icon theme")
  79     add_feature_info(WITH_OXYGEN WITH_OXYGEN "Install Oxygen icon theme")
  80 endif()
  81
  82 if (WITH_OXYGEN)
  83     add_definitions(-DWITH_OXYGEN)
  84 endif()
  85 if (WITH_BREEZE)
  86     add_definitions(-DWITH_BREEZE)
  87 endif()
  88 if (WITH_BREEZE_DARK)
  89     add_definitions(-DWITH_BREEZE_DARK)
  90 endif()
  91
  92 # For this, the feature info is added after we know if QtWebkit is installed
  93 option(WITH_WEBKIT "WebKit support (for link previews) (legacy)" OFF)
  94
  95 # For this, the feature info is added after we know if QtWebEngine is installed
  96 option(WITH_WEBENGINE "WebEngine support (for link previews)" ON)
  97
  98 if (APPLE)
  99     # Notification Center is only available in > 10.8, which is Darwin v12
 100     if (NOT CMAKE_SYSTEM_VERSION VERSION_LESS 12)
 101         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
 102         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
 103     endif()
 104     find_library(CARBON_LIBRARY Carbon)
 105     mark_as_advanced(CARBON_LIBRARY)
 106     link_libraries(${CARBON_LIBRARY})
 107 endif()
 108
 109 # Always embed on Windows, OSX or for a static build; never embed when enabling KDE integration
 110 set(EMBED_DEFAULT OFF)
 111 if (STATIC OR WIN32 OR APPLE)
 112     set(EMBED_DEFAULT ON)
 113 endif()
 114 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
 115                                    "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
 116 if (NOT EMBED_DEFAULT)
 117     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
 118 endif()
 119
 120 # The following options are not for end-user consumption, so don't list them in the feature summary
 121 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
 122
 123 # Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
 124 cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
 125
 126 # For static builds, arbitrary extra libs might need to be linked
 127 # Define a comma-separated list here
 128 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 129 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 130 if (LINK_EXTRA)
 131     string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 132     link_libraries(${LINK_EXTRA})
 133 endif()
 134
 135
 136 # Setup CMake
 137 #####################################################################
 138
 139 if (USE_QT5 AND WITH_KDE)
 140     cmake_minimum_required(VERSION 2.8.12)
 141 else()
 142     cmake_minimum_required(VERSION 2.8.9)
 143 endif()
 144
 145 # Setting COMPILE_DEFINITIONS_<CONFIG> is deprecated since CMake 3.0 in favor of generator expressions.
 146 # These have existed since CMake 2.8.10; until we depend on that, we have to explicitly enable the old policy.
 147 if (POLICY CMP0043)
 148     cmake_policy(SET CMP0043 OLD)
 149 endif()
 150
 151 # Honor visibility settings for all target types
 152 if (POLICY CMP0063)
 153     cmake_policy(SET CMP0063 NEW)
 154 endif()
 155
 156
 157 # Simplify later checks
 158 #####################################################################
 159
 160 if (WANT_MONO OR WANT_QTCLIENT)
 161     set(BUILD_GUI true)
 162 endif()
 163 if (WANT_MONO OR WANT_CORE)
 164     set(BUILD_CORE true)
 165 endif()
 166
 167
 168 # Set up Qt
 169 #####################################################################
 170
 171 # Find package dependencies
 172 #
 173 # Note that you can forcefully disable optional packages
 174 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 175 #####################################################################
 176
 177 if (USE_QT5)
 178     message(STATUS "Building for Qt5...")
 179     set(QT_MIN_VERSION "5.2.0")
 180     add_definitions(-DHAVE_QT5)
 181
 182     find_package(Qt5Core ${QT_MIN_VERSION} QUIET)
 183     set_package_properties(Qt5Core PROPERTIES TYPE REQUIRED
 184         URL "http://qt.digia.com"
 185         DESCRIPTION "contains core functionality for Qt"
 186     )
 187     # find_package without REQUIRED won't check for the version properly; also, older Qt5 versions
 188     # used Qt5Core_VERSION_STRING... let's just make sure here that we bail out here if our Qt5 is not new enough.
 189     if (NOT Qt5Core_VERSION OR Qt5Core_VERSION VERSION_LESS ${QT_MIN_VERSION})
 190         message(FATAL_ERROR "Could NOT find Qt5 >= version ${QT_MIN_VERSION}!")
 191     endif()
 192
 193     find_package(Qt5Network QUIET)
 194     set_package_properties(Qt5Network PROPERTIES TYPE REQUIRED
 195         DESCRIPTION "the network module for Qt5"
 196     )
 197
 198     if (BUILD_GUI)
 199         find_package(Qt5Gui QUIET)
 200         set_package_properties(Qt5Gui PROPERTIES TYPE REQUIRED
 201             DESCRIPTION "the GUI module for Qt5"
 202         )
 203         find_package(Qt5Widgets QUIET)
 204         set_package_properties(Qt5Widgets PROPERTIES TYPE REQUIRED
 205             DESCRIPTION "the widgets module for Qt5"
 206         )
 207
 208         if (NOT WIN32)
 209             find_package(Qt5DBus QUIET)
 210             set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 211                 URL "http://qt.digia.com"
 212                 DESCRIPTION "D-Bus support for Qt5"
 213                 PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 214             )
 215             if (Qt5DBus_FOUND)
 216                 find_package(dbusmenu-qt5 QUIET CONFIG)
 217                 set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 218                     URL "https://launchpad.net/libdbusmenu-qt"
 219                     DESCRIPTION "a library implementing the DBusMenu specification"
 220                     PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 221                 )
 222             endif()
 223         endif()
 224
 225         find_package(Qt5Multimedia QUIET)
 226         set_package_properties(Qt5Multimedia PROPERTIES TYPE RECOMMENDED
 227             URL "http://qt.digia.com"
 228             DESCRIPTION "Multimedia support for Qt5"
 229             PURPOSE     "Required for audio notifications"
 230         )
 231
 232         if (NOT Qt5Multimedia_FOUND)
 233             find_package(Phonon4Qt5 QUIET)
 234             set_package_properties(Phonon4Qt5 PROPERTIES TYPE RECOMMENDED
 235                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 236                 DESCRIPTION "a multimedia abstraction library"
 237                 PURPOSE     "Required for audio notifications"
 238             )
 239         endif()
 240
 241         find_package(LibsnoreQt5 0.7.0 QUIET)
 242         set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
 243             URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 244             DESCRIPTION "a cross-platform notification framework"
 245             PURPOSE     "Enable support for the snorenotify framework"
 246         )
 247         if(LibsnoreQt5_FOUND)
 248             find_package(LibsnoreSettingsQt5)
 249             set_package_properties(LibsnoreSettingsQt5 PROPERTIES TYPE REQUIRED
 250                 URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 251                 DESCRIPTION "a cross-platform notification framework"
 252                 PURPOSE     "Enable support for the snorenotify framework"
 253             )
 254         endif()
 255
 256
 257         if (WITH_WEBKIT)
 258             find_package(Qt5WebKit QUIET)
 259             set_package_properties(Qt5WebKit PROPERTIES TYPE RECOMMENDED
 260                 URL "http://qt.digia.com"
 261                 DESCRIPTION "a WebKit implementation for Qt"
 262                 PURPOSE     "Needed for displaying previews for URLs in chat"
 263             )
 264             if (Qt5WebKit_FOUND)
 265                 find_package(Qt5WebKitWidgets QUIET)
 266                 set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE RECOMMENDED
 267                     URL "http://qt.digia.com"
 268                     DESCRIPTION "widgets for Qt's WebKit implementation"
 269                     PURPOSE     "Needed for displaying previews for URLs in chat"
 270                 )
 271             endif()
 272         endif()
 273
 274         if (WITH_WEBKIT AND Qt5WebKitWidgets_FOUND)
 275             set(HAVE_WEBKIT true)
 276         endif()
 277         add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" HAVE_WEBKIT "Support showing previews for URLs in chat (legacy)")
 278
 279         if (WITH_WEBENGINE)
 280             find_package(Qt5WebEngine QUIET)
 281             set_package_properties(Qt5WebEngine PROPERTIES TYPE RECOMMENDED
 282                 URL "http://qt.digia.com"
 283                 DESCRIPTION "a WebEngine implementation for Qt"
 284                 PURPOSE     "Needed for displaying previews for URLs in chat"
 285             )
 286             if (Qt5WebEngine_FOUND)
 287                 find_package(Qt5WebEngineWidgets QUIET)
 288                 set_package_properties(Qt5WebEngineWidgets PROPERTIES TYPE RECOMMENDED
 289                     URL "http://qt.digia.com"
 290                     DESCRIPTION "widgets for Qt's WebEngine implementation"
 291                     PURPOSE     "Needed for displaying previews for URLs in chat"
 292                 )
 293             endif()
 294         endif()
 295
 296         if (WITH_WEBENGINE AND Qt5WebEngineWidgets_FOUND)
 297             set(HAVE_WEBENGINE true)
 298         endif()
 299         add_feature_info("WITH_WEBENGINE, QtWebEngine and QtWebEngineWidgets modules" HAVE_WEBENGINE "Support showing previews for URLs in chat")
 300
 301         # KDE Frameworks
 302         ################
 303
 304         if (WITH_KDE)
 305             set(ecm_find_type "REQUIRED")
 306         else()
 307             # Even with KDE integration disabled, we optionally use tier1 frameworks if we find them
 308             set(ecm_find_type "RECOMMENDED")
 309         endif()
 310
 311         # extra-cmake-modules
 312         find_package(ECM NO_MODULE QUIET)
 313         set_package_properties(ECM PROPERTIES TYPE ${ecm_find_type}
 314             URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules"
 315             DESCRIPTION "extra modules for CMake, maintained by the KDE project"
 316             PURPOSE     "Required to find KDE Frameworks components"
 317         )
 318
 319         if (ECM_FOUND)
 320             list(APPEND CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
 321             if (WITH_KDE)
 322                 find_package(KF5 COMPONENTS ConfigWidgets CoreAddons Notifications NotifyConfig TextWidgets WidgetsAddons XmlGui QUIET)
 323                 set_package_properties(KF5 PROPERTIES TYPE REQUIRED
 324                     URL "http://www.kde.org"
 325                     DESCRIPTION "KDE Frameworks"
 326                     PURPOSE     "Required for integration into the Plasma desktop"
 327                 )
 328             else()
 329                 find_package(KF5Sonnet QUIET)
 330                 set_package_properties(KF5Sonnet PROPERTIES TYPE RECOMMENDED
 331                     URL "http://api.kde.org/frameworks-api/frameworks5-apidocs/sonnet/html"
 332                     DESCRIPTION "framework for providing spell-checking capabilities"
 333                     PURPOSE "Enables spell-checking support in input widgets"
 334                 )
 335             endif()
 336         endif()
 337
 338     endif()
 339
 340     if (BUILD_CORE)
 341         find_package(Qt5Script QUIET)
 342         set_package_properties(Qt5Script PROPERTIES TYPE REQUIRED
 343             DESCRIPTION "provides scripting support for Qt5"
 344         )
 345         find_package(Qt5Sql QUIET)
 346         set_package_properties(Qt5Sql PROPERTIES TYPE REQUIRED
 347             DESCRIPTION "the database support module for Qt5"
 348         )
 349
 350         find_package(QCA2-QT5)
 351         set_package_properties(QCA2-QT5 PROPERTIES TYPE RECOMMENDED
 352             URL "https://projects.kde.org/projects/kdesupport/qca"
 353             DESCRIPTION "Qt Cryptographic Architecture"
 354             PURPOSE "Required for encryption support"
 355         )
 356
 357     endif()
 358
 359     find_package(Qt5LinguistTools QUIET)
 360     set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 361                            DESCRIPTION "contains tools for handling translation files"
 362                            PURPOSE "Required for having translations"
 363     )
 364
 365     # Some Qt5 versions do not define a target for lconvert, so we need to find it ourselves
 366     if (Qt5LinguistTools_FOUND)
 367         if (NOT TARGET Qt5::lconvert AND TARGET Qt5::lrelease)
 368             get_target_property(_lrelease_location Qt5::lrelease LOCATION)
 369             get_filename_component(_lrelease_path ${_lrelease_location} PATH)
 370             find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 371         elseif(TARGET Qt5::lconvert AND NOT Qt5_LCONVERT_EXECUTABLE)
 372             # Newer Qt5 versions define the target, but not the Qt5_LCONVERT_EXECUTABLE variable for some reason
 373             get_target_property(QT_LCONVERT_EXECUTABLE Qt5::lconvert LOCATION)
 374         endif()
 375
 376         # Compatibility with the Qt4 variables
 377         set(QT_LRELEASE_EXECUTABLE ${Qt5_LRELEASE_EXECUTABLE})
 378         set(QT_LUPDATE_EXECUTABLE ${Qt5_LUPDATE_EXECUTABLE})
 379         if (Qt5_LCONVERT_EXECUTABLE)
 380             set(QT_LCONVERT_EXECUTABLE ${Qt5_LCONVERT_EXECUTABLE})
 381         endif()
 382     endif()
 383
 384 else()
 385     message(STATUS "Building for Qt4...")
 386     set(QT_MIN_VERSION "4.8.0")
 387
 388     find_package(Qt4 ${QT_MIN_VERSION} QUIET REQUIRED)
 389
 390     if (BUILD_GUI)
 391         add_feature_info("QtDBus module" QT_QTDBUS_FOUND "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments")
 392         if (QT_QTDBUS_FOUND)
 393             find_package(dbusmenu-qt QUIET CONFIG)
 394             set_package_properties(dbusmenu-qt PROPERTIES TYPE RECOMMENDED
 395                 URL "https://launchpad.net/libdbusmenu-qt"
 396                 DESCRIPTION "a library implementing the DBusMenu specification"
 397                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 398             )
 399         endif()
 400
 401         if (WITH_WEBKIT AND QT_QTWEBKIT_FOUND)
 402             set(HAVE_WEBKIT true)
 403         endif()
 404         add_feature_info("WITH_WEBKIT and QtWebKit module" HAVE_WEBKIT "Support showing previews for URLs in chat")
 405
 406         if (WITH_KDE)
 407             # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 408             set(_cflags ${CMAKE_C_FLAGS})
 409             find_package(KDE4 4.4 QUIET)
 410             set_package_properties(KDE4 PROPERTIES TYPE REQUIRED
 411                 URL "http://www.kde.org"
 412                 DESCRIPTION "a world-class desktop environment"
 413                 PURPOSE "Enables various bits for improving integration with KDE"
 414             )
 415             set(CMAKE_C_FLAGS ${_cflags})
 416
 417         else()
 418             find_package(Phonon QUIET)
 419             set_package_properties(Phonon PROPERTIES TYPE RECOMMENDED
 420                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 421                 DESCRIPTION "a multimedia abstraction library"
 422                 PURPOSE     "Required for audio notifications"
 423             )
 424         endif()
 425
 426         find_package(IndicateQt QUIET)
 427         set_package_properties(IndicateQt PROPERTIES TYPE OPTIONAL
 428             URL "https://launchpad.net/libindicate-qt/"
 429             DESCRIPTION "a library to raise flags on DBus for other components of the desktop to pick up and visualize"
 430             PURPOSE     "Provides integration into the Ayatana notification system used by e.g. Ubuntu"
 431         )
 432
 433     endif()
 434
 435     if (BUILD_CORE)
 436
 437         find_package(QCA2 QUIET)
 438         set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 439             URL "https://projects.kde.org/projects/kdesupport/qca"
 440             DESCRIPTION "Qt Cryptographic Architecture"
 441             PURPOSE     "Required for encryption support"
 442         )
 443
 444
 445     endif()
 446
 447     # Qt4 does not consider lconvert relevant, so they don't support finding it...
 448     # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 449     if (QT_LRELEASE_EXECUTABLE)
 450         get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 451         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 452     endif()
 453 endif()
 454
 455
 456 # Non-Qt-based packages
 457
 458 # zlib for compression, however we can always fall back to miniz
 459 find_package(ZLIB QUIET)
 460 set_package_properties(ZLIB PROPERTIES TYPE RECOMMENDED
 461     URL "http://www.zlib.net"
 462     DESCRIPTION "a popular compression library"
 463     PURPOSE     "Use the most common library for protocol compression, instead of the bundled miniz implementation"
 464 )
 465
 466
 467 if (NOT WIN32)
 468     # Execinfo is needed for generating backtraces
 469     find_package(ExecInfo QUIET)
 470     set_package_properties(ExecInfo PROPERTIES TYPE OPTIONAL
 471         DESCRIPTION "a library for inspecting backtraces"
 472         PURPOSE "Used for generating backtraces in case of a crash"
 473     )
 474 endif()
 475
 476 # Check for SSL support in Qt
 477 # As there's no easy way to get Qt's configuration in particular for Qt5, let's just compile
 478 # a small test program checking the defines. This works for both Qt4 and Qt5.
 479 cmake_push_check_state(RESET)
 480 set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES} ${Qt5Core_INCLUDE_DIRS})
 481 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Core_EXECUTABLE_COMPILE_FLAGS}")
 482
 483 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 484     set(CMAKE_REQUIRED_FLAGS "-fPIC -DQT_NO_VERSION_TAGGING")
 485 endif()
 486
 487 check_cxx_source_compiles("
 488     #include \"qglobal.h\"
 489     #if defined QT_NO_SSL
 490     #  error \"No SSL support\"
 491     #endif
 492     int main() {}"
 493     HAVE_SSL)
 494 cmake_pop_check_state()
 495
 496 # Additional compile settings
 497 #####################################################################
 498
 499 # This sets -fPIC and friends if required by the installed Qt5 library
 500 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 501     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 502 endif()
 503
 504 # Needed to compile with mingw without kde
 505 if (MINGW AND NOT KDE4_FOUND)
 506     add_definitions(-D_WIN32_WINNT=0x0500)
 507     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 508     # workaround for bug in mingw gcc 4.0
 509     add_definitions(-U__STRICT_ANSI__)
 510 endif()
 511
 512 # Sanitize compiler flags - old versions of KDE set -ansi, which breaks -std=c++11
 513 if (CMAKE_COMPILER_IS_GNUCXX)
 514     string(REPLACE "-ansi" "" CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS})
 515 endif()
 516
 517
 518 # Setup KDE / KDE Frameworks
 519 #####################################################################
 520
 521 # We want to do this up here, so we have the necessary variables and defines set before
 522 # compiling anything
 523
 524 if (KDE4_FOUND)
 525     # We always use external icons for KDE4 support, since we use its iconloader rather than Qt's
 526     set(EMBED_DATA OFF)
 527
 528     # Better have the compile flags global, even for the core, to avoid problems with linking the mono client
 529     add_definitions(-DHAVE_KDE -DHAVE_KDE4 ${KDE4_DEFINITIONS})
 530     set(WITH_KDE4 TRUE)
 531 endif()
 532
 533 if (USE_QT5 AND WITH_KDE)
 534     # If KDE Frameworks are present, they're most probably providing Qt5 integration including icon loading
 535     set(EMBED_DATA OFF)
 536
 537     include(KDEInstallDirs)
 538     include(KDECompilerSettings)
 539     include(KDECMakeSettings)
 540
 541     add_definitions(-DHAVE_KDE -DHAVE_KF5)
 542     set(WITH_KF5 TRUE)
 543 endif()
 544
 545 # This needs to come after setting up KDE integration, so we can use KDE-specific paths
 546 include(QuasselInstallDirs)
 547
 548 # Various config-dependent checks and settings
 549 #####################################################################
 550
 551 if (NOT ZLIB_FOUND)
 552     message(STATUS "zlib NOT found, using bundled miniz for compression")
 553     if (${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 554         message(STATUS "WARNING: This may be slow on 32 bit systems!")
 555     endif()
 556 endif()
 557
 558 if (HAVE_SSL)
 559     add_definitions(-DHAVE_SSL)
 560 endif()
 561 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 562
 563 # Check for syslog support
 564 if (NOT WIN32)
 565     check_include_file(syslog.h HAVE_SYSLOG)
 566     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 567 endif()
 568
 569 add_feature_info("Qt Linguist Tools" QT_LCONVERT_EXECUTABLE "Translation support for Quassel")
 570
 571 if (EMBED_DATA)
 572     message(STATUS "Embedding data files into the binary")
 573 else()
 574     message(STATUS "Installing data files separately")
 575 endif()
 576
 577 if (INDICATEQT_FOUND)
 578     add_definitions(-DXDG_APPS_INSTALL_DIR=${CMAKE_INSTALL_APPDIR})
 579 endif()
 580
 581 if (NOT WIN32)
 582     check_function_exists(umask HAVE_UMASK)
 583     if(HAVE_UMASK)
 584         add_definitions(-DHAVE_UMASK)
 585     endif()
 586 endif()
 587
 588
 589 # Windows-specific stuff
 590 #####################################################################
 591
 592 if (WIN32)
 593     link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 594     if (MSVC)
 595         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /DNOMINMAX")
 596         set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 597         set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 598         set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 599         link_libraries(Version dwmapi shlwapi)
 600         if (USE_QT5)
 601             set(QT_QTMAIN_LIBRARY Qt5::WinMain)
 602         endif()
 603     endif()
 604     if(HAVE_SSL AND STATIC)
 605         find_package(OpenSSL REQUIRED)
 606         link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 607     endif()
 608 endif()
 609
 610
 611 # Static builds (very much non-portable, so don't use -DSTATIC
 612 # unless you know what you do!)
 613 #####################################################################
 614
 615 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 616     set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 617     link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 618     if (HAVE_SSL)
 619         set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 620     endif()
 621 endif()
 622
 623
 624 # Generate version information from Git
 625 #####################################################################
 626
 627 include(GetGitRevisionDescription)
 628 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 629 git_describe(GIT_DESCRIBE --long)
 630
 631 # If in a Git repo we can get the commit-date from a git command
 632 if (GIT_HEAD)
 633     execute_process(
 634         COMMAND git show -s --format=%ct
 635         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 636         OUTPUT_VARIABLE GIT_COMMIT_DATE
 637         OUTPUT_STRIP_TRAILING_WHITESPACE
 638     )
 639 endif()
 640
 641 # If not in a Git repo try to read GIT_HEAD and GIT_DESCRIBE from
 642 # enviroment
 643 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 644   if (DEFINED ENV{GIT_HEAD})
 645       set(GIT_HEAD $ENV{GIT_HEAD})
 646   endif()
 647   if (DEFINED ENV{GIT_DESCRIBE})
 648      set(GIT_DESCRIBE $ENV{GIT_DESCRIBE})
 649   endif()
 650 endif()
 651
 652 # Sanitize things if we're not in a Git repo
 653 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 654     set(GIT_HEAD "")
 655     set(GIT_DESCRIBE "")
 656     set(GIT_COMMIT_DATE 0)
 657 endif()
 658
 659 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 660
 661 # Prepare the build
 662 #####################################################################
 663
 664 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 665 set(COMMON_DEPS ${RC_WIN32})
 666 set(CORE_DEPS )
 667 set(CLIENT_DEPS )
 668
 669 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 670 add_subdirectory(data)
 671 add_subdirectory(icons)
 672 add_subdirectory(pics)
 673 add_subdirectory(po)
 674
 675
 676 # Set up and display feature summary
 677 #####################################################################
 678
 679 feature_summary(WHAT ALL
 680                 INCLUDE_QUIET_PACKAGES
 681                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 682 )
 683
 684 # Finally, compile the sources
 685 # We want this after displaying the feature summary to avoid ugly
 686 # CMake backtraces in case a required Qt5 module is missing
 687 #####################################################################
 688
 689 add_subdirectory(src)