CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 project(QuasselIRC)
  10
  11 # Versions
  12 set(QUASSEL_MAJOR  0)
  13 set(QUASSEL_MINOR 12)
  14 set(QUASSEL_PATCH  0)
  15 set(QUASSEL_VERSION_STRING "0.12-pre")
  16
  17 # Tell CMake about or own modules
  18 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  19
  20 # General conveniences
  21 set(CMAKE_AUTOMOC ON)
  22 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  23
  24 # Include various CMake modules...
  25 include(CMakePushCheckState)
  26 include(CheckFunctionExists)
  27 include(CheckIncludeFile)
  28 include(CheckCXXSourceCompiles)
  29 include(CMakeDependentOption)
  30 include(FeatureSummary)
  31
  32 # ... and our own stuff
  33 include(QuasselCompileSettings)
  34 include(QuasselMacros)
  35
  36
  37 # Options and variables that can be set on the command line
  38 #####################################################################
  39
  40 # First, choose a Qt version. We support USE_QT4 and USE_QT5; if neither is set, prefer Qt4 for now
  41 option(USE_QT5 "Enable support for Qt5 (disables KDE integration)" OFF)
  42 if (USE_QT4) # takes precedence
  43     set(USE_QT5 OFF)
  44 else()
  45     if (NOT USE_QT5)
  46         set(USE_QT4 ON)
  47     endif()
  48 endif()
  49
  50 # Select the binaries to build
  51 option(WANT_CORE     "Build the core (server) binary"           ON)
  52 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  53 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  54 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  55 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  56 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  57
  58 # Whether to enable KDE integration (work in progress for Qt5 / KDE Frameworks)
  59 # Note that when building with Qt5, WITH_KDE enables integration with higher-tier KDE frameworks that
  60 # require runtime support. We still optionally make use of certain Tier 1 frameworks even if WITH_KDE
  61 # is disabled.
  62 if (USE_QT4)
  63     option(WITH_KDE "KDE4 integration" OFF)
  64     add_feature_info(WITH_KDE WITH_KDE "Enable KDE4 integration")
  65 else()
  66     option(WITH_KDE "Integration with the KDE Frameworks runtime environment")
  67     add_feature_info(WITH_KDE WITH_KDE "Integrate with the KDE Frameworks runtime environment")
  68 endif()
  69
  70 cmake_dependent_option(WITH_OXYGEN "Install Oxygen icon set (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
  71 if (NOT WITH_KDE)
  72     add_feature_info(WITH_OXYGEN WITH_OXYGEN "Install Oxygen icon set")
  73 endif()
  74
  75 # For this, the feature info is added after we know if QtWebkit is installed
  76 option(WITH_WEBKIT "WebKit support (for link previews)" ON)
  77
  78 if (APPLE)
  79     # Notification Center is only available in > 10.8, which is Darwin v12
  80     if (CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  81         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
  82         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
  83     endif()
  84 endif()
  85
  86 # Always embed on Windows, OSX or for a static build; never embed when enabling KDE integration
  87 set(EMBED_DEFAULT OFF)
  88 if (STATIC OR WIN32 OR APPLE)
  89     set(EMBED_DEFAULT ON)
  90 endif()
  91 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
  92                                    "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
  93 if (NOT EMBED_DEFAULT)
  94     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
  95 endif()
  96
  97 # The following options are not for end-user consumption, so don't list them in the feature summary
  98 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
  99
 100 # Handle with care
 101 set(QT_PATH "" CACHE PATH "Path to a Qt4 installation to use instead of the system Qt (e.g. for static builds)")
 102
 103 # Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
 104 cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
 105
 106 # For static builds, arbitrary extra libs might need to be linked
 107 # Define a comma-separated list here
 108 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 109 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 110 if (LINK_EXTRA)
 111     string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 112     link_libraries(${LINK_EXTRA})
 113 endif()
 114
 115
 116 # Setup CMake
 117 #####################################################################
 118
 119 if (USE_QT5 AND WITH_KDE)
 120     cmake_minimum_required(VERSION 2.8.12)
 121 else()
 122     cmake_minimum_required(VERSION 2.8.9)
 123 endif()
 124
 125 # Setting COMPILE_DEFINITIONS_<CONFIG> is deprecated since CMake 3.0 in favor of generator expressions.
 126 # These have existed since CMake 2.8.10; until we depend on that, we have to explicitly enable the old policy.
 127 if (CMAKE_MAJOR_VERSION GREATER 2)
 128     cmake_policy(SET CMP0043 OLD)
 129 endif()
 130
 131
 132 # Simplify later checks
 133 #####################################################################
 134
 135 if (WANT_MONO OR WANT_QTCLIENT)
 136     set(BUILD_GUI true)
 137 endif()
 138 if (WANT_MONO OR WANT_CORE)
 139     set(BUILD_CORE true)
 140 endif()
 141
 142
 143 # Set up Qt
 144 #####################################################################
 145
 146 if (USE_QT5)
 147     message(STATUS "Building for Qt5...")
 148     set(QT_MIN_VERSION "5.2.0")
 149     add_definitions(-DHAVE_QT5)
 150 else()
 151     message(STATUS "Building for Qt4...")
 152     set(QT_MIN_VERSION "4.8.0")
 153
 154     # Select a Qt installation here, if you don't want to use system Qt
 155     if(QT_PATH)
 156         # FindQt4 will look for the qmake binary in $PATH, so we just prepend QT_PATH
 157         set(ENV{PATH} ${QT_PATH}/bin:$ENV{PATH})
 158     endif()
 159 endif()
 160
 161
 162 # Find package dependencies
 163 #
 164 # Note that you can forcefully disable optional packages
 165 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 166 #####################################################################
 167
 168 if (USE_QT5)
 169     find_package(Qt5Core ${QT_MIN_VERSION} QUIET)
 170     set_package_properties(Qt5Core PROPERTIES TYPE REQUIRED
 171         URL "http://qt.digia.com"
 172         DESCRIPTION "contains core functionality for Qt"
 173     )
 174     # find_package without REQUIRED won't check for the version properly; also, older Qt5 versions
 175     # used Qt5Core_VERSION_STRING... let's just make sure here that we bail out here if our Qt5 is not new enough.
 176     if (NOT Qt5Core_VERSION OR Qt5Core_VERSION VERSION_LESS ${QT_MIN_VERSION})
 177         message(FATAL_ERROR "Could NOT find Qt5 >= version ${QT_MIN_VERSION}!")
 178     endif()
 179
 180     find_package(Qt5Network QUIET)
 181     set_package_properties(Qt5Network PROPERTIES TYPE REQUIRED
 182         DESCRIPTION "the network module for Qt5"
 183     )
 184
 185     if (BUILD_GUI)
 186         find_package(Qt5Gui QUIET)
 187         set_package_properties(Qt5Gui PROPERTIES TYPE REQUIRED
 188             DESCRIPTION "the GUI module for Qt5"
 189         )
 190         find_package(Qt5Widgets QUIET)
 191         set_package_properties(Qt5Widgets PROPERTIES TYPE REQUIRED
 192             DESCRIPTION "the widgets module for Qt5"
 193         )
 194
 195         find_package(Qt5DBus QUIET)
 196         set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 197             URL "http://qt.digia.com"
 198             DESCRIPTION "D-Bus support for Qt5"
 199             PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 200         )
 201         if (Qt5DBus_FOUND)
 202             find_package(dbusmenu-qt5 QUIET CONFIG)
 203             set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 204                 URL "https://launchpad.net/libdbusmenu-qt"
 205                 DESCRIPTION "a library implementing the DBusMenu specification"
 206                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 207             )
 208         endif()
 209
 210         find_package(Phonon4Qt5 QUIET)
 211         set_package_properties(Phonon4Qt5 PROPERTIES TYPE RECOMMENDED
 212             URL "https://projects.kde.org/projects/kdesupport/phonon"
 213             DESCRIPTION "a multimedia abstraction library"
 214             PURPOSE     "Required for audio notifications"
 215         )
 216
 217         find_package(LibsnoreQt5 QUIET)
 218         set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
 219             URL "https://github.com/TheOneRing/Snorenotify"
 220             DESCRIPTION "a cross-platform notification framework"
 221             PURPOSE     "Enable support for the snorenotify framework"
 222         )
 223
 224         if (WITH_WEBKIT)
 225             find_package(Qt5WebKit QUIET)
 226             set_package_properties(Qt5WebKit PROPERTIES TYPE RECOMMENDED
 227                 URL "http://qt.digia.com"
 228                 DESCRIPTION "a WebKit implementation for Qt"
 229                 PURPOSE     "Needed for displaying previews for URLs in chat"
 230             )
 231             if (Qt5WebKit_FOUND)
 232                 find_package(Qt5WebKitWidgets QUIET)
 233                 set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE RECOMMENDED
 234                     URL "http://qt.digia.com"
 235                     DESCRIPTION "widgets for Qt's WebKit implementation"
 236                     PURPOSE     "Needed for displaying previews for URLs in chat"
 237                 )
 238             endif()
 239         endif()
 240         add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" Qt5WebKitWidgets_FOUND "Support showing previews for URLs in chat")
 241
 242         # KDE Frameworks
 243         ################
 244
 245         if (WITH_KDE)
 246             set(ecm_find_type "REQUIRED")
 247         else()
 248             # Even with KDE integration disabled, we optionally use tier1 frameworks if we find them
 249             set(ecm_find_type "RECOMMENDED")
 250         endif()
 251
 252         # extra-cmake-modules
 253         find_package(ECM NO_MODULE QUIET)
 254         set_package_properties(ECM PROPERTIES TYPE ${ecm_find_type}
 255             URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules"
 256             DESCRIPTION "extra modules for CMake, maintained by the KDE project"
 257             PURPOSE     "Required to find KDE Frameworks components"
 258         )
 259
 260         if (ECM_FOUND)
 261             list(APPEND CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
 262         endif()
 263
 264         if (WITH_KDE)
 265             find_package(KF5CoreAddons QUIET)
 266             set_package_properties(KF5CoreAddons PROPERTIES TYPE REQUIRED
 267                 URL "http://inqlude.org/libraries/kcoreaddons.html"
 268                 DESCRIPTION "framework for solving common problems such as caching, randomization, and more"
 269                 PURPOSE     "Required for KDE Frameworks integration"
 270             )
 271
 272             find_package(KF5TextWidgets QUIET)
 273             set_package_properties(KF5TextWidgets PROPERTIES TYPE REQUIRED
 274                 URL "http://inqlude.org/libraries/ktextwidgets.html"
 275                 DESCRIPTION "framework providing an assortment of widgets for displaying and editing text"
 276                 PURPOSE     "Allows to use extra features provided by KDE Frameworks in input widgets"
 277             )
 278
 279         endif()
 280
 281     endif(BUILD_GUI)
 282     if (BUILD_CORE)
 283         find_package(Qt5Script QUIET)
 284         set_package_properties(Qt5Script PROPERTIES TYPE REQUIRED
 285             DESCRIPTION "provides scripting support for Qt5"
 286         )
 287         find_package(Qt5Sql QUIET)
 288         set_package_properties(Qt5Sql PROPERTIES TYPE REQUIRED
 289             DESCRIPTION "the database support module for Qt5"
 290         )
 291
 292         find_package(QCA2-QT5)
 293         set_package_properties(QCA2-QT5 PROPERTIES TYPE RECOMMENDED
 294             URL "https://projects.kde.org/projects/kdesupport/qca"
 295             DESCRIPTION "Qt Cryptographic Architecture"
 296             PURPOSE "Required for encryption support"
 297         )
 298
 299     endif(BUILD_CORE)
 300
 301     find_package(Qt5LinguistTools QUIET)
 302     set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 303                            DESCRIPTION "contains tools for handling translation files"
 304                            PURPOSE "Required for having translations"
 305     )
 306     # Some Qt5 versions do not define a target for lconvert, so we need to find it ourselves
 307     if (Qt5LinguistTools_FOUND)
 308         if (NOT TARGET Qt5::lconvert AND TARGET Qt5::lrelease)
 309             get_target_property(_lrelease_location Qt5::lrelease LOCATION)
 310             get_filename_component(_lrelease_path ${_lrelease_location} PATH)
 311             find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 312         elseif(TARGET Qt5::lconvert AND NOT Qt5_LCONVERT_EXECUTABLE)
 313             # Newer Qt5 versions define the target, but not the Qt5_LCONVERT_EXECUTABLE variable for some reason
 314             get_target_property(QT_LCONVERT_EXECUTABLE Qt5::lconvert LOCATION)
 315         endif()
 316
 317         # Compatibility with the Qt4 variables
 318         set(QT_LRELEASE_EXECUTABLE ${Qt5_LRELEASE_EXECUTABLE})
 319         set(QT_LUPDATE_EXECUTABLE ${Qt5_LUPDATE_EXECUTABLE})
 320         if (Qt5_LCONVERT_EXECUTABLE)
 321             set(QT_LCONVERT_EXECUTABLE ${Qt5_LCONVERT_EXECUTABLE})
 322         endif()
 323     endif()
 324
 325 else(USE_QT5)
 326     find_package(Qt4 ${QT_MIN_VERSION} QUIET REQUIRED)
 327
 328     if (BUILD_GUI)
 329         add_feature_info("QtDBus module" QT_QTDBUS_FOUND "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments")
 330         if (QT_QTDBUS_FOUND)
 331             find_package(dbusmenu-qt QUIET CONFIG)
 332             set_package_properties(dbusmenu-qt PROPERTIES TYPE RECOMMENDED
 333                 URL "https://launchpad.net/libdbusmenu-qt"
 334                 DESCRIPTION "a library implementing the DBusMenu specification"
 335                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 336             )
 337         endif()
 338
 339         if (WITH_WEBKIT AND QT_QTWEBKIT_FOUND)
 340             set(HAVE_WEBKIT true)
 341         endif()
 342         add_feature_info("WITH_WEBKIT and QtWebKit module" HAVE_WEBKIT "Support showing previews for URLs in chat")
 343
 344         if (WITH_KDE)
 345             # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 346             set(_cflags ${CMAKE_C_FLAGS})
 347             find_package(KDE4 4.4 QUIET)
 348             set_package_properties(KDE4 PROPERTIES TYPE REQUIRED
 349                 URL "http://www.kde.org"
 350                 DESCRIPTION "a world-class desktop environment"
 351                 PURPOSE "Enables various bits for improving integration with KDE"
 352             )
 353             set(CMAKE_C_FLAGS ${_cflags})
 354
 355         else(WITH_KDE)
 356             find_package(Phonon QUIET)
 357             set_package_properties(Phonon PROPERTIES TYPE RECOMMENDED
 358                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 359                 DESCRIPTION "a multimedia abstraction library"
 360                 PURPOSE     "Required for audio notifications"
 361             )
 362
 363             find_package(Libsnore QUIET)
 364             set_package_properties(Libsnore PROPERTIES TYPE OPTIONAL
 365                 URL "https://github.com/TheOneRing/Snorenotify"
 366                 DESCRIPTION "a cross-platform notification framework"
 367                 PURPOSE     "Enable support for the snorenotify framework"
 368             )
 369         endif(WITH_KDE)
 370
 371         find_package(IndicateQt QUIET)
 372         set_package_properties(IndicateQt PROPERTIES TYPE OPTIONAL
 373             URL "https://launchpad.net/libindicate-qt/"
 374             DESCRIPTION "a library to raise flags on DBus for other components of the desktop to pick up and visualize"
 375             PURPOSE     "Provides integration into the Ayatana notification system used by e.g. Ubuntu"
 376         )
 377
 378     endif(BUILD_GUI)
 379
 380     if (BUILD_CORE)
 381
 382         find_package(QCA2 QUIET)
 383         set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 384             URL "https://projects.kde.org/projects/kdesupport/qca"
 385             DESCRIPTION "Qt Cryptographic Architecture"
 386             PURPOSE     "Required for encryption support"
 387         )
 388
 389
 390     endif()
 391
 392     # Qt4 does not consider lconvert relevant, so they don't support finding it...
 393     # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 394     if (QT_LRELEASE_EXECUTABLE)
 395         get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 396         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 397     endif()
 398 endif()
 399
 400
 401 # Non-Qt-based packages
 402
 403 # zlib for compression, however we can always fall back to miniz
 404 find_package(ZLIB QUIET)
 405 set_package_properties(ZLIB PROPERTIES TYPE RECOMMENDED
 406     URL "http://www.zlib.net"
 407     DESCRIPTION "a popular compression library"
 408     PURPOSE     "Use the most common library for protocol compression, instead of the bundled miniz implementation"
 409 )
 410
 411
 412 if (NOT WIN32)
 413     # Execinfo is needed for generating backtraces
 414     find_package(ExecInfo QUIET)
 415     set_package_properties(ExecInfo PROPERTIES TYPE OPTIONAL
 416         DESCRIPTION "a library for inspecting backtraces"
 417         PURPOSE "Used for generating backtraces in case of a crash"
 418     )
 419 endif()
 420
 421
 422 # Additional compile settings
 423 #####################################################################
 424
 425 # This sets -fPIC and friends if required by the installed Qt5 library
 426 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 427     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 428 endif()
 429
 430 # Needed to compile with mingw without kde
 431 if (MINGW AND NOT KDE4_FOUND)
 432     add_definitions(-D_WIN32_WINNT=0x0500)
 433     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 434     # workaround for bug in mingw gcc 4.0
 435     add_definitions(-U__STRICT_ANSI__)
 436 endif()
 437
 438 # Sanitize compiler flags - old versions of KDE set -ansi, which breaks -std=c++11
 439 if (CMAKE_COMPILER_IS_GNUCXX)
 440     string(REPLACE "-ansi" "" CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS})
 441 endif()
 442
 443
 444 # Setup KDE / KDE Frameworks
 445 #####################################################################
 446
 447 # We want to do this up here, so we have the necessary variables and defines set before
 448 # compiling anything
 449
 450 if (KDE4_FOUND)
 451     # We always use external icons for KDE4 support, since we use its iconloader rather than Qt's
 452     set(EMBED_DATA OFF)
 453
 454     # Better have the compile flags global, even for the core, to avoid problems with linking the mono client
 455     add_definitions(-DHAVE_KDE -DHAVE_KDE4 ${KDE4_DEFINITIONS})
 456     set(WITH_KDE4 TRUE)
 457 endif()
 458
 459 if (USE_QT5 AND WITH_KDE)
 460     # If KDE Frameworks are present, they're most probably providing Qt5 integration including icon loading
 461     set(EMBED_DATA OFF)
 462
 463     include(KDEInstallDirs)
 464     include(KDECompilerSettings)
 465     include(KDECMakeSettings)
 466
 467     add_definitions(-DHAVE_KDE -DHAVE_KF5)
 468     set(WITH_KF5 TRUE)
 469 endif()
 470
 471 # This needs to come after setting up KDE integration, so we can use KDE-specific paths
 472 include(QuasselInstallDirs)
 473
 474 # Various config-dependent checks and settings
 475 #####################################################################
 476
 477 if (NOT ZLIB_FOUND)
 478     message(STATUS "zlib NOT found, using bundled miniz for compression")
 479     if (${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 480         message(STATUS "WARNING: This may be slow on 32 bit systems!")
 481     endif()
 482 endif()
 483
 484 # Check for SSL support in Qt
 485 # As there's no easy way to get Qt's configuration in particular for Qt5, let's just compile
 486 # a small test program checking the defines. This works for both Qt4 and Qt5.
 487 cmake_push_check_state(RESET)
 488 set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES} ${Qt5Core_INCLUDE_DIRS})
 489 check_cxx_source_compiles("
 490     #include \"qglobal.h\"
 491     #if defined QT_NO_OPENSSL || defined QT_NO_SSL
 492     #  error \"No SSL support\"
 493     #endif
 494     int main() {}"
 495     HAVE_SSL)
 496 cmake_pop_check_state()
 497
 498 if (HAVE_SSL)
 499     add_definitions(-DHAVE_SSL)
 500 endif()
 501 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 502
 503 # Check for syslog support
 504 if (NOT WIN32)
 505     check_include_file(syslog.h HAVE_SYSLOG)
 506     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 507 endif()
 508
 509 add_feature_info("Qt Linguist Tools" QT_LCONVERT_EXECUTABLE "Translation support for Quassel")
 510
 511 if (EMBED_DATA)
 512     message(STATUS "Embedding data files into the binary")
 513 else()
 514     message(STATUS "Installing data files separately")
 515 endif()
 516
 517 if (INDICATEQT_FOUND)
 518     add_definitions(-DXDG_APPS_INSTALL_DIR=${CMAKE_INSTALL_APPDIR})
 519 endif()
 520
 521 if (NOT WIN32)
 522     check_function_exists(umask HAVE_UMASK)
 523     if(HAVE_UMASK)
 524         add_definitions(-DHAVE_UMASK)
 525     endif(HAVE_UMASK)
 526 endif()
 527
 528
 529 # Windows-specific stuff
 530 #####################################################################
 531
 532 if (WIN32)
 533     link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 534     if (MSVC)
 535         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /DNOMINMAX")
 536         set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 537         set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 538         set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 539         link_libraries(Version dwmapi shlwapi)
 540         if (USE_QT5)
 541             set(QT_QTMAIN_LIBRARY Qt5::WinMain)
 542         endif()
 543     endif()
 544     if(HAVE_SSL AND STATIC)
 545         find_package(OpenSSL REQUIRED)
 546         link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 547     endif()
 548 endif()
 549
 550
 551 # Static builds (very much non-portable, so don't use -DSTATIC
 552 # unless you know what you do!)
 553 #####################################################################
 554
 555 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 556     set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 557     link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 558     if (HAVE_SSL)
 559         set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 560     endif()
 561 endif()
 562
 563
 564 # Generate version information from Git
 565 #####################################################################
 566
 567 include(GetGitRevisionDescription)
 568 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 569 git_describe(GIT_DESCRIBE --long)
 570
 571 # Sanitize things if we're not in a Git repo
 572 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 573     set(GIT_HEAD "")
 574     set(GIT_DESCRIBE "")
 575 endif()
 576
 577 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 578
 579 # Prepare the build
 580 #####################################################################
 581
 582 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 583 set(COMMON_DEPS ${RC_WIN32})
 584 set(CORE_DEPS )
 585 set(CLIENT_DEPS )
 586
 587 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 588 add_subdirectory(data)
 589 add_subdirectory(icons)
 590 add_subdirectory(pics)
 591 add_subdirectory(po)
 592
 593
 594 # Set up and display feature summary
 595 #####################################################################
 596
 597 feature_summary(WHAT ALL
 598                 INCLUDE_QUIET_PACKAGES
 599                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 600 )
 601
 602 # Finally, compile the sources
 603 # We want this after displaying the feature summary to avoid ugly
 604 # CMake backtraces in case a required Qt5 module is missing
 605 #####################################################################
 606
 607 add_subdirectory(src)