CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 cmake_minimum_required(VERSION 3.5)
  10
  11 # Tell CMake about or own modules
  12 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  13
  14 include(QuasselVersion)
  15
  16 message(STATUS "Using CMake ${CMAKE_VERSION}")
  17
  18 # Set up build type rather early
  19 include(BuildType)
  20
  21 # Support ccache if found
  22 # This should happen before calling project(), so compiler settings are validated.
  23 option(USE_CCACHE "Enable support for ccache if available" ON)
  24 if (USE_CCACHE)
  25     message(STATUS "Checking for ccache")
  26     find_program(CCACHE_PROGRAM ccache)
  27     if (CCACHE_PROGRAM)
  28         set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_PROGRAM}")
  29         message(STATUS "Checking for ccache - enabled")
  30     else()
  31         message(STATUS "Checking for ccache - not found")
  32     endif()
  33 endif()
  34
  35 # Set up project
  36 project(Quassel CXX)
  37
  38 # Let CMake handle file generation for Qt
  39 set(CMAKE_AUTOMOC ON)
  40 set(CMAKE_AUTORCC ON)
  41 set(CMAKE_AUTOUIC ON)
  42
  43 # Needed, otherwise some .moc files won't be found with older CMake versions
  44 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  45
  46 # Include various CMake modules...
  47 include(CMakePushCheckState)
  48 include(CheckFunctionExists)
  49 include(CheckIncludeFileCXX)
  50 include(CheckCXXSourceCompiles)
  51 include(CMakeDependentOption)
  52 include(FeatureSummary)
  53
  54 # ... and our own
  55 include(QuasselCompileSettings)
  56 include(QuasselMacros)
  57
  58 # Options and variables that can be set on the command line
  59 #####################################################################
  60
  61 # Select the binaries to build
  62 option(WANT_CORE     "Build the core (server) binary"           ON)
  63 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  64 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  65 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  66 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  67 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  68
  69 # Whether to enable integration with higher-tier KDE frameworks that require runtime support.
  70 # We still optionally make use of certain Tier 1 frameworks even if WITH_KDE is disabled.
  71 option(WITH_KDE "Integration with the KDE Frameworks runtime environment")
  72 add_feature_info(WITH_KDE WITH_KDE "Integrate with the KDE Frameworks runtime environment")
  73
  74 # Icon theme support. By default, install the Breeze icon theme (may be disabled if a system installation is present)
  75 option(WITH_BUNDLED_ICONS "Install required icons from the Breeze icon theme" ON)
  76 add_feature_info(WITH_BUNDLED_ICONS WITH_BUNDLED_ICONS "Install required icons from the Breeze icon theme")
  77
  78 option(WITH_OXYGEN_ICONS "Support the Oxygen icon theme (KDE4)" OFF)
  79 add_feature_info(WITH_OXYGEN_ICONS WITH_OXYGEN_ICONS "Support the Oxygen icon theme (KDE4)")
  80
  81 # For this, the feature info is added after we know if QtWebkit is installed
  82 option(WITH_WEBKIT "WebKit support (for link previews) (legacy)" OFF)
  83
  84 # For this, the feature info is added after we know if QtWebEngine is installed
  85 option(WITH_WEBENGINE "WebEngine support (for link previews)" ON)
  86
  87 if (APPLE)
  88     # Notification Center is only available in > 10.8, which is Darwin v12
  89     if (NOT CMAKE_SYSTEM_VERSION VERSION_LESS 12)
  90         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
  91         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
  92     endif()
  93     find_library(CARBON_LIBRARY Carbon)
  94     mark_as_advanced(CARBON_LIBRARY)
  95     link_libraries(${CARBON_LIBRARY})
  96 endif()
  97
  98 # Always embed on Windows or OSX; never embed when enabling KDE integration
  99 set(EMBED_DEFAULT OFF)
 100 if (WIN32 OR APPLE)
 101     set(EMBED_DEFAULT ON)
 102 endif()
 103 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
 104                                    "NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
 105 if (NOT EMBED_DEFAULT)
 106     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
 107 endif()
 108
 109 # The following options are not for end-user consumption, so don't list them in the feature summary
 110 option(FATAL_WARNINGS "Make compile warnings fatal (most useful for CI builds)" OFF)
 111 option(WARN_QT_DEPRECATION "Warn about deprecated Qt functionality" OFF)
 112 if (WARN_QT_DEPRECATION)
 113     # Enable Qt deprecation warnings for Qt < 5.13 (on by default in newer versions)
 114     add_definitions("-DQT_DEPRECATED_WARNINGS")
 115 endif()
 116 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg" OFF "APPLE" OFF)
 117
 118 # List of authenticators and the cmake flags to build them
 119 # (currently that's just LDAP, but more can be added here).
 120 ####################################################################
 121 option(WITH_LDAP "Enable LDAP authentication support if present on system" ON)
 122
 123 # Setup CMake
 124 #####################################################################
 125
 126 # Visibility settings apply to all targets
 127 if (POLICY CMP0063)
 128     cmake_policy(SET CMP0063 NEW)
 129 endif()
 130
 131 # Let automoc/autouic process generated files
 132 if (POLICY CMP0071)
 133     cmake_policy(SET CMP0071 NEW)
 134 endif()
 135
 136 set(BUILD_SHARED_LIBS TRUE CACHE BOOL "" FORCE)
 137
 138 # Don't use X11 on OSX
 139 if (APPLE)
 140     set(CMAKE_DISABLE_FIND_PACKAGE_X11 true)
 141     set(CMAKE_DISABLE_FIND_PACKAGE_XCB true)
 142     set(CMAKE_DISABLE_FIND_PACKAGE_Qt5X11Extras true)
 143 endif()
 144
 145 # Simplify later checks
 146 #####################################################################
 147
 148 if (WANT_MONO OR WANT_QTCLIENT)
 149     set(BUILD_GUI true)
 150 endif()
 151 if (WANT_MONO OR WANT_CORE)
 152     set(BUILD_CORE true)
 153 endif()
 154
 155 # Set up Qt
 156 #####################################################################
 157
 158 # Find package dependencies
 159 #
 160 # Note that you can forcefully disable optional packages
 161 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 162 #####################################################################
 163
 164 set(QT_MIN_VERSION "5.5.0")
 165
 166 # Required Qt components
 167 set(qt_components Core Network)
 168 if (BUILD_GUI)
 169     list(APPEND qt_components Gui Widgets)
 170 endif()
 171 if (BUILD_CORE)
 172     list(APPEND qt_components Sql)
 173 endif()
 174
 175 find_package(Qt5 ${QT_MIN_VERSION} REQUIRED COMPONENTS ${qt_components})
 176 set_package_properties(Qt5 PROPERTIES TYPE REQUIRED
 177     URL "https://www.qt.io/"
 178     DESCRIPTION "the Qt libraries"
 179 )
 180 message(STATUS "Found Qt ${Qt5Core_VERSION}")
 181
 182 # Check for SSL support in Qt
 183 cmake_push_check_state(RESET)
 184 set(CMAKE_REQUIRED_LIBRARIES Qt5::Core)
 185 check_cxx_source_compiles("
 186     #include \"qglobal.h\"
 187     #if defined QT_NO_SSL
 188     #  error \"No SSL support\"
 189     #endif
 190     int main() {}"
 191     HAVE_SSL)
 192 cmake_pop_check_state()
 193
 194 if (NOT HAVE_SSL)
 195     message(FATAL_ERROR "Quassel requires SSL support, but Qt is built with QT_NO_SSL")
 196 endif()
 197
 198 # Optional Qt components
 199
 200 find_package(Qt5LinguistTools QUIET)
 201 set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 202     DESCRIPTION "contains tools for handling translation files"
 203     PURPOSE "Required for having translations"
 204 )
 205
 206 if (BUILD_GUI)
 207     if (NOT WIN32)
 208         find_package(Qt5DBus QUIET)
 209         set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 210             URL "https://www.qt.io/"
 211             DESCRIPTION "D-Bus support for Qt5"
 212             PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 213         )
 214         if (Qt5DBus_FOUND)
 215             find_package(dbusmenu-qt5 QUIET CONFIG)
 216             set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 217                 URL "https://launchpad.net/libdbusmenu-qt"
 218                 DESCRIPTION "a library implementing the DBusMenu specification"
 219                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 220             )
 221         endif()
 222     endif()
 223
 224     find_package(Qt5Multimedia QUIET)
 225     set_package_properties(Qt5Multimedia PROPERTIES TYPE RECOMMENDED
 226         URL "https://www.qt.io/"
 227         DESCRIPTION "Multimedia support for Qt5"
 228         PURPOSE     "Required for audio notifications"
 229     )
 230
 231     # snorenotify segfaults on startup on msys2
 232     # we don't check for just MSYS to support the Ninja generator
 233     if(NOT (WIN32 AND (NOT $ENV{MSYSTEM} STREQUAL "")))
 234         find_package(LibsnoreQt5 0.7.0 QUIET)
 235         set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
 236             URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 237             DESCRIPTION "a cross-platform notification framework"
 238             PURPOSE     "Enable support for the snorenotify framework"
 239         )
 240         if (LibsnoreQt5_FOUND)
 241             find_package(LibsnoreSettingsQt5 QUIET)
 242             set_package_properties(LibsnoreSettingsQt5 PROPERTIES TYPE OPTIONAL
 243                 URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 244                 DESCRIPTION "a cross-platform notification framework"
 245                 PURPOSE     "Enable support for the snorenotify framework"
 246             )
 247         endif()
 248     endif()
 249
 250     if (WITH_WEBENGINE)
 251         find_package(Qt5WebEngine QUIET)
 252         set_package_properties(Qt5WebEngine PROPERTIES TYPE RECOMMENDED
 253             URL "https://www.qt.io/"
 254             DESCRIPTION "a WebEngine implementation for Qt"
 255             PURPOSE     "Needed for displaying previews for URLs in chat"
 256         )
 257         if (Qt5WebEngine_FOUND)
 258             find_package(Qt5WebEngineWidgets QUIET)
 259             set_package_properties(Qt5WebEngineWidgets PROPERTIES TYPE RECOMMENDED
 260                 URL "https://www.qt.io/"
 261                 DESCRIPTION "widgets for Qt's WebEngine implementation"
 262                 PURPOSE     "Needed for displaying previews for URLs in chat"
 263             )
 264         endif()
 265     endif()
 266
 267     if (WITH_WEBENGINE AND Qt5WebEngineWidgets_FOUND)
 268         set(HAVE_WEBENGINE true)
 269     endif()
 270     add_feature_info("WITH_WEBENGINE, QtWebEngine and QtWebEngineWidgets modules" HAVE_WEBENGINE "Support showing previews for URLs in chat")
 271
 272     if (NOT HAVE_WEBENGINE)
 273         if (WITH_WEBKIT)
 274             find_package(Qt5WebKit QUIET)
 275             set_package_properties(Qt5WebKit PROPERTIES TYPE OPTIONAL
 276                 URL "https://www.qt.io/"
 277                 DESCRIPTION "a WebKit implementation for Qt"
 278                 PURPOSE     "Needed for displaying previews for URLs in chat"
 279                 )
 280             if (Qt5WebKit_FOUND)
 281                 find_package(Qt5WebKitWidgets QUIET)
 282                 set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE OPTIONAL
 283                     URL "https://www.qt.io/"
 284                     DESCRIPTION "widgets for Qt's WebKit implementation"
 285                     PURPOSE     "Needed for displaying previews for URLs in chat"
 286                     )
 287             endif()
 288         endif()
 289
 290         if (WITH_WEBKIT AND Qt5WebKitWidgets_FOUND)
 291             set(HAVE_WEBKIT true)
 292         endif()
 293         add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" HAVE_WEBKIT "Support showing previews for URLs in chat (legacy)")
 294     endif()
 295
 296     # KDE Frameworks
 297     ################
 298
 299     # extra-cmake-modules
 300     if (WITH_KDE)
 301         set(ecm_find_type "REQUIRED")
 302         find_package(ECM NO_MODULE REQUIRED)
 303     else()
 304         # Even with KDE integration disabled, we optionally use tier1 frameworks if we find them
 305         set(ecm_find_type "RECOMMENDED")
 306         find_package(ECM NO_MODULE QUIET)
 307     endif()
 308
 309     set_package_properties(ECM PROPERTIES TYPE ${ecm_find_type}
 310         URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules"
 311         DESCRIPTION "extra modules for CMake, maintained by the KDE project"
 312         PURPOSE     "Required to find KDE Frameworks components"
 313     )
 314
 315     if (ECM_FOUND)
 316         list(APPEND CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
 317         if (WITH_KDE)
 318             find_package(KF5 REQUIRED COMPONENTS ConfigWidgets CoreAddons Notifications NotifyConfig Sonnet TextWidgets WidgetsAddons XmlGui)
 319             set_package_properties(KF5 PROPERTIES TYPE REQUIRED
 320                 URL "http://www.kde.org"
 321                 DESCRIPTION "KDE Frameworks"
 322                 PURPOSE     "Required for integration into the Plasma desktop"
 323             )
 324             message(STATUS "Found KDE Frameworks ${KF5_VERSION}")
 325         endif()
 326
 327         # Optional KF5 tier1 components
 328         find_package(KF5Sonnet QUIET)
 329         set_package_properties(KF5Sonnet PROPERTIES TYPE RECOMMENDED
 330             URL "http://api.kde.org/frameworks-api/frameworks5-apidocs/sonnet/html"
 331             DESCRIPTION "framework for providing spell-checking capabilities"
 332             PURPOSE "Enables spell-checking support in input widgets"
 333         )
 334     endif()
 335 endif()
 336
 337 if (BUILD_CORE)
 338     find_package(Qca-qt5 2.0 QUIET)
 339     set_package_properties(Qca-qt5 PROPERTIES TYPE RECOMMENDED
 340         URL "https://projects.kde.org/projects/kdesupport/qca"
 341         DESCRIPTION "Qt Cryptographic Architecture"
 342         PURPOSE "Required for encryption support"
 343     )
 344
 345     if (WITH_LDAP)
 346         find_package(Ldap QUIET)
 347         set_package_properties(Ldap PROPERTIES TYPE OPTIONAL
 348             URL "http://www.openldap.org/"
 349             DESCRIPTION "LDAP (Lightweight Directory Access Protocol) libraries"
 350             PURPOSE "Enables core user authentication via LDAP"
 351         )
 352     endif()
 353 endif()
 354
 355 # Non-Qt-based packages
 356 #####################################################################
 357
 358 find_package(Boost 1.54 REQUIRED)
 359 set_package_properties(Boost PROPERTIES TYPE REQUIRED
 360     URL "https://www.boost.org/"
 361     DESCRIPTION "Boost libraries for C++"
 362 )
 363 # Older versions don't define the imported target
 364 if (NOT TARGET Boost::boost)
 365     add_library(Boost::boost INTERFACE IMPORTED GLOBAL)
 366     if (Boost_INCLUDE_DIRS)
 367         set_target_properties(Boost::boost PROPERTIES
 368             INTERFACE_INCLUDE_DIRECTORIES "${Boost_INCLUDE_DIRS}")
 369     endif()
 370 endif()
 371
 372 find_package(ZLIB REQUIRED)
 373 set_package_properties(ZLIB PROPERTIES TYPE REQUIRED
 374     URL "http://www.zlib.net"
 375     DESCRIPTION "a popular compression library"
 376     PURPOSE     "Used for protocol compression"
 377 )
 378
 379 if (NOT WIN32)
 380     # Needed for generating backtraces
 381     find_package(Backtrace QUIET)
 382     set_package_properties(Backtrace PROPERTIES TYPE RECOMMENDED
 383         DESCRIPTION "a header (and possibly library) for inspecting backtraces"
 384         PURPOSE "Used for generating backtraces in case of a crash"
 385     )
 386 endif()
 387
 388 # Shared library support
 389 #####################################################################
 390
 391 option(ENABLE_SHARED "Build modules as shared libraries" ON)
 392 add_feature_info(ENABLE_SHARED ENABLE_SHARED "Build modules as shared libraries")
 393
 394 # Setup unit testing
 395 #####################################################################
 396
 397 option(BUILD_TESTING "Enable unit tests" OFF)
 398 add_feature_info(BUILD_TESTING BUILD_TESTING "Build unit tests")
 399
 400 if (BUILD_TESTING)
 401     find_package(GTest QUIET)
 402     set_package_properties(GTest PROPERTIES TYPE REQUIRED
 403         DESCRIPTION "Google's unit testing framework"
 404         PURPOSE "Required for building unit tests"
 405     )
 406
 407     find_package(Qt5Test QUIET)
 408     set_package_properties(Qt5Test PROPERTIES TYPE REQUIRED
 409         DESCRIPTION "unit testing library for the Qt5 framework"
 410         PURPOSE "Required for building unit tests"
 411     )
 412     enable_testing()
 413
 414     # GTest messes with CMAKE_CXX_FLAGS, so process them again
 415     process_cmake_cxx_flags()
 416 endif()
 417
 418 # Setup support for KDE Frameworks
 419 #####################################################################
 420
 421 if (WITH_KDE)
 422     add_definitions(-DHAVE_KDE -DHAVE_KF5)
 423     set(WITH_KF5 TRUE)
 424
 425     # If KDE Frameworks are present, they're most probably providing Qt5 integration including icon loading
 426     set(EMBED_DATA OFF)
 427
 428     include(KDEInstallDirs)
 429 endif()
 430
 431 # This needs to come after setting up KDE integration, so we can use KDE-specific paths
 432 include(QuasselInstallDirs)
 433
 434 # RPATH and output settings
 435 #####################################################################
 436
 437 # Build artifacts in a well-known location; especially important for Windows DLLs
 438 # (which go into RUNTIME_OUTPUT_DIRECTORY and can thus be found by executables)
 439 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/bin")
 440 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib")
 441 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib")
 442
 443 # These RPATH settings allow for running directly from the build dir
 444 set(CMAKE_SKIP_BUILD_RPATH            FALSE)
 445 set(CMAKE_BUILD_WITH_INSTALL_RPATH    FALSE)
 446 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE )
 447
 448 # Set install RPATH only if libdir isn't a system directory
 449 if (IS_ABSOLUTE "${CMAKE_INSTALL_LIBDIR}")
 450     set(libdir "${CMAKE_INSTALL_LIBDIR}")
 451 else()
 452     set(libdir "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_LIBDIR}")
 453 endif()
 454 list(FIND CMAKE_PLATFORM_IMPLICIT_LINK_DIRECTORIES "${libdir}" is_systemdir)
 455 if ("${is_systemdir}" STREQUAL "-1")
 456    set(CMAKE_INSTALL_RPATH "${libdir}")
 457 endif()
 458
 459 # Various config-dependent checks and settings
 460 #####################################################################
 461
 462 # Check for syslog support
 463 if (NOT WIN32)
 464     check_include_file_cxx(syslog.h HAVE_SYSLOG)
 465     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 466 endif()
 467
 468 if (NOT WIN32)
 469     check_function_exists(umask HAVE_UMASK)
 470 endif()
 471
 472 if (EMBED_DATA)
 473     message(STATUS "Embedding data files into the binary")
 474 else()
 475     message(STATUS "Installing data files separately")
 476 endif()
 477
 478 # Windows-specific stuff
 479 #####################################################################
 480
 481 if (WIN32)
 482     link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 483     if (MSVC)
 484         link_libraries(Version dwmapi shlwapi)
 485     endif()
 486 endif()
 487
 488 # Prepare the build
 489 #####################################################################
 490
 491 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 492 add_subdirectory(data)
 493 add_subdirectory(icons)
 494 add_subdirectory(pics)
 495 add_subdirectory(po)
 496
 497 # Set up and display feature summary
 498 #####################################################################
 499
 500 feature_summary(WHAT ALL
 501                 INCLUDE_QUIET_PACKAGES
 502                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 503 )
 504
 505 # Finally, compile the sources
 506 # We want this after displaying the feature summary to avoid ugly
 507 # CMake backtraces in case a required Qt5 module is missing
 508 #####################################################################
 509
 510 add_subdirectory(src)
 511
 512 # Build tests if so desired
 513 if (BUILD_TESTING)
 514     add_subdirectory(tests)
 515 endif()