CMakeLists.txt

   1 # This is the cmake-based build system for Quassel IRC.
   2 #
   3 # You may pass various options to cmake:
   4 #
   5 # -DWANT_(CORE|QTCLIENT|MONO)=(ON|OFF)
   6 #                        : select binaries to build
   7 # -DWITH_OPENSSL=OFF     : Disable OpenSSL support
   8 # -DWITH_DBUS=OFF        : Disable D-Bus support (dbus notifications)
   9 # -DWITH_WEBKIT=OFF      : Disable WebKit support (link previews)
  10 # -DWITH_PHONON=OFF      : Disable Phonon support (audio notifications)
  11 # -DWITH_LIBINDICATE=OFF : Disable libindicate support (Ayatana notifications)
  12 # -DWITH_KDE=ON          : Enable KDE4 support
  13 # -DWITH_CRYPT=OFF       : Disable encryption support
  14 # -DWITH_OXYGEN=(ON|OFF) : Whether to install Oxygen icons (default: yes, unless KDE > 4.3.0 is present and enabled)
  15 # -DWITH_SYSLOG=OFF      : Disable syslog support
  16 #
  17 # -DEMBED_DATA=ON        : Embed all data files in icons the binary, rather than installing them separately
  18 #
  19 # -DQT=/path/to/qt       : Choose a Qt4 installation to use instead of the system Qt4
  20 # -DSTATIC=ON            : Enable static building of Quassel. Use with care.
  21 # -DDEPLOY=ON            : Mac OS X only. Use only for creating Quassel Packages!
  22 #
  23 # -DWITH_QT5=ON          : Enable (very) experimental support for Qt5 (see doc/README.Qt5!)
  24 #
  25 # NOTE: You should remove CMakeCache.txt if you plan to change any of these values!
  26
  27
  28 project(QuasselIRC)
  29
  30 include(CheckFunctionExists)
  31 include(CheckIncludeFile)
  32 include(CheckCXXCompilerFlag)
  33
  34 # For building against Qt5, we check for an even newer cmake version below!
  35 cmake_minimum_required(VERSION 2.8.1 FATAL_ERROR)
  36
  37 if(COMMAND cmake_policy)
  38    cmake_policy(SET CMP0003 NEW)
  39 endif(COMMAND cmake_policy)
  40
  41 # Use our own (well, and KDE's) version of some modules
  42 # In particular cmake's own FindQt4 and FindOpenSSL are quite buggy
  43 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  44 include(QuasselMacros)
  45
  46 # Various options and variables that can be set on the command line
  47 option(WANT_CORE     "Build the core (server) binary"           ON)
  48 option(WANT_QTCLIENT "Build the Qt4 GUI client binary"          ON)
  49 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  50
  51 option(WITH_OPENSSL  "Enable OpenSSL support if present on the system"  ON)
  52 option(WITH_DBUS     "Enable D-Bus support if present on the system"    ON)
  53 option(WITH_WEBKIT   "Enable WebKit support (for link previews)"        ON)
  54 option(WITH_PHONON   "Enable Phonon support (for audio notifications)"  ON)
  55 option(WITH_LIBINDICATE "Enable Ayatana notification support"           ON)
  56 option(WITH_KDE      "Enable KDE4 integration"                          OFF)
  57 option(WITH_CRYPT    "Enable encryption support if present on system"   ON)
  58 option(WITH_SYSLOG   "Use syslog for storing log data"                  ON)
  59
  60 # We use icon paths from KDE 4.3.x, which are partially invalid on older and possibly
  61 # even on newer KDE versions. Do not disable this unless you are sure that your Quassel will
  62 # run on a matching KDE version only.
  63 set(WITH_OXYGEN AUTO CACHE STRING "Install Oxygen icons (default is \"AUTO\" to install when KDE 4.3 or later is present")
  64
  65 # Enable very experimental support for Qt5. Might break the compilation, or even more!
  66 option(WITH_QT5      "Enable (very) experimental support for Qt5"       OFF)
  67
  68 option(STATIC        "Enable static building (might not be portable)" OFF)
  69
  70 if(APPLE)
  71   option(DEPLOY        "Mac OS X only! Adds required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF)
  72   option(WITH_NOTIFICATION_CENTER "Enable OS X Notification Center support" ON)
  73 endif(APPLE)
  74
  75 # Default to embedding data in the static case
  76 if(STATIC OR WIN32)
  77   set(EMBED_DEFAULT ON)
  78 else(STATIC OR WIN32)
  79   set(EMBED_DEFAULT ON) # should be OFF as soon as everything works
  80 endif(STATIC OR WIN32)
  81
  82 option(EMBED_DATA    "Embed all data files in the binary (rather than installing them separately)"   ${EMBED_DEFAULT})
  83
  84 set(QT "" CACHE STRING "Path to a Qt installation to use instead of the system Qt (e.g. for static builds)")
  85
  86 # Some settings imply others
  87 if(STATIC)
  88   add_definitions(-DSTATIC)
  89   set(WITH_KDE OFF CACHE BOOL "Static building with KDE is not supported")
  90 endif(STATIC)
  91
  92 if(WIN32)
  93   # We don't support separately installed resources yet on Win32
  94   set(EMBED_DATA ON)
  95 endif(WIN32)
  96
  97 # For static builds, arbitrary extra libs might need to be linked
  98 # Define a comma-separated list here
  99 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 100 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 101 if(LINK_EXTRA)
 102   string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 103   link_libraries(${LINK_EXTRA})
 104 endif(LINK_EXTRA)
 105
 106 # Build Types
 107
 108 if(CMAKE_CONFIGURATION_TYPES)
 109    set(CMAKE_CONFIGURATION_TYPES Release RelWithDebInfo Debug Debugfull Profile MinSizeRel)
 110    set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 111      "Reset the configurations to what we need"
 112      FORCE)
 113 endif()
 114
 115 if(NOT CMAKE_BUILD_TYPE)
 116   SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 117      "Choose the type of build, options are: None Debug Release RelWithDebInfo Debug Debugfull Profile MinSizeRel."
 118      FORCE)
 119 endif()
 120
 121 # Qt debug flags
 122 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_DEBUG QT_DEBUG)
 123 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_DEBUGFULL QT_DEBUG)
 124 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_RELEASE QT_NO_DEBUG NDEBUG)
 125 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_RELWITHDEBINFO QT_NO_DEBUG NDEBUG)
 126 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_PROFILE QT_NO_DEBUG NDEBUG)
 127 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_MINSIZEREL QT_NO_DEBUG NDEBUG)
 128
 129 if(NOT CMAKE_CONFIGURATION_TYPES AND NOT CMAKE_BUILD_TYPE)
 130   set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_DEBUG NDEBUG)
 131 endif()
 132
 133 # Enable various flags on gcc
 134 if(CMAKE_COMPILER_IS_GNUCXX)
 135   # Let's just hope that all gccs support these options and skip the tests...
 136   # -fno-strict-aliasing is needed apparently for Qt < 4.6
 137   set(CMAKE_CXX_FLAGS                  "${CMAKE_CXX_FLAGS} -ansi -Wall -Wextra -Wnon-virtual-dtor -fno-strict-aliasing")
 138 #  set(CMAKE_CXX_FLAGS_RELEASE          "-O2")   # use CMake default
 139 #  set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "-g -O2")  # use CMake default
 140   set(CMAKE_CXX_FLAGS_DEBUG             "-g -ggdb -O2 -fno-reorder-blocks -fno-schedule-insns -fno-inline")
 141   set(CMAKE_CXX_FLAGS_DEBUGFULL         "-g3 -ggdb -fno-inline")
 142   set(CMAKE_CXX_FLAGS_PROFILE           "-g3 -ggdb -fno-inline -ftest-coverage -fprofile-arcs")
 143
 144   set(CMAKE_CXX_FLAGS                  "${CMAKE_CXX_FLAGS} -ansi -W -Wall -Wextra -Wnon-virtual-dtor -fno-strict-aliasing -Wundef -Wcast-align -Wpointer-arith -Wformat-security -fno-check-new -fno-common")
 145
 146   check_cxx_compiler_flag(-Woverloaded-virtual CXX_W_OVERLOADED_VIRTUAL)
 147   if(CXX_W_OVERLOADED_VIRTUAL)
 148     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Woverloaded-virtual")
 149   endif()
 150 endif(CMAKE_COMPILER_IS_GNUCXX)
 151
 152 # Mac build stuff
 153 if(APPLE AND DEPLOY)
 154   set(CMAKE_OSX_ARCHITECTURES "x86_64")
 155   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.6")
 156   set(CMAKE_OSX_SYSROOT "/Developer/SDKs/MacOSX10.6.sdk/")
 157   add_definitions(-DMAC_10_6_SDK)
 158 endif(APPLE AND DEPLOY)
 159
 160 # Simplify checks
 161 if(WANT_MONO OR WANT_QTCLIENT)
 162   set(BUILD_GUI true)
 163 endif(WANT_MONO OR WANT_QTCLIENT)
 164 if(WANT_MONO OR WANT_CORE)
 165   set(BUILD_CORE true)
 166 endif(WANT_MONO OR WANT_CORE)
 167
 168
 169 # Version checks
 170 ################
 171
 172 if(WITH_QT5)
 173   set(QT_MIN_VERSION "5.0.0")
 174   add_definitions(-DHAVE_QT5)
 175
 176   # Qt5 needs a new enough cmake...
 177   cmake_minimum_required(VERSION 2.8.6 FATAL_ERROR)
 178
 179   # ... for automoc
 180   set(CMAKE_AUTOMOC ON)
 181 else(WITH_QT5)
 182
 183   # GUI stuff needs some new features
 184   if(BUILD_GUI)
 185     set(QT_MIN_VERSION "4.6.0")
 186   else(BUILD_GUI)
 187     set(QT_MIN_VERSION "4.4.0")
 188   endif(BUILD_GUI)
 189 endif(WITH_QT5)
 190
 191
 192 # Dependencies
 193 ##############
 194
 195 if(WITH_QT5)
 196   find_package(Qt5Core ${QT_MIN_VERSION} REQUIRED)
 197   # We need QtWidgets
 198   set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} Widgets)
 199
 200   # Setup the i18n-related variables
 201   find_package(Qt5LinguistTools)
 202
 203 else(WITH_QT5)
 204   # Select a Qt installation here, if you don't want to use system Qt
 205   if(QT)
 206     # FindQt4 will look for the qmake binary in $PATH, so we just prepend the Qt dir
 207     set(ENV{PATH} ${QT}/bin:$ENV{PATH})
 208   endif(QT)
 209
 210   # Now that we have the correct $PATH, lets find Qt!
 211   find_package(Qt4 ${QT_MIN_VERSION} REQUIRED)
 212 endif(WITH_QT5)
 213
 214
 215 # Neither Qt4 nor Qt5 consider lconvert relevant, so they don't support finding it...
 216 # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 217 if(QT_LRELEASE_EXECUTABLE)
 218   get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 219   if(WITH_QT5)
 220     find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 221   else(WITH_QT5)
 222     find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 223   endif(WITH_QT5)
 224 endif(QT_LRELEASE_EXECUTABLE)
 225
 226
 227 # Execinfo is needed for generating backtraces
 228 find_package(ExecInfo)
 229 if(EXECINFO_FOUND)
 230   add_definitions(-DHAVE_EXECINFO)
 231   include_directories(${EXECINFO_INCLUDES})
 232   link_libraries(${EXECINFO_LIBRARIES})
 233 endif(EXECINFO_FOUND)
 234
 235
 236 # PkgConfig isn't strictly required.
 237 # However, some optional deps might not be found if it's not present, so warn!
 238 find_package(PkgConfig)
 239 if(NOT PKG_CONFIG_FOUND)
 240   message(STATUS "WARNING: PkgConfig not available! Some dependencies for optional features might not be found.")
 241   message(STATUS "         Affected features might include encryption support, DBus menus and Ayatana notifications.")
 242 endif(NOT PKG_CONFIG_FOUND)
 243
 244
 245 # Setup OpenSSL
 246 # We don't link to or include OpenSSL ourselves, but use exclusively the Qt API.
 247 # Thus, we simply check if OpenSSL support is present in Qt's config and enable our
 248 # own SSL stuff in this case. Qt should care for adding what it needs itself.
 249 if(WITH_OPENSSL)
 250   if(QT_QCONFIG MATCHES "openssl")
 251     message(STATUS "Found OpenSSL support in Qt, enabling SSL")
 252     add_definitions(-DHAVE_SSL)
 253     set(HAVE_SSL true)
 254   else(QT_QCONFIG MATCHES "openssl")
 255     message(STATUS "No OpenSSL support found in Qt, disabling SSL")
 256     add_definitions(-DQT_NO_OPENSSL)
 257   endif(QT_QCONFIG MATCHES "openssl")
 258 else(WITH_OPENSSL)
 259   message(STATUS "Not enabling OpenSSL support")
 260 endif(WITH_OPENSSL)
 261
 262
 263 # Check for GUI specific stuff
 264 if(BUILD_GUI)
 265
 266   # Setup D-Bus support
 267   if(WITH_DBUS)
 268     if(WITH_QT5)
 269       find_package(Qt5DBus ${QT_MIN_VERSION})
 270       find_package(Qt5DBusTools)
 271     endif(WITH_QT5)
 272
 273     if(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 274       message(STATUS "Found QtDBus, enabling D-Bus support")
 275       add_definitions(-DHAVE_DBUS)
 276       set(HAVE_DBUS true)
 277       set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} DBus)
 278
 279       # check if we have dbusmenu as well
 280       if(NOT WITH_QT5)
 281         find_package(DBusMenuQt)
 282         if(DBUSMENUQT_FOUND)
 283           message(STATUS "Enabling support for exporting the tray menu via D-Bus")
 284           add_definitions(-DHAVE_DBUSMENU)
 285           include_directories(${DBUSMENUQT_INCLUDE_DIR})
 286           set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${DBUSMENUQT_LIBRARIES})
 287           set(CLIENT_COMPILE_FLAGS "${CLIENT_COMPILE_FLAGS} ${DBUSMENUQT_DEFINITIONS}")
 288         else(DBUSMENUQT_FOUND)
 289           message(STATUS "Disabling support for exporting the tray menu via D-Bus")
 290         endif(DBUSMENUQT_FOUND)
 291       endif(NOT WITH_QT5)
 292
 293     else(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 294       message(STATUS "QtDBus not found, disabling D-Bus support")
 295     endif(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 296   else(WITH_DBUS)
 297     message(STATUS "Not enabling D-Bus support")
 298   endif(WITH_DBUS)
 299
 300   # Setup QtWebkit support
 301   if(WITH_WEBKIT)
 302     if(WITH_QT5)
 303       find_package(Qt5Webkit ${QT_MIN_VERSION} QUIET)
 304     endif(WITH_QT5)
 305     if(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 306       message(STATUS "Found QtWebKit, enabling WebKit support")
 307       add_definitions(-DHAVE_WEBKIT)
 308       set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} Webkit XmlPatterns)
 309       set(HAVE_WEBKIT true)
 310     else(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 311       message(STATUS "QtWebkit not found, disabling Webkit support")
 312     endif(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 313   else(WITH_WEBKIT)
 314     message(STATUS "Not enabling Webkit support")
 315   endif(WITH_WEBKIT)
 316
 317   # Setup KDE4 support
 318   if(WITH_KDE AND NOT WITH_QT5)
 319     find_package(KDE4)
 320     if(KDE4_FOUND)
 321       message(STATUS "Enabling KDE4 integration")
 322       include_directories(${KDE4_INCLUDES})
 323       add_definitions(-DHAVE_KDE ${KDE4_DEFINITIONS})
 324       set(HAVE_KDE 1)
 325       set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${KDE4_KDECORE_LIBS} ${KDE4_KDEUI_LIBRARY} ${KDE4_SOLID_LIBS} knotifyconfig)
 326       # We always use external icons for KDE4 support, since we use its iconloader rather than our own
 327       set(EMBED_DATA OFF)
 328     else(KDE4_FOUND)
 329       message(STATUS "KDE4 not found, disabling KDE integration")
 330     endif(KDE4_FOUND)
 331   else(WITH_KDE AND NOT WITH_QT5)
 332     message(STATUS "Not enabling KDE4 integration")
 333   endif(WITH_KDE AND NOT WITH_QT5)
 334
 335   # Setup Phonon support - we only need this if we don't have or want KDE4
 336   if(NOT HAVE_KDE)
 337     if(WITH_PHONON)
 338       if(WITH_QT5)
 339         find_package(Qt5phonon)
 340         if(Qt5phonon_FOUND)
 341           message(STATUS "Enabling Phonon support")
 342           add_definitions(-DHAVE_PHONON)
 343           set(HAVE_PHONON true)
 344           set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} phonon)
 345         else(Qt5phonon_FOUND)
 346           message(STATUS "Phonon not found, disabling audio notifications")
 347         endif(Qt5phonon_FOUND)
 348       else(WITH_QT5)
 349         find_package(Phonon)
 350         if(PHONON_FOUND)
 351           message(STATUS "Enabling Phonon support")
 352           add_definitions(-DHAVE_PHONON)
 353           include_directories(${PHONON_INCLUDES})
 354           set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${PHONON_LIBS})
 355           set(HAVE_PHONON true)
 356         else(PHONON_FOUND)
 357           message(STATUS "Phonon not found, disabling audio notifications")
 358         endif(PHONON_FOUND)
 359       endif(WITH_QT5)
 360     else(WITH_PHONON)
 361       message(STATUS "Not enabling Phonon support")
 362     endif(WITH_PHONON)
 363   endif(NOT HAVE_KDE)
 364
 365   # Setup libindicate-qt support
 366   if(WITH_LIBINDICATE AND NOT WITH_QT5)
 367     pkg_check_modules(INDICATEQT QUIET indicate-qt>=0.2.1)
 368     if(INDICATEQT_FOUND)
 369       message(STATUS "Enabling Ayatana notification support")
 370       set(HAVE_INDICATEQT true)
 371       add_definitions(-DHAVE_INDICATEQT)
 372       link_directories(${INDICATEQT_LIBRARY_DIRS})
 373       set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${INDICATEQT_LIBRARIES})
 374     else(INDICATEQT_FOUND)
 375       message(STATUS "Disabling Ayatana notification support")
 376     endif(INDICATEQT_FOUND)
 377   else(WITH_LIBINDICATE AND NOT WITH_QT5)
 378     message(STATUS "Not enabling Ayatana notification support")
 379     # We don't want to link against it even if another package has found it
 380     set(INDICATEQT_LIBRARIES "")
 381   endif(WITH_LIBINDICATE AND NOT WITH_QT5)
 382
 383   # Setup OS X notification center support
 384   if(WITH_NOTIFICATION_CENTER AND APPLE)
 385     set(HAVE_NOTIFICATION_CENTER true)
 386     add_definitions(-DHAVE_NOTIFICATION_CENTER)
 387     set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES}
 388       /System/Library/Frameworks/Foundation.framework
 389     )
 390   endif()
 391
 392 endif(BUILD_GUI)
 393
 394 # Core-only deps
 395 if(BUILD_CORE)
 396
 397   # Setup encryption support
 398   if(WITH_CRYPT AND NOT WITH_QT5)
 399     find_package(QCA2)
 400     if(QCA2_FOUND)
 401       message(STATUS "Enabling encryption support")
 402       add_definitions(-DHAVE_QCA2)
 403       set(LINK_QCA2 QCA2)
 404       set(HAVE_QCA2 true)
 405       set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_QCA2)
 406     else(QCA2_FOUND)
 407       message(STATUS "Disabling encryption support")
 408     endif(QCA2_FOUND)
 409   else(WITH_CRYPT AND NOT WITH_QT5)
 410     message(STATUS "Not enabling encryption support")
 411   endif(WITH_CRYPT AND NOT WITH_QT5)
 412
 413   # Setup syslog support
 414   if(WITH_SYSLOG)
 415     check_include_file(syslog.h HAVE_SYSLOG_H)
 416     if(HAVE_SYSLOG_H)
 417       message(STATUS "Enabling syslog support")
 418       set(HAVE_SYSLOG true)
 419       add_definitions(-DHAVE_SYSLOG)
 420     else(HAVE_SYSLOG_H)
 421       message(STATUS "Disabling syslog support")
 422     endif(HAVE_SYSLOG_H)
 423   else(WITH_SYSLOG)
 424     message(STATUS "Not enabling syslog support")
 425   endif(WITH_SYSLOG)
 426
 427 endif(BUILD_CORE)
 428
 429
 430 # Various settings
 431 ##################
 432
 433 # needed to compile with mingw without kde
 434 if(MINGW AND NOT HAVE_KDE)
 435     add_definitions(-D_WIN32_WINNT=0x0500)
 436     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 437 # workaround for bug in mingw gcc 4.0
 438     add_definitions(-U__STRICT_ANSI__)
 439 endif(MINGW AND NOT HAVE_KDE)
 440
 441 # Now set up install locations; those are set by KDE if integration is enabled
 442 if(NOT HAVE_KDE)
 443   if(WIN32)
 444     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX} CACHE FILEPATH "Install path for binaries")
 445     set(DATA_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/apps CACHE FILEPATH "Install path for data files")
 446     set(ICON_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/icons CACHE FILEPATH "Global icon install path")
 447     set(XDG_APPS_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/applications CACHE FILEPATH "Install path for .desktop files")
 448   else(WIN32)
 449     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin CACHE FILEPATH "Install path for binaries")
 450     set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps CACHE FILEPATH "Install path for data files")
 451     set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons CACHE FILEPATH "Global icon install path")
 452     set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications CACHE FILEPATH "Install path for .desktop files")
 453   endif(WIN32)
 454 endif(NOT HAVE_KDE)
 455
 456 if(EMBED_DATA)
 457   message(STATUS "Embedding data files into the binary")
 458 else(EMBED_DATA)
 459   message(STATUS "Installing data files separately")
 460 endif(EMBED_DATA)
 461
 462 # RPATH needs to be set correctly
 463 # Do this down here, since otherwise KDE wants to handle it itself, and fails
 464 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
 465 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
 466
 467 # Set global buildflags
 468 # This is very much non-portable, so don't use -DSTATIC until you know what
 469 # you do.
 470 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 471   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 472   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 473   if(HAVE_SSL)
 474     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 475   endif(HAVE_SSL)
 476 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 477
 478 if(WIN32)
 479   link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 480   if(MSVC)
 481     set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 482     set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 483     set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 484     link_libraries(Version dwmapi shlwapi)
 485   endif(MSVC)
 486   if(HAVE_SSL AND STATIC)
 487      find_package(OpenSSL REQUIRED)
 488      link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 489   endif(HAVE_SSL AND STATIC)
 490 endif(WIN32)
 491
 492 if(HAVE_INDICATEQT)
 493   add_definitions(-DXDG_APPS_INSTALL_DIR=${XDG_APPS_INSTALL_DIR})
 494 endif(HAVE_INDICATEQT)
 495
 496 if(NOT WIN32)
 497   check_function_exists(umask HAVE_UMASK)
 498   if(HAVE_UMASK)
 499     add_definitions(-DHAVE_UMASK)
 500   endif(HAVE_UMASK)
 501 endif(NOT WIN32)
 502
 503 # We need to create a version.gen
 504 # For this, we create our genversion binary and make sure it is run every time.
 505
 506 setup_qt_variables()
 507 include_directories(${QUASSEL_QT_INCLUDES})
 508
 509 add_executable(genversion ${CMAKE_SOURCE_DIR}/src/common/genversion.cpp)
 510 target_link_libraries(genversion ${QUASSEL_QT_LIBRARIES})
 511 set_target_properties(genversion PROPERTIES COMPILE_FLAGS "${QUASSEL_QT_COMPILEFLAGS}")
 512
 513 get_target_property(GENVERSION_EXECUTABLE genversion LOCATION)
 514 add_custom_target(genversion_run ALL ${GENVERSION_EXECUTABLE}
 515                   ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR}/src/version.gen)
 516 add_dependencies(genversion_run genversion)
 517
 518 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 519 set(COMMON_DEPS ${RC_WIN32})
 520 set(CORE_DEPS )
 521 set(CLIENT_DEPS )
 522
 523 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 524 add_subdirectory(data)
 525 add_subdirectory(icons)
 526 add_subdirectory(pics)
 527 add_subdirectory(po)
 528 add_subdirectory(src)