CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 project(QuasselIRC)
  10
  11 # Versions
  12 set(QUASSEL_MAJOR  0)
  13 set(QUASSEL_MINOR 12)
  14 set(QUASSEL_PATCH  4)
  15 set(QUASSEL_VERSION_STRING "0.12.4")
  16
  17 # We want to know CMake's version for debug reasons
  18 message(STATUS "Using CMake ${CMAKE_VERSION}")
  19
  20 # Tell CMake about or own modules
  21 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  22
  23 # General conveniences
  24 set(CMAKE_AUTOMOC ON)
  25 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  26
  27 # Include various CMake modules...
  28 include(CMakePushCheckState)
  29 include(CheckFunctionExists)
  30 include(CheckIncludeFile)
  31 include(CheckCXXSourceCompiles)
  32 include(CMakeDependentOption)
  33 include(FeatureSummary)
  34
  35 # ... and our own stuff
  36 include(QuasselCompileSettings)
  37 include(QuasselMacros)
  38
  39
  40 # Options and variables that can be set on the command line
  41 #####################################################################
  42
  43 # First, choose a Qt version. We support USE_QT4 and USE_QT5; if neither is set, prefer Qt4 for now
  44 option(USE_QT5 "Enable support for Qt5 (disables KDE integration)" OFF)
  45 if (USE_QT4) # takes precedence
  46     set(USE_QT5 OFF)
  47 else()
  48     if (NOT USE_QT5)
  49         set(USE_QT4 ON)
  50     endif()
  51 endif()
  52
  53 # Select the binaries to build
  54 option(WANT_CORE     "Build the core (server) binary"           ON)
  55 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  56 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  57 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  58 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  59 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  60
  61 # Whether to enable KDE integration (work in progress for Qt5 / KDE Frameworks)
  62 # Note that when building with Qt5, WITH_KDE enables integration with higher-tier KDE frameworks that
  63 # require runtime support. We still optionally make use of certain Tier 1 frameworks even if WITH_KDE
  64 # is disabled.
  65 if (USE_QT4)
  66     option(WITH_KDE "KDE4 integration" OFF)
  67     add_feature_info(WITH_KDE WITH_KDE "Enable KDE4 integration")
  68 else()
  69     option(WITH_KDE "Integration with the KDE Frameworks runtime environment")
  70     add_feature_info(WITH_KDE WITH_KDE "Integrate with the KDE Frameworks runtime environment")
  71 endif()
  72
  73 cmake_dependent_option(WITH_OXYGEN "Install Oxygen icon set (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
  74 if (NOT WITH_KDE)
  75     add_feature_info(WITH_OXYGEN WITH_OXYGEN "Install Oxygen icon set")
  76 endif()
  77
  78 # For this, the feature info is added after we know if QtWebkit is installed
  79 option(WITH_WEBKIT "WebKit support (for link previews) (legacy)" OFF)
  80
  81 # For this, the feature info is added after we know if QtWebEngine is installed
  82 option(WITH_WEBENGINE "WebEngine support (for link previews)" ON)
  83
  84 if (APPLE)
  85     # Notification Center is only available in > 10.8, which is Darwin v12
  86     if (NOT CMAKE_SYSTEM_VERSION VERSION_LESS 12)
  87         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
  88         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
  89     endif()
  90     find_library(CARBON_LIBRARY Carbon)
  91     mark_as_advanced(CARBON_LIBRARY)
  92     link_libraries(${CARBON_LIBRARY})
  93 endif()
  94
  95 # Always embed on Windows, OSX or for a static build; never embed when enabling KDE integration
  96 set(EMBED_DEFAULT OFF)
  97 if (STATIC OR WIN32 OR APPLE)
  98     set(EMBED_DEFAULT ON)
  99 endif()
 100 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
 101                                    "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
 102 if (NOT EMBED_DEFAULT)
 103     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
 104 endif()
 105
 106 # The following options are not for end-user consumption, so don't list them in the feature summary
 107 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
 108
 109 # Handle with care
 110 set(QT_PATH "" CACHE PATH "Path to a Qt4 installation to use instead of the system Qt (e.g. for static builds)")
 111
 112 # Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
 113 cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
 114
 115 # For static builds, arbitrary extra libs might need to be linked
 116 # Define a comma-separated list here
 117 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 118 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 119 if (LINK_EXTRA)
 120     string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 121     link_libraries(${LINK_EXTRA})
 122 endif()
 123
 124
 125 # Setup CMake
 126 #####################################################################
 127
 128 if (USE_QT5 AND WITH_KDE)
 129     cmake_minimum_required(VERSION 2.8.12)
 130 else()
 131     cmake_minimum_required(VERSION 2.8.9)
 132 endif()
 133
 134 # Setting COMPILE_DEFINITIONS_<CONFIG> is deprecated since CMake 3.0 in favor of generator expressions.
 135 # These have existed since CMake 2.8.10; until we depend on that, we have to explicitly enable the old policy.
 136 if (POLICY CMP0043)
 137     cmake_policy(SET CMP0043 OLD)
 138 endif()
 139
 140 # Honor visibility settings for all target types
 141 if (POLICY CMP0063)
 142     cmake_policy(SET CMP0063 NEW)
 143 endif()
 144
 145
 146 # Simplify later checks
 147 #####################################################################
 148
 149 if (WANT_MONO OR WANT_QTCLIENT)
 150     set(BUILD_GUI true)
 151 endif()
 152 if (WANT_MONO OR WANT_CORE)
 153     set(BUILD_CORE true)
 154 endif()
 155
 156
 157 # Set up Qt
 158 #####################################################################
 159
 160 # Find package dependencies
 161 #
 162 # Note that you can forcefully disable optional packages
 163 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 164 #####################################################################
 165
 166 if (USE_QT5)
 167     message(STATUS "Building for Qt5...")
 168     set(QT_MIN_VERSION "5.2.0")
 169     add_definitions(-DHAVE_QT5)
 170
 171     find_package(Qt5Core ${QT_MIN_VERSION} QUIET)
 172     set_package_properties(Qt5Core PROPERTIES TYPE REQUIRED
 173         URL "http://qt.digia.com"
 174         DESCRIPTION "contains core functionality for Qt"
 175     )
 176     # find_package without REQUIRED won't check for the version properly; also, older Qt5 versions
 177     # used Qt5Core_VERSION_STRING... let's just make sure here that we bail out here if our Qt5 is not new enough.
 178     if (NOT Qt5Core_VERSION OR Qt5Core_VERSION VERSION_LESS ${QT_MIN_VERSION})
 179         message(FATAL_ERROR "Could NOT find Qt5 >= version ${QT_MIN_VERSION}!")
 180     endif()
 181
 182     find_package(Qt5Network QUIET)
 183     set_package_properties(Qt5Network PROPERTIES TYPE REQUIRED
 184         DESCRIPTION "the network module for Qt5"
 185     )
 186
 187     if (BUILD_GUI)
 188         find_package(Qt5Gui QUIET)
 189         set_package_properties(Qt5Gui PROPERTIES TYPE REQUIRED
 190             DESCRIPTION "the GUI module for Qt5"
 191         )
 192         find_package(Qt5Widgets QUIET)
 193         set_package_properties(Qt5Widgets PROPERTIES TYPE REQUIRED
 194             DESCRIPTION "the widgets module for Qt5"
 195         )
 196
 197         if (NOT WIN32)
 198             find_package(Qt5DBus QUIET)
 199             set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 200                 URL "http://qt.digia.com"
 201                 DESCRIPTION "D-Bus support for Qt5"
 202                 PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 203             )
 204             if (Qt5DBus_FOUND)
 205                 find_package(dbusmenu-qt5 QUIET CONFIG)
 206                 set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 207                     URL "https://launchpad.net/libdbusmenu-qt"
 208                     DESCRIPTION "a library implementing the DBusMenu specification"
 209                     PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 210                 )
 211             endif()
 212         endif()
 213
 214         find_package(Phonon4Qt5 QUIET)
 215         set_package_properties(Phonon4Qt5 PROPERTIES TYPE RECOMMENDED
 216             URL "https://projects.kde.org/projects/kdesupport/phonon"
 217             DESCRIPTION "a multimedia abstraction library"
 218             PURPOSE     "Required for audio notifications"
 219         )
 220
 221         find_package(LibsnoreQt5 0.7.0 QUIET)
 222         set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
 223             URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 224             DESCRIPTION "a cross-platform notification framework"
 225             PURPOSE     "Enable support for the snorenotify framework"
 226         )
 227         if(LibsnoreQt5_FOUND)
 228             find_package(LibsnoreSettingsQt5)
 229             set_package_properties(LibsnoreSettingsQt5 PROPERTIES TYPE REQUIRED
 230                 URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 231                 DESCRIPTION "a cross-platform notification framework"
 232                 PURPOSE     "Enable support for the snorenotify framework"
 233             )
 234         endif()
 235
 236
 237         if (WITH_WEBKIT)
 238             find_package(Qt5WebKit QUIET)
 239             set_package_properties(Qt5WebKit PROPERTIES TYPE RECOMMENDED
 240                 URL "http://qt.digia.com"
 241                 DESCRIPTION "a WebKit implementation for Qt"
 242                 PURPOSE     "Needed for displaying previews for URLs in chat"
 243             )
 244             if (Qt5WebKit_FOUND)
 245                 find_package(Qt5WebKitWidgets QUIET)
 246                 set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE RECOMMENDED
 247                     URL "http://qt.digia.com"
 248                     DESCRIPTION "widgets for Qt's WebKit implementation"
 249                     PURPOSE     "Needed for displaying previews for URLs in chat"
 250                 )
 251             endif()
 252         endif()
 253
 254         if (WITH_WEBKIT AND Qt5WebKitWidgets_FOUND)
 255             set(HAVE_WEBKIT true)
 256         endif()
 257         add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" HAVE_WEBKIT "Support showing previews for URLs in chat (legacy)")
 258
 259         if (WITH_WEBENGINE)
 260             find_package(Qt5WebEngine QUIET)
 261             set_package_properties(Qt5WebEngine PROPERTIES TYPE RECOMMENDED
 262                 URL "http://qt.digia.com"
 263                 DESCRIPTION "a WebEngine implementation for Qt"
 264                 PURPOSE     "Needed for displaying previews for URLs in chat"
 265             )
 266             if (Qt5WebEngine_FOUND)
 267                 find_package(Qt5WebEngineWidgets QUIET)
 268                 set_package_properties(Qt5WebEngineWidgets PROPERTIES TYPE RECOMMENDED
 269                     URL "http://qt.digia.com"
 270                     DESCRIPTION "widgets for Qt's WebEngine implementation"
 271                     PURPOSE     "Needed for displaying previews for URLs in chat"
 272                 )
 273             endif()
 274         endif()
 275
 276         if (WITH_WEBENGINE AND Qt5WebEngineWidgets_FOUND)
 277             set(HAVE_WEBENGINE true)
 278         endif()
 279         add_feature_info("WITH_WEBENGINE, QtWebEngine and QtWebEngineWidgets modules" HAVE_WEBENGINE "Support showing previews for URLs in chat")
 280
 281         # KDE Frameworks
 282         ################
 283
 284         if (WITH_KDE)
 285             set(ecm_find_type "REQUIRED")
 286         else()
 287             # Even with KDE integration disabled, we optionally use tier1 frameworks if we find them
 288             set(ecm_find_type "RECOMMENDED")
 289         endif()
 290
 291         # extra-cmake-modules
 292         find_package(ECM NO_MODULE QUIET)
 293         set_package_properties(ECM PROPERTIES TYPE ${ecm_find_type}
 294             URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules"
 295             DESCRIPTION "extra modules for CMake, maintained by the KDE project"
 296             PURPOSE     "Required to find KDE Frameworks components"
 297         )
 298
 299         if (ECM_FOUND)
 300             list(APPEND CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
 301         endif()
 302
 303         if (WITH_KDE)
 304             find_package(KF5 COMPONENTS ConfigWidgets CoreAddons Notifications NotifyConfig TextWidgets WidgetsAddons XmlGui QUIET)
 305             set_package_properties(KF5 PROPERTIES TYPE REQUIRED
 306                 URL "http://www.kde.org"
 307                 DESCRIPTION "KDE Frameworks"
 308                 PURPOSE     "Required for integration into the Plasma desktop"
 309             )
 310
 311         endif()
 312
 313     endif(BUILD_GUI)
 314
 315     if (BUILD_CORE)
 316         find_package(Qt5Script QUIET)
 317         set_package_properties(Qt5Script PROPERTIES TYPE REQUIRED
 318             DESCRIPTION "provides scripting support for Qt5"
 319         )
 320         find_package(Qt5Sql QUIET)
 321         set_package_properties(Qt5Sql PROPERTIES TYPE REQUIRED
 322             DESCRIPTION "the database support module for Qt5"
 323         )
 324
 325         find_package(QCA2-QT5)
 326         set_package_properties(QCA2-QT5 PROPERTIES TYPE RECOMMENDED
 327             URL "https://projects.kde.org/projects/kdesupport/qca"
 328             DESCRIPTION "Qt Cryptographic Architecture"
 329             PURPOSE "Required for encryption support"
 330         )
 331
 332     endif(BUILD_CORE)
 333
 334     find_package(Qt5LinguistTools QUIET)
 335     set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 336                            DESCRIPTION "contains tools for handling translation files"
 337                            PURPOSE "Required for having translations"
 338     )
 339
 340     # Some Qt5 versions do not define a target for lconvert, so we need to find it ourselves
 341     if (Qt5LinguistTools_FOUND)
 342         if (NOT TARGET Qt5::lconvert AND TARGET Qt5::lrelease)
 343             get_target_property(_lrelease_location Qt5::lrelease LOCATION)
 344             get_filename_component(_lrelease_path ${_lrelease_location} PATH)
 345             find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 346         elseif(TARGET Qt5::lconvert AND NOT Qt5_LCONVERT_EXECUTABLE)
 347             # Newer Qt5 versions define the target, but not the Qt5_LCONVERT_EXECUTABLE variable for some reason
 348             get_target_property(QT_LCONVERT_EXECUTABLE Qt5::lconvert LOCATION)
 349         endif()
 350
 351         # Compatibility with the Qt4 variables
 352         set(QT_LRELEASE_EXECUTABLE ${Qt5_LRELEASE_EXECUTABLE})
 353         set(QT_LUPDATE_EXECUTABLE ${Qt5_LUPDATE_EXECUTABLE})
 354         if (Qt5_LCONVERT_EXECUTABLE)
 355             set(QT_LCONVERT_EXECUTABLE ${Qt5_LCONVERT_EXECUTABLE})
 356         endif()
 357     endif()
 358
 359 else(USE_QT5)
 360     message(STATUS "Building for Qt4...")
 361     set(QT_MIN_VERSION "4.8.0")
 362
 363     # Select a Qt installation here, if you don't want to use system Qt
 364     if(QT_PATH)
 365         # FindQt4 will look for the qmake binary in $PATH, so we just prepend QT_PATH
 366         set(ENV{PATH} ${QT_PATH}/bin:$ENV{PATH})
 367     endif()
 368
 369     find_package(Qt4 ${QT_MIN_VERSION} QUIET REQUIRED)
 370
 371     if (BUILD_GUI)
 372         add_feature_info("QtDBus module" QT_QTDBUS_FOUND "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments")
 373         if (QT_QTDBUS_FOUND)
 374             find_package(dbusmenu-qt QUIET CONFIG)
 375             set_package_properties(dbusmenu-qt PROPERTIES TYPE RECOMMENDED
 376                 URL "https://launchpad.net/libdbusmenu-qt"
 377                 DESCRIPTION "a library implementing the DBusMenu specification"
 378                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 379             )
 380         endif()
 381
 382         if (WITH_WEBKIT AND QT_QTWEBKIT_FOUND)
 383             set(HAVE_WEBKIT true)
 384         endif()
 385         add_feature_info("WITH_WEBKIT and QtWebKit module" HAVE_WEBKIT "Support showing previews for URLs in chat")
 386
 387         if (WITH_KDE)
 388             # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 389             set(_cflags ${CMAKE_C_FLAGS})
 390             find_package(KDE4 4.4 QUIET)
 391             set_package_properties(KDE4 PROPERTIES TYPE REQUIRED
 392                 URL "http://www.kde.org"
 393                 DESCRIPTION "a world-class desktop environment"
 394                 PURPOSE "Enables various bits for improving integration with KDE"
 395             )
 396             set(CMAKE_C_FLAGS ${_cflags})
 397
 398         else(WITH_KDE)
 399             find_package(Phonon QUIET)
 400             set_package_properties(Phonon PROPERTIES TYPE RECOMMENDED
 401                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 402                 DESCRIPTION "a multimedia abstraction library"
 403                 PURPOSE     "Required for audio notifications"
 404             )
 405         endif(WITH_KDE)
 406
 407         find_package(IndicateQt QUIET)
 408         set_package_properties(IndicateQt PROPERTIES TYPE OPTIONAL
 409             URL "https://launchpad.net/libindicate-qt/"
 410             DESCRIPTION "a library to raise flags on DBus for other components of the desktop to pick up and visualize"
 411             PURPOSE     "Provides integration into the Ayatana notification system used by e.g. Ubuntu"
 412         )
 413
 414     endif(BUILD_GUI)
 415
 416     if (BUILD_CORE)
 417
 418         find_package(QCA2 QUIET)
 419         set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 420             URL "https://projects.kde.org/projects/kdesupport/qca"
 421             DESCRIPTION "Qt Cryptographic Architecture"
 422             PURPOSE     "Required for encryption support"
 423         )
 424
 425
 426     endif()
 427
 428     # Qt4 does not consider lconvert relevant, so they don't support finding it...
 429     # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 430     if (QT_LRELEASE_EXECUTABLE)
 431         get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 432         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 433     endif()
 434 endif()
 435
 436
 437 # Non-Qt-based packages
 438
 439 # zlib for compression, however we can always fall back to miniz
 440 find_package(ZLIB QUIET)
 441 set_package_properties(ZLIB PROPERTIES TYPE RECOMMENDED
 442     URL "http://www.zlib.net"
 443     DESCRIPTION "a popular compression library"
 444     PURPOSE     "Use the most common library for protocol compression, instead of the bundled miniz implementation"
 445 )
 446
 447
 448 if (NOT WIN32)
 449     # Execinfo is needed for generating backtraces
 450     find_package(ExecInfo QUIET)
 451     set_package_properties(ExecInfo PROPERTIES TYPE OPTIONAL
 452         DESCRIPTION "a library for inspecting backtraces"
 453         PURPOSE "Used for generating backtraces in case of a crash"
 454     )
 455 endif()
 456
 457 # Check for SSL support in Qt
 458 # As there's no easy way to get Qt's configuration in particular for Qt5, let's just compile
 459 # a small test program checking the defines. This works for both Qt4 and Qt5.
 460 cmake_push_check_state(RESET)
 461 set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES} ${Qt5Core_INCLUDE_DIRS})
 462 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Core_EXECUTABLE_COMPILE_FLAGS}")
 463
 464 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 465     set(CMAKE_REQUIRED_FLAGS "-fPIC -DQT_NO_VERSION_TAGGING")
 466 endif()
 467
 468 check_cxx_source_compiles("
 469     #include \"qglobal.h\"
 470     #if defined QT_NO_SSL
 471     #  error \"No SSL support\"
 472     #endif
 473     int main() {}"
 474     HAVE_SSL)
 475 cmake_pop_check_state()
 476
 477 # Additional compile settings
 478 #####################################################################
 479
 480 # This sets -fPIC and friends if required by the installed Qt5 library
 481 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 482     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 483 endif()
 484
 485 # Needed to compile with mingw without kde
 486 if (MINGW AND NOT KDE4_FOUND)
 487     add_definitions(-D_WIN32_WINNT=0x0500)
 488     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 489     # workaround for bug in mingw gcc 4.0
 490     add_definitions(-U__STRICT_ANSI__)
 491 endif()
 492
 493 # Sanitize compiler flags - old versions of KDE set -ansi, which breaks -std=c++11
 494 if (CMAKE_COMPILER_IS_GNUCXX)
 495     string(REPLACE "-ansi" "" CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS})
 496 endif()
 497
 498
 499 # Setup KDE / KDE Frameworks
 500 #####################################################################
 501
 502 # We want to do this up here, so we have the necessary variables and defines set before
 503 # compiling anything
 504
 505 if (KDE4_FOUND)
 506     # We always use external icons for KDE4 support, since we use its iconloader rather than Qt's
 507     set(EMBED_DATA OFF)
 508
 509     # Better have the compile flags global, even for the core, to avoid problems with linking the mono client
 510     add_definitions(-DHAVE_KDE -DHAVE_KDE4 ${KDE4_DEFINITIONS})
 511     set(WITH_KDE4 TRUE)
 512 endif()
 513
 514 if (USE_QT5 AND WITH_KDE)
 515     # If KDE Frameworks are present, they're most probably providing Qt5 integration including icon loading
 516     set(EMBED_DATA OFF)
 517
 518     include(KDEInstallDirs)
 519     include(KDECompilerSettings)
 520     include(KDECMakeSettings)
 521
 522     add_definitions(-DHAVE_KDE -DHAVE_KF5)
 523     set(WITH_KF5 TRUE)
 524 endif()
 525
 526 # This needs to come after setting up KDE integration, so we can use KDE-specific paths
 527 include(QuasselInstallDirs)
 528
 529 # Various config-dependent checks and settings
 530 #####################################################################
 531
 532 if (NOT ZLIB_FOUND)
 533     message(STATUS "zlib NOT found, using bundled miniz for compression")
 534     if (${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 535         message(STATUS "WARNING: This may be slow on 32 bit systems!")
 536     endif()
 537 endif()
 538
 539 if (HAVE_SSL)
 540     add_definitions(-DHAVE_SSL)
 541 endif()
 542 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 543
 544 # Check for syslog support
 545 if (NOT WIN32)
 546     check_include_file(syslog.h HAVE_SYSLOG)
 547     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 548 endif()
 549
 550 add_feature_info("Qt Linguist Tools" QT_LCONVERT_EXECUTABLE "Translation support for Quassel")
 551
 552 if (EMBED_DATA)
 553     message(STATUS "Embedding data files into the binary")
 554 else()
 555     message(STATUS "Installing data files separately")
 556 endif()
 557
 558 if (INDICATEQT_FOUND)
 559     add_definitions(-DXDG_APPS_INSTALL_DIR=${CMAKE_INSTALL_APPDIR})
 560 endif()
 561
 562 if (NOT WIN32)
 563     check_function_exists(umask HAVE_UMASK)
 564     if(HAVE_UMASK)
 565         add_definitions(-DHAVE_UMASK)
 566     endif(HAVE_UMASK)
 567 endif()
 568
 569
 570 # Windows-specific stuff
 571 #####################################################################
 572
 573 if (WIN32)
 574     link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 575     if (MSVC)
 576         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /DNOMINMAX")
 577         set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 578         set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 579         set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 580         link_libraries(Version dwmapi shlwapi)
 581         if (USE_QT5)
 582             set(QT_QTMAIN_LIBRARY Qt5::WinMain)
 583         endif()
 584     endif()
 585     if(HAVE_SSL AND STATIC)
 586         find_package(OpenSSL REQUIRED)
 587         link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 588     endif()
 589 endif()
 590
 591
 592 # Static builds (very much non-portable, so don't use -DSTATIC
 593 # unless you know what you do!)
 594 #####################################################################
 595
 596 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 597     set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 598     link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 599     if (HAVE_SSL)
 600         set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 601     endif()
 602 endif()
 603
 604
 605 # Generate version information from Git
 606 #####################################################################
 607
 608 include(GetGitRevisionDescription)
 609 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 610 git_describe(GIT_DESCRIBE --long)
 611
 612 # If in a Git repo we can get the commit-date from a git command
 613 if (GIT_HEAD)
 614     execute_process(
 615         COMMAND git show -s --format=%ct
 616         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 617         OUTPUT_VARIABLE GIT_COMMIT_DATE
 618         OUTPUT_STRIP_TRAILING_WHITESPACE
 619     )
 620 endif()
 621
 622 # If not in a Git repo try to read GIT_HEAD and GIT_DESCRIBE from
 623 # enviroment
 624 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 625   if (DEFINED ENV{GIT_HEAD})
 626       set(GIT_HEAD $ENV{GIT_HEAD})
 627   endif ()
 628   if (DEFINED ENV{GIT_DESCRIBE})
 629      set(GIT_DESCRIBE $ENV{GIT_DESCRIBE})
 630   endif()
 631 endif()
 632
 633 # Sanitize things if we're not in a Git repo
 634 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 635     set(GIT_HEAD "")
 636     set(GIT_DESCRIBE "")
 637     set(GIT_COMMIT_DATE 0)
 638 endif()
 639
 640 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 641
 642 # Prepare the build
 643 #####################################################################
 644
 645 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 646 set(COMMON_DEPS ${RC_WIN32})
 647 set(CORE_DEPS )
 648 set(CLIENT_DEPS )
 649
 650 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 651 add_subdirectory(data)
 652 add_subdirectory(icons)
 653 add_subdirectory(pics)
 654 add_subdirectory(po)
 655
 656
 657 # Set up and display feature summary
 658 #####################################################################
 659
 660 feature_summary(WHAT ALL
 661                 INCLUDE_QUIET_PACKAGES
 662                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 663 )
 664
 665 # Finally, compile the sources
 666 # We want this after displaying the feature summary to avoid ugly
 667 # CMake backtraces in case a required Qt5 module is missing
 668 #####################################################################
 669
 670 add_subdirectory(src)