CMakeLists.txt

   1 # This is the cmake-based build system for Quassel IRC.
   2 #
   3 # You may pass various options to cmake:
   4 # -DWANT_(CORE|QTCLIENT|MONO)=(ON|OFF)
   5 #                     : select binaries to build
   6 # -DWITH_OPENSSL=OFF  : Disable OpenSSL support
   7 # -DWITH_DBUS=OFF     : Disable D-Bus support (dbus notifications)
   8 # -DWITH_WEBKIT=OFF   : Disable WebKit support (link previews)
   9 # -DWITH_PHONON=OFF   : Disable Phonon support (audio notifications)
  10 # -DWITH_KDE=ON       : Enable KDE4 support
  11 #
  12 # -DEMBED_DATA=ON     : Embed all data files in icons the binary, rather than installing them separately
  13 #
  14 # -DQT=/path/to/qt    : Choose a Qt4 installation to use instead of the system Qt4
  15 # -DSTATIC=ON         : Enable static building of Quassel. Use with care.
  16 # -DDEPLOY=ON         : Mac OS X only. Use only for creating Quassel Packages!
  17 #
  18 # NOTE: You should remove CMakeCache.txt if you plan to change any of these values!
  19
  20 project(QuasselIRC)
  21
  22 cmake_minimum_required(VERSION 2.6.0 FATAL_ERROR)
  23
  24 if(COMMAND cmake_policy)
  25    cmake_policy(SET CMP0003 NEW)
  26 endif(COMMAND cmake_policy)
  27
  28 # Use our own (well, and KDE's) version of some modules
  29 # In particular cmake's own FindQt4 and FindOpenSSL are quite buggy
  30 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  31 include(QuasselMacros)
  32
  33 # Various options and variables that can be set on the command line
  34 option(WANT_CORE     "Build the core (server) binary"           ON)
  35 option(WANT_QTCLIENT "Build the Qt4 GUI client binary"          ON)
  36 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  37
  38 option(WITH_OPENSSL  "Enable OpenSSL support if present on the system"  ON)
  39 option(WITH_DBUS     "Enable D-Bus support if present on the system"    ON)
  40 option(WITH_WEBKIT   "Enable WebKit support (for link previews)"        ON)
  41 option(WITH_PHONON   "Enable Phonon support (for audio notifications)"  ON)
  42 option(WITH_KDE      "Enable KDE4 integration"                          OFF)
  43
  44 # We use icon paths from KDE 4.3 trunk, which are partially invalid on older and possibly
  45 # even on newer KDE versions. Do not disable this unless you are sure that your Quassel will
  46 # run on a matching KDE version only.
  47 option(WITH_OXYGEN   "Install Oxygen icons. Heavily recommended unless you use KDE 4.3" ON)
  48
  49 option(STATIC        "Enable static building (might not be portable)" OFF)
  50
  51 if(APPLE)
  52   option(DEPLOY        "Mac OS X only! Adds required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF)
  53 endif(APPLE)
  54
  55 # Default to embedding data in the static case
  56 if(STATIC OR WIN32)
  57   set(EMBED_DEFAULT ON)
  58 else(STATIC OR WIN32)
  59   set(EMBED_DEFAULT ON) # should be OFF as soon as everything works
  60 endif(STATIC OR WIN32)
  61
  62 option(EMBED_DATA    "Embed all data files in the binary (rather than installing them separately)"   ${EMBED_DEFAULT})
  63
  64 set(QT "" CACHE STRING "Path to a Qt installation to use instead of the system Qt (e.g. for static builds)")
  65 set(LINGUAS "" CACHE STRING "Comma-separated list of locales specifying languages that should be compiled")
  66
  67 # Some settings imply others
  68 if(STATIC)
  69   add_definitions(-DSTATIC)
  70   set(WITH_KDE OFF CACHE BOOL "Static building with KDE is not supported")
  71 endif(STATIC)
  72
  73 if(WIN32)
  74   # We don't support separately installed resources yet on Win32
  75   set(EMBED_DATA ON)
  76 endif(WIN32)
  77
  78 # For static builds, arbitrary extra libs might need to be linked
  79 # Define a comma-separated list here
  80 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
  81 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
  82 if(LINK_EXTRA)
  83   string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
  84   link_libraries(${LINK_EXTRA})
  85 endif(LINK_EXTRA)
  86
  87 # Build Type
  88 # We need to make sure it's not empty
  89 # Supported: Release, RelWithDebugInfo, Debug, Debugfull
  90
  91 # On WIN32, only Release seems to work correctly (?)
  92 if(WIN32)
  93   set(DEFAULT_BUILD_TYPE "Release")
  94 else(WIN32)
  95   set(DEFAULT_BUILD_TYPE "RelWithDebugInfo")
  96 endif(WIN32)
  97
  98 set(CMAKE_BUILD_TYPE ${DEFAULT_BUILD_TYPE} CACHE STRING "CMake Build Type")
  99 if(NOT CMAKE_BUILD_TYPE)
 100   set(CMAKE_BUILD_TYPE ${DEFAULT_BUILD_TYPE} CACHE STRING "CMake Build Type" FORCE)
 101 endif(NOT CMAKE_BUILD_TYPE)
 102
 103 # Enable various flags on gcc
 104 if(CMAKE_COMPILER_IS_GNUCXX)
 105   # Let's just hope that all gccs support these options and skip the tests...
 106   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -ansi -Wall -Wextra -Wnon-virtual-dtor")
 107   set(CMAKE_CXX_FLAGS_RELWITHDEBUGINFO "-O2")
 108   set(CMAKE_CXX_FLAGS_DEBUG "-g -fno-reorder-blocks -fno-schedule-insns -fno-inline")
 109   set(CMAKE_CXX_FLAGS_DEBUGFULL "-g3")
 110 endif(CMAKE_COMPILER_IS_GNUCXX)
 111
 112 if(WANT_MONO OR WANT_QTCLIENT)
 113   set(QT_MIN_VERSION "4.4.1") # Client crashes often with 4.4.0
 114 else(WANT_MONO OR WANT_QTCLIENT)
 115   set(QT_MIN_VERSION "4.4.0")
 116 endif(WANT_MONO OR WANT_QTCLIENT)
 117
 118 if(APPLE AND DEPLOY)
 119   set(CMAKE_OSX_ARCHITECTURES "i386;ppc")
 120   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.4")
 121   set(CMAKE_OSX_SYSROOT "/Developer/SDKs/MacOSX10.4u.sdk/")
 122   add_definitions(-DMAC_10_4_SDK)
 123 endif(APPLE AND DEPLOY)
 124
 125 # Execinfo is needed for generating backtraces
 126 find_package(ExecInfo)
 127 if(EXECINFO_FOUND)
 128   add_definitions(-DHAVE_EXECINFO)
 129   include_directories(${EXECINFO_INCLUDES})
 130   link_libraries(${EXECINFO_LIBRARIES})
 131 endif(EXECINFO_FOUND)
 132
 133 # Select a Qt installation here, if you don't want to use system Qt
 134 if(QT)
 135   # FindQt4 will look for the qmake binary in $PATH, so we just prepend the Qt dir
 136   set(ENV{PATH} ${QT}/bin:$ENV{PATH})
 137 endif(QT)
 138
 139 # Now that we have the correct $PATH, lets find Qt!
 140 find_package(Qt4 REQUIRED)
 141
 142 set(QT_DONT_USE_QTGUI 1)
 143 include(${QT_USE_FILE})
 144 include_directories(${QT_INCLUDES})
 145
 146 # Setup OpenSSL
 147 if(WITH_OPENSSL)
 148   find_package(OpenSSL)
 149 else(WITH_OPENSSL)
 150   message(STATUS "Disabling OpenSSL support")
 151 endif(WITH_OPENSSL)
 152
 153 if(OPENSSL_FOUND)
 154   if(NOT QT_DEFINITIONS MATCHES "QT_NO_OPENSSL")
 155     message(STATUS "Found OpenSSL support in Qt")
 156     add_definitions(-DHAVE_SSL)
 157     set(HAVE_SSL true)
 158     set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_SSL)
 159   else(NOT QT_DEFINITIONS MATCHES "QT_NO_OPENSSL")
 160     message(STATUS "No OpenSSL support found in Qt, disabling")
 161   endif(NOT QT_DEFINITIONS MATCHES "QT_NO_OPENSSL")
 162 else(OPENSSL_FOUND)
 163   add_definitions(-DQT_NO_OPENSSL)
 164 endif(OPENSSL_FOUND)
 165
 166 # Setup D-Bus support
 167 if(WITH_DBUS)
 168   if(QT_QTDBUS_FOUND)
 169     message(STATUS "Found QtDBus, enabling D-Bus support")
 170     add_definitions(-DHAVE_DBUS)
 171     set(LINK_DBUS DBUS)
 172     set(HAVE_DBUS true)
 173     set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_DBUS)
 174   else(QT_QTDBUS_FOUND)
 175     message(STATUS "QtDBus not found, disabling D-Bus support")
 176   endif(QT_QTDBUS_FOUND)
 177 else(WITH_DBUS)
 178   message(STATUS "Disabling D-Bus support")
 179 endif(WITH_DBUS)
 180
 181 # Setup QtWebKit support
 182 if(WITH_WEBKIT)
 183   if(QT_QTWEBKIT_FOUND)
 184     message(STATUS "Found QtWebKit, enabling WebKit support")
 185     add_definitions(-DHAVE_WEBKIT)
 186     set(LINK_WEBKIT WEBKIT)
 187     set(HAVE_WEBKIT true)
 188     set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_WEBKIT)
 189   else(QT_QTWEBKIT_FOUND)
 190     message(STATUS "QtWebKit not found, disabling WebKit support")
 191   endif(QT_QTWEBKIT_FOUND)
 192 else(WITH_WEBKIT)
 193   message(STATUS "Disabling WebKit support")
 194 endif(WITH_WEBKIT)
 195
 196 # Setup KDE4 support
 197 if(WITH_KDE)
 198   find_package(KDE4)
 199   if(KDE4_FOUND)
 200     message(STATUS "Enabling KDE4 integration")
 201     include_directories(${KDE4_INCLUDES})
 202     add_definitions(-DHAVE_KDE ${KDE4_DEFINITIONS})
 203     set(HAVE_KDE 1)
 204     set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_KDE)
 205     set(QUASSEL_KDE_LIBRARIES ${KDE4_KDECORE_LIBS} ${KDE4_KDEUI_LIBRARY} knotifyconfig)
 206     # We always use external icons for KDE4 support, since we use its iconloader rather than our own
 207     set(EMBED_DATA OFF)
 208   else(KDE4_FOUND)
 209     message(STATUS "KDE4 not found, disabling KDE integration")
 210   endif(KDE4_FOUND)
 211 else(WITH_KDE)
 212   message(STATUS "Disabling KDE4 integration")
 213 endif(WITH_KDE)
 214
 215 # Setup Phonon support - we only need this if we don't have or want KDE4
 216 if(NOT HAVE_KDE)
 217   if(WITH_PHONON)
 218     find_package(Phonon)
 219     if(PHONON_FOUND)
 220       message(STATUS "Enabling Phonon support")
 221       add_definitions(-DHAVE_PHONON)
 222       set(HAVE_PHONON true)
 223       set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_PHONON)
 224     else(PHONON_FOUND)
 225       message(STATUS "Phonon not found, disabling audio notifications")
 226     endif(PHONON_FOUND)
 227   else(WITH_PHONON)
 228     message(STATUS "Disabling Phonon support")
 229   endif(WITH_PHONON)
 230 endif(NOT HAVE_KDE)
 231
 232 # Now set up install locations; those are set by KDE if integration is enabled
 233 if(NOT HAVE_KDE)
 234   if(WIN32)
 235     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX} CACHE FILEPATH "Install path for binaries")
 236     set(DATA_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/apps CACHE FILEPATH "Install path for data files")
 237     set(ICON_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/icons CACHE FILEPATH "Global icon install path")
 238     set(XDG_APPS_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/applications CACHE FILEPATH "Install path for .desktop files")
 239   else(WIN32)
 240     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin CACHE FILEPATH "Install path for binaries")
 241     set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps CACHE FILEPATH "Install path for data files")
 242     set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons CACHE FILEPATH "Global icon install path")
 243     set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications CACHE FILEPATH "Install path for .desktop files")
 244   endif(WIN32)
 245 endif(NOT HAVE_KDE)
 246
 247 # RPATH needs to be set correctly
 248 # Do this down here, since otherwise KDE wants to handle it itself, and fails
 249 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
 250 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
 251
 252 # Set global buildflags
 253 # This is very much non-portable, so don't use -DSTATIC until you know what
 254 # you do.
 255 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 256   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 257   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 258   if(HAVE_SSL)
 259     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 260   endif(HAVE_SSL)
 261 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 262
 263 if(WIN32)
 264   link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 265
 266   if(HAVE_SSL)
 267      link_libraries(${OPENSSL_LIBRARIES} libeay32MD)
 268   endif(HAVE_SSL)
 269 endif(WIN32)
 270
 271 # We need to create a version.gen
 272 # For this, we create our genversion binary and make sure it is run every time.
 273 add_executable(genversion ${CMAKE_SOURCE_DIR}/src/common/genversion.cpp)
 274 target_link_libraries(genversion ${QT_LIBRARIES} ${QT_CORE_LIB_DEPENDENCIES})
 275
 276 get_target_property(GENVERSION_EXECUTABLE genversion LOCATION)
 277 add_custom_target(genversion_run ALL ${GENVERSION_EXECUTABLE}
 278                   ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR}/src/version.gen)
 279 add_dependencies(genversion_run genversion)
 280
 281 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 282 set(COMMON_DEPS ${RC_WIN32})
 283 set(CORE_DEPS )
 284 set(CLIENT_DEPS )
 285
 286 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 287 add_subdirectory(data)
 288 add_subdirectory(icons)
 289 add_subdirectory(pics)
 290 add_subdirectory(i18n)
 291 add_subdirectory(src)