CMakeLists.txt

   1 # This is the cmake-based build system for Quassel IRC.
   2 #
   3 # You may pass various options to cmake:
   4 #
   5 # -DWANT_(CORE|QTCLIENT|MONO)=(ON|OFF)
   6 #                        : select binaries to build
   7 # -DWITH_OPENSSL=OFF     : Disable OpenSSL support
   8 # -DWITH_DBUS=OFF        : Disable D-Bus support (dbus notifications)
   9 # -DWITH_WEBKIT=OFF      : Disable WebKit support (link previews)
  10 # -DWITH_PHONON=OFF      : Disable Phonon support (audio notifications)
  11 # -DWITH_LIBINDICATE=OFF : Disable libindicate support (Ayatana notifications)
  12 # -DWITH_KDE=ON          : Enable KDE4 support
  13 # -DWITH_CRYPT=OFF       : Disable encryption support
  14 # -DWITH_OXYGEN=(ON|OFF) : Whether to install Oxygen icons (default: yes, unless KDE > 4.3.0 is present and enabled)
  15 # -DWITH_SYSLOG=OFF      : Disable syslog support
  16 #
  17 # -DEMBED_DATA=ON        : Embed all data files in icons the binary, rather than installing them separately
  18 #
  19 # -DQT=/path/to/qt       : Choose a Qt4 installation to use instead of the system Qt4
  20 # -DSTATIC=ON            : Enable static building of Quassel. Use with care.
  21 # -DDEPLOY=ON            : Mac OS X only. Use only for creating Quassel Packages!
  22 #
  23 # -DWITH_QT5=ON          : Enable (very) experimental support for Qt5 (see doc/README.Qt5!)
  24 #
  25 # NOTE: You should remove CMakeCache.txt if you plan to change any of these values!
  26
  27
  28 project(QuasselIRC)
  29
  30 include(CheckFunctionExists)
  31 include(CheckIncludeFile)
  32 include(CheckCXXCompilerFlag)
  33
  34 # For building against Qt5, we check for an even newer cmake version below!
  35 cmake_minimum_required(VERSION 2.8.1 FATAL_ERROR)
  36
  37 if(COMMAND cmake_policy)
  38    cmake_policy(SET CMP0003 NEW)
  39 endif(COMMAND cmake_policy)
  40
  41 # Use our own (well, and KDE's) version of some modules
  42 # In particular cmake's own FindQt4 and FindOpenSSL are quite buggy
  43 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  44 include(QuasselMacros)
  45
  46 # Various options and variables that can be set on the command line
  47 option(WANT_CORE     "Build the core (server) binary"           ON)
  48 option(WANT_QTCLIENT "Build the Qt4 GUI client binary"          ON)
  49 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  50
  51 option(WITH_OPENSSL  "Enable OpenSSL support if present on the system"  ON)
  52 option(WITH_DBUS     "Enable D-Bus support if present on the system"    ON)
  53 option(WITH_WEBKIT   "Enable WebKit support (for link previews)"        ON)
  54 option(WITH_PHONON   "Enable Phonon support (for audio notifications)"  ON)
  55 option(WITH_LIBINDICATE "Enable Ayatana notification support"           ON)
  56 option(WITH_KDE      "Enable KDE4 integration"                          OFF)
  57 option(WITH_CRYPT    "Enable encryption support if present on system"   ON)
  58 option(WITH_SYSLOG   "Use syslog for storing log data"                  ON)
  59
  60 # We use icon paths from KDE 4.3.x, which are partially invalid on older and possibly
  61 # even on newer KDE versions. Do not disable this unless you are sure that your Quassel will
  62 # run on a matching KDE version only.
  63 set(WITH_OXYGEN AUTO CACHE STRING "Install Oxygen icons (default is \"AUTO\" to install when KDE 4.3 or later is present")
  64
  65 # Enable very experimental support for Qt5. Might break the compilation, or even more!
  66 option(WITH_QT5      "Enable (very) experimental support for Qt5"       OFF)
  67
  68 option(STATIC        "Enable static building (might not be portable)" OFF)
  69
  70 if(APPLE)
  71   option(DEPLOY        "Mac OS X only! Adds required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF)
  72   # Notification Center is only available in > 10.8, which is Darwin v12
  73   if(CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  74     option(WITH_NOTIFICATION_CENTER "Enable OS X Notification Center support" ON)
  75   endif(CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  76 endif(APPLE)
  77
  78 # Default to embedding data in the static case
  79 if(STATIC OR WIN32)
  80   set(EMBED_DEFAULT ON)
  81 else(STATIC OR WIN32)
  82   set(EMBED_DEFAULT ON) # should be OFF as soon as everything works
  83 endif(STATIC OR WIN32)
  84
  85 option(EMBED_DATA    "Embed all data files in the binary (rather than installing them separately)"   ${EMBED_DEFAULT})
  86
  87 set(QT "" CACHE STRING "Path to a Qt installation to use instead of the system Qt (e.g. for static builds)")
  88
  89 # Some settings imply others
  90 if(STATIC)
  91   add_definitions(-DSTATIC)
  92   set(WITH_KDE OFF CACHE BOOL "Static building with KDE is not supported")
  93 endif(STATIC)
  94
  95 if(WIN32)
  96   # We don't support separately installed resources yet on Win32
  97   set(EMBED_DATA ON)
  98 endif(WIN32)
  99
 100 # For static builds, arbitrary extra libs might need to be linked
 101 # Define a comma-separated list here
 102 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 103 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 104 if(LINK_EXTRA)
 105   string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 106   link_libraries(${LINK_EXTRA})
 107 endif(LINK_EXTRA)
 108
 109 # Build Types
 110
 111 if(CMAKE_CONFIGURATION_TYPES)
 112    set(CMAKE_CONFIGURATION_TYPES Release RelWithDebInfo Debug Debugfull Profile MinSizeRel)
 113    set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 114      "Reset the configurations to what we need"
 115      FORCE)
 116 endif()
 117
 118 if(NOT CMAKE_BUILD_TYPE)
 119   SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 120      "Choose the type of build, options are: None Debug Release RelWithDebInfo Debug Debugfull Profile MinSizeRel."
 121      FORCE)
 122 endif()
 123
 124 # Qt debug flags
 125 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_DEBUG QT_DEBUG)
 126 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_DEBUGFULL QT_DEBUG)
 127 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_RELEASE QT_NO_DEBUG NDEBUG)
 128 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_RELWITHDEBINFO QT_NO_DEBUG NDEBUG)
 129 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_PROFILE QT_NO_DEBUG NDEBUG)
 130 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_MINSIZEREL QT_NO_DEBUG NDEBUG)
 131
 132 if(NOT CMAKE_CONFIGURATION_TYPES AND NOT CMAKE_BUILD_TYPE)
 133   set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_DEBUG NDEBUG)
 134 endif()
 135
 136 # Enable various flags on gcc
 137 if(CMAKE_COMPILER_IS_GNUCXX)
 138   # Let's just hope that all gccs support these options and skip the tests...
 139   # -fno-strict-aliasing is needed apparently for Qt < 4.6
 140   set(CMAKE_CXX_FLAGS                  "${CMAKE_CXX_FLAGS} -ansi -Wall -Wextra -Wnon-virtual-dtor -fno-strict-aliasing")
 141 #  set(CMAKE_CXX_FLAGS_RELEASE          "-O2")   # use CMake default
 142 #  set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "-g -O2")  # use CMake default
 143   set(CMAKE_CXX_FLAGS_DEBUG             "-g -ggdb -O2 -fno-reorder-blocks -fno-schedule-insns -fno-inline")
 144   set(CMAKE_CXX_FLAGS_DEBUGFULL         "-g3 -ggdb -fno-inline")
 145   set(CMAKE_CXX_FLAGS_PROFILE           "-g3 -ggdb -fno-inline -ftest-coverage -fprofile-arcs")
 146
 147   set(CMAKE_CXX_FLAGS                  "${CMAKE_CXX_FLAGS} -ansi -W -Wall -Wextra -Wnon-virtual-dtor -fno-strict-aliasing -Wundef -Wcast-align -Wpointer-arith -Wformat-security -fno-check-new -fno-common")
 148
 149   check_cxx_compiler_flag(-Woverloaded-virtual CXX_W_OVERLOADED_VIRTUAL)
 150   if(CXX_W_OVERLOADED_VIRTUAL)
 151     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Woverloaded-virtual")
 152   endif()
 153
 154   # Just for miniz
 155   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-unused-function -fno-strict-aliasing")
 156 endif(CMAKE_COMPILER_IS_GNUCXX)
 157
 158 # ... and for Clang
 159 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 160   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wnon-virtual-dtor -Wno-long-long -Wundef -Wcast-align -Wchar-subscripts -Wall -W -Wextra -Wpointer-arith -Wformat-security -Woverloaded-virtual -fno-common -Werror=return-type")
 161 #  set(CMAKE_CXX_FLAGS_RELEASE        "-O2 -DNDEBUG -DQT_NO_DEBUG")     # Use CMake default
 162 #  set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "-O2 -g -DNDEBUG -DQT_NO_DEBUG")  # Use CMake default
 163   set(CMAKE_CXX_FLAGS_DEBUG          "-g -O2 -fno-inline")
 164   set(CMAKE_CXX_FLAGS_DEBUGFULL      "-g3 -fno-inline")
 165   set(CMAKE_CXX_FLAGS_PROFILE        "-g3 -fno-inline -ftest-coverage -fprofile-arcs")
 166
 167   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-unused-function -fno-strict-aliasing")
 168 endif()
 169
 170 # Mac build stuff
 171 if(APPLE AND DEPLOY)
 172   set(CMAKE_OSX_ARCHITECTURES "x86_64")
 173   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.6")
 174   set(CMAKE_OSX_SYSROOT "/Developer/SDKs/MacOSX10.6.sdk/")
 175   add_definitions(-DMAC_10_6_SDK)
 176 endif(APPLE AND DEPLOY)
 177
 178 # Simplify checks
 179 if(WANT_MONO OR WANT_QTCLIENT)
 180   set(BUILD_GUI true)
 181 endif(WANT_MONO OR WANT_QTCLIENT)
 182 if(WANT_MONO OR WANT_CORE)
 183   set(BUILD_CORE true)
 184 endif(WANT_MONO OR WANT_CORE)
 185
 186
 187 # Version checks
 188 ################
 189
 190 if(WITH_QT5)
 191   set(QT_MIN_VERSION "5.0.0")
 192   add_definitions(-DHAVE_QT5)
 193
 194   # Qt5 needs a new enough cmake...
 195   cmake_minimum_required(VERSION 2.8.6 FATAL_ERROR)
 196
 197   # ... for automoc
 198   set(CMAKE_AUTOMOC ON)
 199 else(WITH_QT5)
 200
 201   # GUI stuff needs some new features
 202   if(BUILD_GUI)
 203     set(QT_MIN_VERSION "4.6.0")
 204   else(BUILD_GUI)
 205     set(QT_MIN_VERSION "4.4.0")
 206   endif(BUILD_GUI)
 207 endif(WITH_QT5)
 208
 209
 210 # Dependencies
 211 ##############
 212
 213 if(WITH_QT5)
 214   find_package(Qt5Core ${QT_MIN_VERSION} REQUIRED)
 215   # We need QtWidgets
 216   set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} Widgets)
 217
 218   # Setup the i18n-related variables
 219   find_package(Qt5LinguistTools)
 220
 221 else(WITH_QT5)
 222   # Select a Qt installation here, if you don't want to use system Qt
 223   if(QT)
 224     # FindQt4 will look for the qmake binary in $PATH, so we just prepend the Qt dir
 225     set(ENV{PATH} ${QT}/bin:$ENV{PATH})
 226   endif(QT)
 227
 228   # Now that we have the correct $PATH, lets find Qt!
 229   find_package(Qt4 ${QT_MIN_VERSION} REQUIRED)
 230 endif(WITH_QT5)
 231
 232
 233 # Neither Qt4 nor Qt5 consider lconvert relevant, so they don't support finding it...
 234 # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 235 if(QT_LRELEASE_EXECUTABLE)
 236   get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 237   if(WITH_QT5)
 238     find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 239   else(WITH_QT5)
 240     find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 241   endif(WITH_QT5)
 242 endif(QT_LRELEASE_EXECUTABLE)
 243
 244
 245 # Execinfo is needed for generating backtraces
 246 find_package(ExecInfo)
 247 if(EXECINFO_FOUND)
 248   add_definitions(-DHAVE_EXECINFO)
 249   include_directories(${EXECINFO_INCLUDES})
 250   link_libraries(${EXECINFO_LIBRARIES})
 251 endif(EXECINFO_FOUND)
 252
 253
 254 # PkgConfig isn't strictly required.
 255 # However, some optional deps might not be found if it's not present, so warn!
 256 find_package(PkgConfig)
 257 if(NOT PKG_CONFIG_FOUND)
 258   message(STATUS "WARNING: PkgConfig not available! Some dependencies for optional features might not be found.")
 259   message(STATUS "         Affected features might include encryption support, DBus menus and Ayatana notifications.")
 260 endif(NOT PKG_CONFIG_FOUND)
 261
 262
 263 # Setup OpenSSL
 264 # We don't link to or include OpenSSL ourselves, but use exclusively the Qt API.
 265 # Thus, we simply check if OpenSSL support is present in Qt's config and enable our
 266 # own SSL stuff in this case. Qt should care for adding what it needs itself.
 267 if(WITH_OPENSSL)
 268   if(QT_QCONFIG MATCHES "openssl")
 269     message(STATUS "Found OpenSSL support in Qt, enabling SSL")
 270     add_definitions(-DHAVE_SSL)
 271     set(HAVE_SSL true)
 272   else(QT_QCONFIG MATCHES "openssl")
 273     message(STATUS "No OpenSSL support found in Qt, disabling SSL")
 274     add_definitions(-DQT_NO_OPENSSL)
 275   endif(QT_QCONFIG MATCHES "openssl")
 276 else(WITH_OPENSSL)
 277   message(STATUS "Not enabling OpenSSL support")
 278 endif(WITH_OPENSSL)
 279
 280
 281 # Check for GUI specific stuff
 282 if(BUILD_GUI)
 283
 284   # Setup D-Bus support
 285   if(WITH_DBUS)
 286     if(WITH_QT5)
 287       find_package(Qt5DBus ${QT_MIN_VERSION})
 288       find_package(Qt5DBusTools)
 289     endif(WITH_QT5)
 290
 291     if(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 292       message(STATUS "Found QtDBus, enabling D-Bus support")
 293       add_definitions(-DHAVE_DBUS)
 294       set(HAVE_DBUS true)
 295       set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} DBus)
 296
 297       # check if we have dbusmenu as well
 298       if(NOT WITH_QT5)
 299         find_package(DBusMenuQt)
 300         if(DBUSMENUQT_FOUND)
 301           message(STATUS "Enabling support for exporting the tray menu via D-Bus")
 302           add_definitions(-DHAVE_DBUSMENU)
 303           include_directories(${DBUSMENUQT_INCLUDE_DIR})
 304           set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${DBUSMENUQT_LIBRARIES})
 305           set(CLIENT_COMPILE_FLAGS "${CLIENT_COMPILE_FLAGS} ${DBUSMENUQT_DEFINITIONS}")
 306         else(DBUSMENUQT_FOUND)
 307           message(STATUS "Disabling support for exporting the tray menu via D-Bus")
 308         endif(DBUSMENUQT_FOUND)
 309       endif(NOT WITH_QT5)
 310
 311     else(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 312       message(STATUS "QtDBus not found, disabling D-Bus support")
 313     endif(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 314   else(WITH_DBUS)
 315     message(STATUS "Not enabling D-Bus support")
 316   endif(WITH_DBUS)
 317
 318   # Setup QtWebkit support
 319   if(WITH_WEBKIT)
 320     if(WITH_QT5)
 321       find_package(Qt5Webkit ${QT_MIN_VERSION} QUIET)
 322     endif(WITH_QT5)
 323     if(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 324       message(STATUS "Found QtWebKit, enabling WebKit support")
 325       add_definitions(-DHAVE_WEBKIT)
 326       set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} Webkit XmlPatterns)
 327       set(HAVE_WEBKIT true)
 328     else(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 329       message(STATUS "QtWebkit not found, disabling Webkit support")
 330     endif(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 331   else(WITH_WEBKIT)
 332     message(STATUS "Not enabling Webkit support")
 333   endif(WITH_WEBKIT)
 334
 335   # Setup KDE4 support
 336   if(WITH_KDE AND NOT WITH_QT5)
 337     # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 338     set(_cflags ${CMAKE_C_FLAGS})
 339     find_package(KDE4)
 340     if(KDE4_FOUND)
 341       message(STATUS "Enabling KDE4 integration")
 342       include_directories(${KDE4_INCLUDES})
 343       add_definitions(-DHAVE_KDE ${KDE4_DEFINITIONS})
 344       set(HAVE_KDE 1)
 345       set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${KDE4_KDECORE_LIBS} ${KDE4_KDEUI_LIBRARY} ${KDE4_SOLID_LIBS} ${KDE4_KNOTIFYCONFIG_LIBRARY})
 346       # We always use external icons for KDE4 support, since we use its iconloader rather than our own
 347       set(EMBED_DATA OFF)
 348       # Restore our old CFLAGS
 349       set(CMAKE_C_FLAGS ${_cflags})
 350     else(KDE4_FOUND)
 351       message(STATUS "KDE4 not found, disabling KDE integration")
 352     endif(KDE4_FOUND)
 353   else(WITH_KDE AND NOT WITH_QT5)
 354     message(STATUS "Not enabling KDE4 integration")
 355   endif(WITH_KDE AND NOT WITH_QT5)
 356
 357   # Setup Phonon support - we only need this if we don't have or want KDE4
 358   if(NOT HAVE_KDE)
 359     if(WITH_PHONON)
 360       if(WITH_QT5)
 361         find_package(Qt5phonon)
 362         if(Qt5phonon_FOUND)
 363           message(STATUS "Enabling Phonon support")
 364           add_definitions(-DHAVE_PHONON)
 365           set(HAVE_PHONON true)
 366           set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} phonon)
 367         else(Qt5phonon_FOUND)
 368           message(STATUS "Phonon not found, disabling audio notifications")
 369         endif(Qt5phonon_FOUND)
 370       else(WITH_QT5)
 371         find_package(Phonon)
 372         if(PHONON_FOUND)
 373           message(STATUS "Enabling Phonon support")
 374           add_definitions(-DHAVE_PHONON)
 375           include_directories(${PHONON_INCLUDES})
 376           set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${PHONON_LIBS})
 377           set(HAVE_PHONON true)
 378         else(PHONON_FOUND)
 379           message(STATUS "Phonon not found, disabling audio notifications")
 380         endif(PHONON_FOUND)
 381       endif(WITH_QT5)
 382     else(WITH_PHONON)
 383       message(STATUS "Not enabling Phonon support")
 384     endif(WITH_PHONON)
 385   endif(NOT HAVE_KDE)
 386
 387   # Setup libindicate-qt support
 388   if(WITH_LIBINDICATE AND NOT WITH_QT5)
 389     pkg_check_modules(INDICATEQT QUIET indicate-qt>=0.2.1)
 390     if(INDICATEQT_FOUND)
 391       message(STATUS "Enabling Ayatana notification support")
 392       set(HAVE_INDICATEQT true)
 393       add_definitions(-DHAVE_INDICATEQT)
 394       link_directories(${INDICATEQT_LIBRARY_DIRS})
 395       set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${INDICATEQT_LIBRARIES})
 396     else(INDICATEQT_FOUND)
 397       message(STATUS "Disabling Ayatana notification support")
 398     endif(INDICATEQT_FOUND)
 399   else(WITH_LIBINDICATE AND NOT WITH_QT5)
 400     message(STATUS "Not enabling Ayatana notification support")
 401     # We don't want to link against it even if another package has found it
 402     set(INDICATEQT_LIBRARIES "")
 403   endif(WITH_LIBINDICATE AND NOT WITH_QT5)
 404
 405   # Setup OS X notification center support
 406   if(WITH_NOTIFICATION_CENTER AND APPLE)
 407     set(HAVE_NOTIFICATION_CENTER true)
 408     add_definitions(-DHAVE_NOTIFICATION_CENTER)
 409     set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES}
 410       /System/Library/Frameworks/Foundation.framework
 411     )
 412   endif()
 413
 414 find_package(Libsnore)
 415 if(LIBSNORE_FOUND)
 416     add_definitions(-DHAVE_LIBSNORE -DLIBSNORE_PLUGIN_PATH="${LIBSNORE_PLUGIN_PATH}")
 417     set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${LIBSNORE_LIBRARIES})
 418     set(HAVE_SNORENOTIFY true)
 419 endif(LIBSNORE_FOUND)
 420 endif(BUILD_GUI)
 421
 422 # Core-only deps
 423 if(BUILD_CORE)
 424
 425   # Setup encryption support
 426   if(WITH_CRYPT AND NOT WITH_QT5)
 427     find_package(QCA2)
 428     if(QCA2_FOUND)
 429       message(STATUS "Enabling encryption support")
 430       add_definitions(-DHAVE_QCA2)
 431       set(LINK_QCA2 QCA2)
 432       set(HAVE_QCA2 true)
 433       set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_QCA2)
 434     else(QCA2_FOUND)
 435       message(STATUS "Disabling encryption support")
 436     endif(QCA2_FOUND)
 437   else(WITH_CRYPT AND NOT WITH_QT5)
 438     message(STATUS "Not enabling encryption support")
 439   endif(WITH_CRYPT AND NOT WITH_QT5)
 440
 441   # Setup syslog support
 442   if(WITH_SYSLOG)
 443     check_include_file(syslog.h HAVE_SYSLOG_H)
 444     if(HAVE_SYSLOG_H)
 445       message(STATUS "Enabling syslog support")
 446       set(HAVE_SYSLOG true)
 447       add_definitions(-DHAVE_SYSLOG)
 448     else(HAVE_SYSLOG_H)
 449       message(STATUS "Disabling syslog support")
 450     endif(HAVE_SYSLOG_H)
 451   else(WITH_SYSLOG)
 452     message(STATUS "Not enabling syslog support")
 453   endif(WITH_SYSLOG)
 454
 455 endif(BUILD_CORE)
 456
 457
 458 # Various settings
 459 ##################
 460
 461 # needed to compile with mingw without kde
 462 if(MINGW AND NOT HAVE_KDE)
 463     add_definitions(-D_WIN32_WINNT=0x0500)
 464     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 465 # workaround for bug in mingw gcc 4.0
 466     add_definitions(-U__STRICT_ANSI__)
 467 endif(MINGW AND NOT HAVE_KDE)
 468
 469 # Now set up install locations; those are set by KDE if integration is enabled
 470 if(NOT HAVE_KDE)
 471   if(WIN32)
 472     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX} CACHE FILEPATH "Install path for binaries")
 473     set(DATA_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/apps CACHE FILEPATH "Install path for data files")
 474     set(ICON_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/icons CACHE FILEPATH "Global icon install path")
 475     set(XDG_APPS_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/applications CACHE FILEPATH "Install path for .desktop files")
 476   else(WIN32)
 477     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin CACHE FILEPATH "Install path for binaries")
 478     set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps CACHE FILEPATH "Install path for data files")
 479     set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons CACHE FILEPATH "Global icon install path")
 480     set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications CACHE FILEPATH "Install path for .desktop files")
 481   endif(WIN32)
 482 endif(NOT HAVE_KDE)
 483
 484 if(EMBED_DATA)
 485   message(STATUS "Embedding data files into the binary")
 486 else(EMBED_DATA)
 487   message(STATUS "Installing data files separately")
 488 endif(EMBED_DATA)
 489
 490 # RPATH needs to be set correctly
 491 # Do this down here, since otherwise KDE wants to handle it itself, and fails
 492 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
 493 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
 494
 495 # Set global buildflags
 496 # This is very much non-portable, so don't use -DSTATIC until you know what
 497 # you do.
 498 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 499   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 500   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 501   if(HAVE_SSL)
 502     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 503   endif(HAVE_SSL)
 504 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 505
 506 if(WIN32)
 507   link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 508   if(MSVC)
 509     set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 510     set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 511     set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 512     link_libraries(Version dwmapi shlwapi)
 513   endif(MSVC)
 514   if(HAVE_SSL AND STATIC)
 515      find_package(OpenSSL REQUIRED)
 516      link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 517   endif(HAVE_SSL AND STATIC)
 518 endif(WIN32)
 519
 520 if(HAVE_INDICATEQT)
 521   add_definitions(-DXDG_APPS_INSTALL_DIR=${XDG_APPS_INSTALL_DIR})
 522 endif(HAVE_INDICATEQT)
 523
 524 if(NOT WIN32)
 525   check_function_exists(umask HAVE_UMASK)
 526   if(HAVE_UMASK)
 527     add_definitions(-DHAVE_UMASK)
 528   endif(HAVE_UMASK)
 529 endif(NOT WIN32)
 530
 531 # We need to create a version.gen
 532 # For this, we create our genversion binary and make sure it is run every time.
 533
 534 setup_qt_variables()
 535 include_directories(${QUASSEL_QT_INCLUDES})
 536
 537 add_executable(genversion ${CMAKE_SOURCE_DIR}/src/common/genversion.cpp)
 538 target_link_libraries(genversion ${QUASSEL_QT_LIBRARIES})
 539 set_target_properties(genversion PROPERTIES COMPILE_FLAGS "${QUASSEL_QT_COMPILEFLAGS}")
 540
 541 get_target_property(GENVERSION_EXECUTABLE genversion LOCATION)
 542 add_custom_target(genversion_run ALL ${GENVERSION_EXECUTABLE}
 543                   ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR}/src/version.gen)
 544 add_dependencies(genversion_run genversion)
 545
 546 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 547 set(COMMON_DEPS ${RC_WIN32})
 548 set(CORE_DEPS )
 549 set(CLIENT_DEPS )
 550
 551 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 552 add_subdirectory(data)
 553 add_subdirectory(icons)
 554 add_subdirectory(pics)
 555 add_subdirectory(po)
 556 add_subdirectory(src)