CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 project(QuasselIRC)
  10
  11 # Versions
  12 set(QUASSEL_MAJOR  0)
  13 set(QUASSEL_MINOR 13)
  14 set(QUASSEL_PATCH  0)
  15 set(QUASSEL_VERSION_STRING "0.13-pre")
  16
  17 # We want to know CMake's version for debug reasons
  18 message(STATUS "Using CMake ${CMAKE_VERSION}")
  19
  20 # Tell CMake about or own modules
  21 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  22
  23 # General conveniences
  24 set(CMAKE_AUTOMOC ON)
  25 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  26
  27 # Include various CMake modules...
  28 include(CMakePushCheckState)
  29 include(CheckFunctionExists)
  30 include(CheckIncludeFile)
  31 include(CheckCXXSourceCompiles)
  32 include(CMakeDependentOption)
  33 include(FeatureSummary)
  34
  35 # ... and our own stuff
  36 include(QuasselCompileSettings)
  37 include(QuasselMacros)
  38
  39
  40 # Options and variables that can be set on the command line
  41 #####################################################################
  42
  43 # First, choose a Qt version. We support USE_QT5 and USE_QT4; if neither is set, Qt5 will be used
  44 option(USE_QT5 "Enable support for Qt5" OFF)
  45 if (USE_QT5) # takes precedence
  46     set(USE_QT4 OFF)
  47 else()
  48     if (NOT USE_QT4)
  49         set(USE_QT5 ON)
  50     endif()
  51 endif()
  52
  53 # Select the binaries to build
  54 option(WANT_CORE     "Build the core (server) binary"           ON)
  55 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  56 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  57 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  58 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  59 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  60
  61 # Whether to enable KDE integration (work in progress for Qt5 / KDE Frameworks)
  62 # Note that when building with Qt5, WITH_KDE enables integration with higher-tier KDE frameworks that
  63 # require runtime support. We still optionally make use of certain Tier 1 frameworks even if WITH_KDE
  64 # is disabled.
  65 if (USE_QT4)
  66     option(WITH_KDE "KDE4 integration" OFF)
  67     add_feature_info(WITH_KDE WITH_KDE "Enable KDE4 integration")
  68 else()
  69     option(WITH_KDE "Integration with the KDE Frameworks runtime environment")
  70     add_feature_info(WITH_KDE WITH_KDE "Integrate with the KDE Frameworks runtime environment")
  71 endif()
  72
  73 cmake_dependent_option(WITH_BREEZE "Install Breeze icon theme (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
  74 cmake_dependent_option(WITH_BREEZE_DARK "Install Dark Breeze icon theme (usually shipped with KDE)" OFF "NOT WITH_KDE" OFF)
  75 cmake_dependent_option(WITH_OXYGEN "Install Oxygen icon theme (usually shipped with KDE)" OFF "NOT WITH_KDE" OFF)
  76 if (NOT WITH_KDE)
  77     add_feature_info(WITH_BREEZE WITH_BREEZE "Install Breeze icon theme")
  78     add_feature_info(WITH_BREEZE_DARK WITH_BREEZE_DARK "Install Dark Breeze icon theme")
  79     add_feature_info(WITH_OXYGEN WITH_OXYGEN "Install Oxygen icon theme")
  80 endif()
  81
  82 if (WITH_OXYGEN)
  83     add_definitions(-DWITH_OXYGEN)
  84 endif()
  85 if (WITH_BREEZE)
  86     add_definitions(-DWITH_BREEZE)
  87 endif()
  88 if (WITH_BREEZE_DARK)
  89     add_definitions(-DWITH_BREEZE_DARK)
  90 endif()
  91
  92 # For this, the feature info is added after we know if QtWebkit is installed
  93 option(WITH_WEBKIT "WebKit support (for link previews) (legacy)" OFF)
  94
  95 # For this, the feature info is added after we know if QtWebEngine is installed
  96 option(WITH_WEBENGINE "WebEngine support (for link previews)" ON)
  97
  98 if (APPLE)
  99     # Notification Center is only available in > 10.8, which is Darwin v12
 100     if (NOT CMAKE_SYSTEM_VERSION VERSION_LESS 12)
 101         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
 102         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
 103     endif()
 104     find_library(CARBON_LIBRARY Carbon)
 105     mark_as_advanced(CARBON_LIBRARY)
 106     link_libraries(${CARBON_LIBRARY})
 107 endif()
 108
 109 # Always embed on Windows, OSX or for a static build; never embed when enabling KDE integration
 110 set(EMBED_DEFAULT OFF)
 111 if (STATIC OR WIN32 OR APPLE)
 112     set(EMBED_DEFAULT ON)
 113 endif()
 114 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
 115                                    "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
 116 if (NOT EMBED_DEFAULT)
 117     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
 118 endif()
 119
 120 # The following options are not for end-user consumption, so don't list them in the feature summary
 121 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
 122
 123 # Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
 124 cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
 125
 126 # For static builds, arbitrary extra libs might need to be linked
 127 # Define a comma-separated list here
 128 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 129 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 130 if (LINK_EXTRA)
 131     string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 132     link_libraries(${LINK_EXTRA})
 133 endif()
 134
 135
 136 # List of authenticators and the cmake flags to build them
 137 # (currently that's just LDAP, but more can be added here).
 138 ####################################################################
 139 option(WITH_LDAP     "Enable LDAP authentication support if present on system"  ON)
 140
 141 # Setup CMake
 142 #####################################################################
 143
 144 if (USE_QT5 AND WITH_KDE)
 145     cmake_minimum_required(VERSION 2.8.12)
 146 else()
 147     cmake_minimum_required(VERSION 2.8.9)
 148 endif()
 149
 150 # Setting COMPILE_DEFINITIONS_<CONFIG> is deprecated since CMake 3.0 in favor of generator expressions.
 151 # These have existed since CMake 2.8.10; until we depend on that, we have to explicitly enable the old policy.
 152 if (POLICY CMP0043)
 153     cmake_policy(SET CMP0043 OLD)
 154 endif()
 155
 156 # Honor visibility settings for all target types
 157 if (POLICY CMP0063)
 158     cmake_policy(SET CMP0063 NEW)
 159 endif()
 160
 161
 162 # Simplify later checks
 163 #####################################################################
 164
 165 if (WANT_MONO OR WANT_QTCLIENT)
 166     set(BUILD_GUI true)
 167 endif()
 168 if (WANT_MONO OR WANT_CORE)
 169     set(BUILD_CORE true)
 170 endif()
 171
 172
 173 # Set up Qt
 174 #####################################################################
 175
 176 # Find package dependencies
 177 #
 178 # Note that you can forcefully disable optional packages
 179 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 180 #####################################################################
 181
 182 if (USE_QT5)
 183     message(STATUS "Building for Qt5...")
 184     set(QT_MIN_VERSION "5.2.0")
 185     add_definitions(-DHAVE_QT5)
 186
 187     find_package(Qt5Core ${QT_MIN_VERSION} QUIET)
 188     set_package_properties(Qt5Core PROPERTIES TYPE REQUIRED
 189         URL "http://qt.digia.com"
 190         DESCRIPTION "contains core functionality for Qt"
 191     )
 192     # find_package without REQUIRED won't check for the version properly; also, older Qt5 versions
 193     # used Qt5Core_VERSION_STRING... let's just make sure here that we bail out here if our Qt5 is not new enough.
 194     if (NOT Qt5Core_VERSION OR Qt5Core_VERSION VERSION_LESS ${QT_MIN_VERSION})
 195         message(FATAL_ERROR "Could NOT find Qt5 >= version ${QT_MIN_VERSION}!")
 196     endif()
 197
 198     find_package(Qt5Network QUIET)
 199     set_package_properties(Qt5Network PROPERTIES TYPE REQUIRED
 200         DESCRIPTION "the network module for Qt5"
 201     )
 202
 203     if (BUILD_GUI)
 204         find_package(Qt5Gui QUIET)
 205         set_package_properties(Qt5Gui PROPERTIES TYPE REQUIRED
 206             DESCRIPTION "the GUI module for Qt5"
 207         )
 208         find_package(Qt5Widgets QUIET)
 209         set_package_properties(Qt5Widgets PROPERTIES TYPE REQUIRED
 210             DESCRIPTION "the widgets module for Qt5"
 211         )
 212
 213         if (NOT WIN32)
 214             find_package(Qt5DBus QUIET)
 215             set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 216                 URL "http://qt.digia.com"
 217                 DESCRIPTION "D-Bus support for Qt5"
 218                 PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 219             )
 220             if (Qt5DBus_FOUND)
 221                 find_package(dbusmenu-qt5 QUIET CONFIG)
 222                 set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 223                     URL "https://launchpad.net/libdbusmenu-qt"
 224                     DESCRIPTION "a library implementing the DBusMenu specification"
 225                     PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 226                 )
 227             endif()
 228         endif()
 229
 230         find_package(Qt5Multimedia QUIET)
 231         set_package_properties(Qt5Multimedia PROPERTIES TYPE RECOMMENDED
 232             URL "http://qt.digia.com"
 233             DESCRIPTION "Multimedia support for Qt5"
 234             PURPOSE     "Required for audio notifications"
 235         )
 236
 237         if (NOT Qt5Multimedia_FOUND)
 238             find_package(Phonon4Qt5 QUIET)
 239             set_package_properties(Phonon4Qt5 PROPERTIES TYPE RECOMMENDED
 240                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 241                 DESCRIPTION "a multimedia abstraction library"
 242                 PURPOSE     "Required for audio notifications"
 243             )
 244         endif()
 245
 246         find_package(LibsnoreQt5 0.7.0 QUIET)
 247         set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
 248             URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 249             DESCRIPTION "a cross-platform notification framework"
 250             PURPOSE     "Enable support for the snorenotify framework"
 251         )
 252         if(LibsnoreQt5_FOUND)
 253             find_package(LibsnoreSettingsQt5)
 254             set_package_properties(LibsnoreSettingsQt5 PROPERTIES TYPE REQUIRED
 255                 URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 256                 DESCRIPTION "a cross-platform notification framework"
 257                 PURPOSE     "Enable support for the snorenotify framework"
 258             )
 259         endif()
 260
 261
 262         if (WITH_WEBKIT)
 263             find_package(Qt5WebKit QUIET)
 264             set_package_properties(Qt5WebKit PROPERTIES TYPE RECOMMENDED
 265                 URL "http://qt.digia.com"
 266                 DESCRIPTION "a WebKit implementation for Qt"
 267                 PURPOSE     "Needed for displaying previews for URLs in chat"
 268             )
 269             if (Qt5WebKit_FOUND)
 270                 find_package(Qt5WebKitWidgets QUIET)
 271                 set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE RECOMMENDED
 272                     URL "http://qt.digia.com"
 273                     DESCRIPTION "widgets for Qt's WebKit implementation"
 274                     PURPOSE     "Needed for displaying previews for URLs in chat"
 275                 )
 276             endif()
 277         endif()
 278
 279         if (WITH_WEBKIT AND Qt5WebKitWidgets_FOUND)
 280             set(HAVE_WEBKIT true)
 281         endif()
 282         add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" HAVE_WEBKIT "Support showing previews for URLs in chat (legacy)")
 283
 284         if (WITH_WEBENGINE)
 285             find_package(Qt5WebEngine QUIET)
 286             set_package_properties(Qt5WebEngine PROPERTIES TYPE RECOMMENDED
 287                 URL "http://qt.digia.com"
 288                 DESCRIPTION "a WebEngine implementation for Qt"
 289                 PURPOSE     "Needed for displaying previews for URLs in chat"
 290             )
 291             if (Qt5WebEngine_FOUND)
 292                 find_package(Qt5WebEngineWidgets QUIET)
 293                 set_package_properties(Qt5WebEngineWidgets PROPERTIES TYPE RECOMMENDED
 294                     URL "http://qt.digia.com"
 295                     DESCRIPTION "widgets for Qt's WebEngine implementation"
 296                     PURPOSE     "Needed for displaying previews for URLs in chat"
 297                 )
 298             endif()
 299         endif()
 300
 301         if (WITH_WEBENGINE AND Qt5WebEngineWidgets_FOUND)
 302             set(HAVE_WEBENGINE true)
 303         endif()
 304         add_feature_info("WITH_WEBENGINE, QtWebEngine and QtWebEngineWidgets modules" HAVE_WEBENGINE "Support showing previews for URLs in chat")
 305
 306         # KDE Frameworks
 307         ################
 308
 309         if (WITH_KDE)
 310             set(ecm_find_type "REQUIRED")
 311         else()
 312             # Even with KDE integration disabled, we optionally use tier1 frameworks if we find them
 313             set(ecm_find_type "RECOMMENDED")
 314         endif()
 315
 316         # extra-cmake-modules
 317         find_package(ECM NO_MODULE QUIET)
 318         set_package_properties(ECM PROPERTIES TYPE ${ecm_find_type}
 319             URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules"
 320             DESCRIPTION "extra modules for CMake, maintained by the KDE project"
 321             PURPOSE     "Required to find KDE Frameworks components"
 322         )
 323
 324         if (ECM_FOUND)
 325             list(APPEND CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
 326             if (WITH_KDE)
 327                 find_package(KF5 COMPONENTS ConfigWidgets CoreAddons Notifications NotifyConfig TextWidgets WidgetsAddons XmlGui QUIET)
 328                 set_package_properties(KF5 PROPERTIES TYPE REQUIRED
 329                     URL "http://www.kde.org"
 330                     DESCRIPTION "KDE Frameworks"
 331                     PURPOSE     "Required for integration into the Plasma desktop"
 332                 )
 333             else()
 334                 find_package(KF5Sonnet QUIET)
 335                 set_package_properties(KF5Sonnet PROPERTIES TYPE RECOMMENDED
 336                     URL "http://api.kde.org/frameworks-api/frameworks5-apidocs/sonnet/html"
 337                     DESCRIPTION "framework for providing spell-checking capabilities"
 338                     PURPOSE "Enables spell-checking support in input widgets"
 339                 )
 340             endif()
 341         endif()
 342
 343     endif()
 344
 345     if (BUILD_CORE)
 346         find_package(Qt5Script QUIET)
 347         set_package_properties(Qt5Script PROPERTIES TYPE REQUIRED
 348             DESCRIPTION "provides scripting support for Qt5"
 349         )
 350         find_package(Qt5Sql QUIET)
 351         set_package_properties(Qt5Sql PROPERTIES TYPE REQUIRED
 352             DESCRIPTION "the database support module for Qt5"
 353         )
 354
 355         find_package(QCA2-QT5)
 356         set_package_properties(QCA2-QT5 PROPERTIES TYPE RECOMMENDED
 357             URL "https://projects.kde.org/projects/kdesupport/qca"
 358             DESCRIPTION "Qt Cryptographic Architecture"
 359             PURPOSE "Required for encryption support"
 360         )
 361
 362     endif()
 363
 364     find_package(Qt5LinguistTools QUIET)
 365     set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 366                            DESCRIPTION "contains tools for handling translation files"
 367                            PURPOSE "Required for having translations"
 368     )
 369
 370     # Some Qt5 versions do not define a target for lconvert, so we need to find it ourselves
 371     if (Qt5LinguistTools_FOUND)
 372         if (NOT TARGET Qt5::lconvert AND TARGET Qt5::lrelease)
 373             get_target_property(_lrelease_location Qt5::lrelease LOCATION)
 374             get_filename_component(_lrelease_path ${_lrelease_location} PATH)
 375             find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 376         elseif(TARGET Qt5::lconvert AND NOT Qt5_LCONVERT_EXECUTABLE)
 377             # Newer Qt5 versions define the target, but not the Qt5_LCONVERT_EXECUTABLE variable for some reason
 378             get_target_property(QT_LCONVERT_EXECUTABLE Qt5::lconvert LOCATION)
 379         endif()
 380
 381         # Compatibility with the Qt4 variables
 382         set(QT_LRELEASE_EXECUTABLE ${Qt5_LRELEASE_EXECUTABLE})
 383         set(QT_LUPDATE_EXECUTABLE ${Qt5_LUPDATE_EXECUTABLE})
 384         if (Qt5_LCONVERT_EXECUTABLE)
 385             set(QT_LCONVERT_EXECUTABLE ${Qt5_LCONVERT_EXECUTABLE})
 386         endif()
 387     endif()
 388
 389 else()
 390     message(STATUS "Building for Qt4...")
 391     set(QT_MIN_VERSION "4.8.0")
 392
 393     find_package(Qt4 ${QT_MIN_VERSION} QUIET REQUIRED)
 394
 395     if (BUILD_GUI)
 396         add_feature_info("QtDBus module" QT_QTDBUS_FOUND "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments")
 397         if (QT_QTDBUS_FOUND)
 398             find_package(dbusmenu-qt QUIET CONFIG)
 399             set_package_properties(dbusmenu-qt PROPERTIES TYPE RECOMMENDED
 400                 URL "https://launchpad.net/libdbusmenu-qt"
 401                 DESCRIPTION "a library implementing the DBusMenu specification"
 402                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 403             )
 404         endif()
 405
 406         if (WITH_WEBKIT AND QT_QTWEBKIT_FOUND)
 407             set(HAVE_WEBKIT true)
 408         endif()
 409         add_feature_info("WITH_WEBKIT and QtWebKit module" HAVE_WEBKIT "Support showing previews for URLs in chat")
 410
 411         if (WITH_KDE)
 412             # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 413             set(_cflags ${CMAKE_C_FLAGS})
 414             find_package(KDE4 4.4 QUIET)
 415             set_package_properties(KDE4 PROPERTIES TYPE REQUIRED
 416                 URL "http://www.kde.org"
 417                 DESCRIPTION "a world-class desktop environment"
 418                 PURPOSE "Enables various bits for improving integration with KDE"
 419             )
 420             set(CMAKE_C_FLAGS ${_cflags})
 421
 422         else()
 423             find_package(Phonon QUIET)
 424             set_package_properties(Phonon PROPERTIES TYPE RECOMMENDED
 425                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 426                 DESCRIPTION "a multimedia abstraction library"
 427                 PURPOSE     "Required for audio notifications"
 428             )
 429         endif()
 430
 431         find_package(IndicateQt QUIET)
 432         set_package_properties(IndicateQt PROPERTIES TYPE OPTIONAL
 433             URL "https://launchpad.net/libindicate-qt/"
 434             DESCRIPTION "a library to raise flags on DBus for other components of the desktop to pick up and visualize"
 435             PURPOSE     "Provides integration into the Ayatana notification system used by e.g. Ubuntu"
 436         )
 437
 438     endif()
 439
 440     if (BUILD_CORE)
 441
 442         find_package(QCA2 QUIET)
 443         set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 444             URL "https://projects.kde.org/projects/kdesupport/qca"
 445             DESCRIPTION "Qt Cryptographic Architecture"
 446             PURPOSE     "Required for encryption support"
 447         )
 448
 449
 450     endif()
 451
 452     # Qt4 does not consider lconvert relevant, so they don't support finding it...
 453     # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 454     if (QT_LRELEASE_EXECUTABLE)
 455         get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 456         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 457     endif()
 458 endif()
 459
 460
 461 # Non-Qt-based packages
 462
 463 # zlib for compression, however we can always fall back to miniz
 464 find_package(ZLIB QUIET)
 465 set_package_properties(ZLIB PROPERTIES TYPE RECOMMENDED
 466     URL "http://www.zlib.net"
 467     DESCRIPTION "a popular compression library"
 468     PURPOSE     "Use the most common library for protocol compression, instead of the bundled miniz implementation"
 469 )
 470
 471
 472 if (NOT WIN32)
 473     # Execinfo is needed for generating backtraces
 474     find_package(ExecInfo QUIET)
 475     set_package_properties(ExecInfo PROPERTIES TYPE OPTIONAL
 476         DESCRIPTION "a library for inspecting backtraces"
 477         PURPOSE "Used for generating backtraces in case of a crash"
 478     )
 479 endif()
 480
 481 # Check for SSL support in Qt
 482 # As there's no easy way to get Qt's configuration in particular for Qt5, let's just compile
 483 # a small test program checking the defines. This works for both Qt4 and Qt5.
 484 cmake_push_check_state(RESET)
 485 set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES} ${Qt5Core_INCLUDE_DIRS})
 486 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Core_EXECUTABLE_COMPILE_FLAGS}")
 487
 488 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 489     set(CMAKE_REQUIRED_FLAGS "-fPIC -DQT_NO_VERSION_TAGGING")
 490 endif()
 491
 492 check_cxx_source_compiles("
 493     #include \"qglobal.h\"
 494     #if defined QT_NO_SSL
 495     #  error \"No SSL support\"
 496     #endif
 497     int main() {}"
 498     HAVE_SSL)
 499 cmake_pop_check_state()
 500
 501 # Additional compile settings
 502 #####################################################################
 503
 504 # This sets -fPIC and friends if required by the installed Qt5 library
 505 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 506     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 507 endif()
 508
 509 # Needed to compile with mingw without kde
 510 if (MINGW AND NOT KDE4_FOUND)
 511     add_definitions(-D_WIN32_WINNT=0x0500)
 512     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 513     # workaround for bug in mingw gcc 4.0
 514     add_definitions(-U__STRICT_ANSI__)
 515 endif()
 516
 517 # Sanitize compiler flags - old versions of KDE set -ansi, which breaks -std=c++11
 518 if (CMAKE_COMPILER_IS_GNUCXX)
 519     string(REPLACE "-ansi" "" CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS})
 520 endif()
 521
 522 # Setup LDAP Authentication support.
 523 #####################################################################
 524 if(WITH_LDAP)
 525     find_package(Ldap)
 526     if(LDAP_FOUND)
 527         message(STATUS "Enabling LDAP authentication support")
 528         set(HAVE_LDAP true)
 529         if(HAVE_LDAP)
 530             add_definitions(-DHAVE_LDAP)
 531         endif(HAVE_LDAP)
 532     else(LDAP_FOUND)
 533         message(STATUS "Disabling LDAP authentication support")
 534     endif(LDAP_FOUND)
 535 else(WITH_LDAP)
 536     message(STATUS "Not enabling LDAP authentication support")
 537 endif(WITH_LDAP)
 538
 539 # Setup KDE / KDE Frameworks
 540 #####################################################################
 541
 542 # We want to do this up here, so we have the necessary variables and defines set before
 543 # compiling anything
 544
 545 if (KDE4_FOUND)
 546     # We always use external icons for KDE4 support, since we use its iconloader rather than Qt's
 547     set(EMBED_DATA OFF)
 548
 549     # Better have the compile flags global, even for the core, to avoid problems with linking the mono client
 550     add_definitions(-DHAVE_KDE -DHAVE_KDE4 ${KDE4_DEFINITIONS})
 551     set(WITH_KDE4 TRUE)
 552 endif()
 553
 554 if (USE_QT5 AND WITH_KDE)
 555     # If KDE Frameworks are present, they're most probably providing Qt5 integration including icon loading
 556     set(EMBED_DATA OFF)
 557
 558     include(KDEInstallDirs)
 559     include(KDECompilerSettings)
 560     include(KDECMakeSettings)
 561
 562     add_definitions(-DHAVE_KDE -DHAVE_KF5)
 563     set(WITH_KF5 TRUE)
 564 endif()
 565
 566 # This needs to come after setting up KDE integration, so we can use KDE-specific paths
 567 include(QuasselInstallDirs)
 568
 569 # Various config-dependent checks and settings
 570 #####################################################################
 571
 572 if (NOT ZLIB_FOUND)
 573     message(STATUS "zlib NOT found, using bundled miniz for compression")
 574     if (${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 575         message(STATUS "WARNING: This may be slow on 32 bit systems!")
 576     endif()
 577 endif()
 578
 579 if (HAVE_SSL)
 580     add_definitions(-DHAVE_SSL)
 581 endif()
 582 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 583
 584 # Check for syslog support
 585 if (NOT WIN32)
 586     check_include_file(syslog.h HAVE_SYSLOG)
 587     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 588 endif()
 589
 590 add_feature_info("Qt Linguist Tools" QT_LCONVERT_EXECUTABLE "Translation support for Quassel")
 591
 592 if (EMBED_DATA)
 593     message(STATUS "Embedding data files into the binary")
 594 else()
 595     message(STATUS "Installing data files separately")
 596 endif()
 597
 598 if (INDICATEQT_FOUND)
 599     add_definitions(-DXDG_APPS_INSTALL_DIR=${CMAKE_INSTALL_APPDIR})
 600 endif()
 601
 602 if (NOT WIN32)
 603     check_function_exists(umask HAVE_UMASK)
 604     if(HAVE_UMASK)
 605         add_definitions(-DHAVE_UMASK)
 606     endif()
 607 endif()
 608
 609
 610 # Windows-specific stuff
 611 #####################################################################
 612
 613 if (WIN32)
 614     link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 615     if (MSVC)
 616         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /DNOMINMAX")
 617         set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 618         set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 619         set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 620         link_libraries(Version dwmapi shlwapi)
 621         if (USE_QT5)
 622             set(QT_QTMAIN_LIBRARY Qt5::WinMain)
 623         endif()
 624     endif()
 625     if(HAVE_SSL AND STATIC)
 626         find_package(OpenSSL REQUIRED)
 627         link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 628     endif()
 629 endif()
 630
 631
 632 # Static builds (very much non-portable, so don't use -DSTATIC
 633 # unless you know what you do!)
 634 #####################################################################
 635
 636 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 637     set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 638     link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 639     if (HAVE_SSL)
 640         set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 641     endif()
 642 endif()
 643
 644
 645 # Generate version information from Git
 646 #####################################################################
 647
 648 include(GetGitRevisionDescription)
 649 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 650 git_describe(GIT_DESCRIBE --long)
 651
 652 # If in a Git repo we can get the commit-date from a git command
 653 if (GIT_HEAD)
 654     execute_process(
 655         COMMAND git show -s --format=%ct
 656         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 657         OUTPUT_VARIABLE GIT_COMMIT_DATE
 658         OUTPUT_STRIP_TRAILING_WHITESPACE
 659     )
 660 endif()
 661
 662 # If not in a Git repo try to read GIT_HEAD and GIT_DESCRIBE from
 663 # enviroment
 664 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 665   if (DEFINED ENV{GIT_HEAD})
 666       set(GIT_HEAD $ENV{GIT_HEAD})
 667   endif()
 668   if (DEFINED ENV{GIT_DESCRIBE})
 669      set(GIT_DESCRIBE $ENV{GIT_DESCRIBE})
 670   endif()
 671 endif()
 672
 673 # Sanitize things if we're not in a Git repo
 674 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 675     set(GIT_HEAD "")
 676     set(GIT_DESCRIBE "")
 677     set(GIT_COMMIT_DATE 0)
 678 endif()
 679
 680 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 681
 682 # Prepare the build
 683 #####################################################################
 684
 685 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 686 set(COMMON_DEPS ${RC_WIN32})
 687 set(CORE_DEPS )
 688 set(CLIENT_DEPS )
 689
 690 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 691 add_subdirectory(data)
 692 add_subdirectory(icons)
 693 add_subdirectory(pics)
 694 add_subdirectory(po)
 695
 696
 697 # Set up and display feature summary
 698 #####################################################################
 699
 700 feature_summary(WHAT ALL
 701                 INCLUDE_QUIET_PACKAGES
 702                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 703 )
 704
 705 # Finally, compile the sources
 706 # We want this after displaying the feature summary to avoid ugly
 707 # CMake backtraces in case a required Qt5 module is missing
 708 #####################################################################
 709
 710 add_subdirectory(src)