CMakeLists.txt

   1 # This is the cmake-based build system for Quassel IRC.
   2 # You may pass various options to cmake:
   3 # -DWANT_(CORE|QTCLIENT|MONO)=(ON|OFF)
   4 #                     : select binaries to build
   5 # -DWITH_OPENSSL=OFF  : Disable OpenSSL support
   6 # -DWITH_DBUS=OFF     : Disable D-Bus support
   7 # -DOXYGEN_ICONS=(Builtin|External)  : If "Builtin" (the default), compile our Oxygen Icon Theme subset into the binary
   8 #                                    : If "External", we assume Oxygen is already installed on the system
   9 # -DQUASSEL_ICONS=(Builtin|External) : If "Builtin" (the default), put our own icons into the binary
  10 #                                    : If "External", we install our icons into $PREFIX/share/apps/quassel (UNIX only)
  11 # -DQT=/path/to/qt    : Choose a Qt4 installation to use instead of the system Qt4
  12 # -DSTATIC=ON         : Enable static building of Quassel. Use with care.
  13 # -DDEPLOY=ON         : Mac OS X only. Use only for creating Quassel Packages!
  14 #
  15 # NOTE: You need to remove CMakeCache.txt if you plan to change any of these values!
  16
  17 project(QuasselIRC)
  18
  19 cmake_minimum_required(VERSION 2.6.0 FATAL_ERROR)
  20
  21 if(COMMAND cmake_policy)
  22    cmake_policy(SET CMP0003 NEW)
  23 endif(COMMAND cmake_policy)
  24
  25 # Use our own (well, and KDE's) version of some modules
  26 # In particular cmake's FindQt4 and FindOpenSSL are quite buggy
  27 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  28
  29 # Various options and variables that can be set on the command line
  30 option(WANT_CORE     "Build the core (server) binary"           ON)
  31 option(WANT_QTCLIENT "Build the Qt4 GUI client binary"          ON)
  32 option(WANT_MONO     "Build the monolithic (all-in-one) binary" OFF)
  33
  34 option(WITH_OPENSSL  "Enable OpenSSL support if present on the system"  ON)
  35 option(WITH_DBUS     "Enable D-Bus support if present on the system"    ON)
  36
  37 option(STATIC        "Enable static building (might not be portable)" OFF)
  38 option(DEPLOY        "Mac OS X only! Adds required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF)
  39 option(SPUTDEV       "Do not use!" OFF)
  40
  41 set(OXYGEN_ICONS "Builtin" CACHE STRING "Builtin: Compile Oxygen icons into the binary; External: Use system-installed Oxygen")
  42 set(QUASSEL_ICONS "Builtin" CACHE STRING "Builtin: Compile Quassel icons into the binary; External: Install them separately")
  43
  44 set(QT "" CACHE STRING "Path to a Qt installation to use instead of the system Qt")
  45 set(LINGUAS "" CACHE STRING "Space-separated List of locales specifying languages that should be compiled")
  46
  47 if(STATIC)
  48   set(CMAKE_BUILD_TYPE Release)
  49   set(OXYGEN_ICONS "Builtin")
  50   set(QUASSEL_ICONS "Builtin")
  51 endif(STATIC)
  52
  53 # RPATH needs to be set correctly
  54 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
  55 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
  56
  57 # Define install locations. Using variables will allow overriding this by the KDE macros later.
  58 set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin)
  59 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps)
  60 set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons)
  61 set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications)
  62
  63 # Enable various flags on gcc
  64 if(CMAKE_COMPILER_IS_GNUCXX)
  65   # Let's just hope that all gccs support these options and skip the tests...
  66   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -ansi -Wall -Wextra -Wnon-virtual-dtor")
  67 endif(CMAKE_COMPILER_IS_GNUCXX)
  68
  69 set(QT_MIN_VERSION "4.4.0")
  70
  71 if(APPLE AND DEPLOY)
  72   set(CMAKE_OSX_ARCHITECTURES "i386;ppc")
  73   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.4")
  74   set(CMAKE_OSX_SYSROOT "/Developer/SDKs/MacOSX10.4u.sdk/")
  75   add_definitions(-DMAC_10_4_SDK)
  76 endif(APPLE AND DEPLOY)
  77
  78 include(QuasselMacros)
  79
  80 # Execinfo is needed for generating backtraces
  81 find_package(ExecInfo)
  82 if(EXECINFO_FOUND)
  83   add_definitions(-DHAVE_EXECINFO)
  84   include_directories(${EXECINFO_INCLUDES})
  85   link_libraries(${EXECINFO_LIBRARIES})
  86 endif(EXECINFO_FOUND)
  87
  88 # Select a Qt installation here, if you don't want to use system Qt
  89 if(QT)
  90   # FindQt4 will look for the qmake binary in $PATH, so we just prepend the Qt dir
  91   set(ENV{PATH} ${QT}/bin:$ENV{PATH})
  92 endif(QT)
  93
  94 # Now that we have the correct $PATH, lets find Qt!
  95 find_package(Qt4 REQUIRED)
  96
  97 set(QT_DONT_USE_QTGUI 1)
  98 include(${QT_USE_FILE})
  99 include_directories(${QT_INCLUDES})
 100
 101 # Setup OpenSSL
 102 if(WITH_OPENSSL)
 103   find_package(OpenSSL)
 104 else(WITH_OPENSSL)
 105   message(STATUS "Disabling OpenSSL support")
 106 endif(WITH_OPENSSL)
 107
 108 if(OPENSSL_FOUND)
 109   if(NOT QT_DEFINITIONS MATCHES "QT_NO_OPENSSL")
 110     message(STATUS "Found OpenSSL support in Qt")
 111     add_definitions(-DHAVE_SSL)
 112     set(HAVE_SSL true)
 113     set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_SSL)
 114   else(NOT QT_DEFINITIONS MATCHES "QT_NO_OPENSSL")
 115     message(STATUS "No OpenSSL support found in Qt, disabling")
 116   endif(NOT QT_DEFINITIONS MATCHES "QT_NO_OPENSSL")
 117 else(OPENSSL_FOUND)
 118   add_definitions(-DQT_NO_OPENSSL)
 119 endif(OPENSSL_FOUND)
 120
 121 # Setup D-Bus support
 122 if(WITH_DBUS)
 123   if(QT_QTDBUS_FOUND)
 124     message(STATUS "Found QtDBus, enabling D-Bus support")
 125     add_definitions(-DHAVE_DBUS)
 126     set(LINK_DBUS DBUS)
 127     set(HAVE_DBUS true)
 128     set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_DBUS)
 129   else(QT_QTDBUS_FOUND)
 130     message(STATUS "QtDBus not found, disabling D-Bus support")
 131   endif(QT_QTDBUS_FOUND)
 132 else(WITH_DBUS)
 133   message(STATUS "Disabling D-Bus support")
 134 endif(WITH_DBUS)
 135
 136 # Set global buildflags
 137 # This is very much non-portable, so don't use -DSTATIC until you know what
 138 # you do.
 139 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 140   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 141   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 142   if(HAVE_SSL)
 143     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 144   endif(HAVE_SSL)
 145 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 146
 147 if(STATIC AND WIN32)
 148   link_libraries(imm32 winmm)  # missing by default :/
 149    if(HAVE_SSL)
 150      link_libraries(${OPENSSL_LIBRARIES} libeay32MD)
 151    endif(HAVE_SSL)
 152 endif(STATIC AND WIN32)
 153
 154 if(WIN32)
 155   set(RC_WIN32 pics/win32.rc)  # for app icons on windows
 156 endif(WIN32)
 157
 158 # This is dirty, but I haven't found a cleaner way to ensure that the generated .qrc files
 159 # (which will be removed with make clean) are regenerated :/
 160 set_directory_properties(PROPERTIES
 161                          ADDITIONAL_MAKE_CLEAN_FILES CMakeCache.txt)
 162
 163 # We need to create a version.gen
 164 # For this, we create our genversion binary and make sure it is run every time.
 165 add_executable(genversion ${CMAKE_SOURCE_DIR}/src/common/genversion.cpp)
 166 target_link_libraries(genversion ${QT_LIBRARIES} ${QT_CORE_LIB_DEPENDENCIES})
 167
 168 get_target_property(GENVERSION_EXECUTABLE genversion LOCATION)
 169 add_custom_target(genversion_run ALL ${GENVERSION_EXECUTABLE}
 170                   ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR}/src/common/version.gen)
 171 add_dependencies(genversion_run genversion)
 172
 173 # Decide what to do with icons
 174 if(WANT_QTCLIENT OR WANT_MONO)
 175   if(QUASSEL_ICONS MATCHES "External")
 176     message(STATUS "Install Quassel icons to ${CMAKE_INSTALL_PREFIX}/share/apps/quassel")
 177   else(QUASSEL_ICONS MATCHES "External")
 178     set(QUASSEL_ICONS "Builtin")
 179     message(STATUS "Compile Quassel icons into the binary")
 180   endif(QUASSEL_ICONS MATCHES "External")
 181
 182   if(OXYGEN_ICONS MATCHES "External")
 183     message(STATUS "Use system-installed Oxygen icon theme")
 184   else(OXYGEN_ICONS MATCHES "External")
 185     set(OXYGEN_ICONS "Builtin")
 186     message(STATUS "Compile Oxygen icon theme subset into the binary")
 187   endif(OXYGEN_ICONS MATCHES "External")
 188 endif(WANT_QTCLIENT OR WANT_MONO)
 189
 190 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 191
 192 set(COMMON_DEPS ${RC_WIN32})
 193 set(CORE_DEPS )
 194 set(CLIENT_DEPS )
 195 set(KDE_DEPS )
 196
 197 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 198 add_subdirectory(data)
 199 add_subdirectory(icons)
 200 #add_subdirectory(pics)
 201 add_subdirectory(i18n)
 202 add_subdirectory(src)
 203
 204 # Make sure version.gen exists before building mod_common
 205 # TODO: make only main.cpp depend on that! Recompiles suck...
 206 add_dependencies(mod_common genversion_run)