CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 cmake_minimum_required(VERSION 2.8.9)  # You'll need at least 2.8.12 for KDE Frameworks integration
  10 project(QuasselIRC)
  11
  12 # Versions
  13 set(QUASSEL_MAJOR  0)
  14 set(QUASSEL_MINOR 12)
  15 set(QUASSEL_PATCH  0)
  16 set(QUASSEL_VERSION_STRING "0.12-pre")
  17
  18 # Tell CMake about or own modules
  19 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  20
  21 # General conveniences
  22 set(CMAKE_AUTOMOC ON)
  23 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  24
  25 # Include various CMake modules...
  26 include(CMakePushCheckState)
  27 include(CheckFunctionExists)
  28 include(CheckIncludeFile)
  29 include(CheckCXXSourceCompiles)
  30 include(CMakeDependentOption)
  31 include(FeatureSummary)
  32
  33 # ... and our own stuff
  34 include(QuasselCompileSettings)
  35 include(QuasselMacros)
  36
  37 # Setting COMPILE_DEFINITIONS_<CONFIG> is deprecated since CMake 3.0 in favor of generator expressions.
  38 # These have existed since CMake 2.8.10; until we depend on that, we have to explicitly enable the old policy.
  39 if (CMAKE_MAJOR_VERSION GREATER 2)
  40     cmake_policy(SET CMP0043 OLD)
  41 endif()
  42
  43 # Options and variables that can be set on the command line
  44 #####################################################################
  45
  46 # First, choose a Qt version. We support USE_QT4 and USE_QT5; if neither is set, prefer Qt4 for now
  47 option(USE_QT5 "Enable support for Qt5 (disables KDE integration)" OFF)
  48 if (USE_QT4) # takes precedence
  49     set(USE_QT5 OFF)
  50 else()
  51     if (NOT USE_QT5)
  52         set(USE_QT4 ON)
  53     endif()
  54 endif()
  55
  56 # Select the binaries to build
  57 option(WANT_CORE     "Build the core (server) binary"           ON)
  58 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  59 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  60 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  61 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  62 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  63
  64 # Whether to enable KDE integration (work in progress for Qt5 / KDE Frameworks)
  65 # Note that when building with Qt5, WITH_KDE enables integration with higher-tier KDE frameworks that
  66 # require runtime support. We still optionally make use of certain Tier 1 frameworks even if WITH_KDE
  67 # is disabled.
  68 if (USE_QT4)
  69     option(WITH_KDE "KDE4 integration" OFF)
  70     add_feature_info(WITH_KDE WITH_KDE "Enable KDE4 integration")
  71 else()
  72     option(WITH_KDE "Integration with the KDE Frameworks runtime environment")
  73     add_feature_info(WITH_KDE WITH_KDE "Integrate with the KDE Frameworks runtime environment")
  74 endif()
  75
  76 cmake_dependent_option(WITH_OXYGEN "Install Oxygen icon set (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
  77 if (NOT WITH_KDE)
  78     add_feature_info(WITH_OXYGEN WITH_OXYGEN "Install Oxygen icon set")
  79 endif()
  80
  81 # For this, the feature info is added after we know if QtWebkit is installed
  82 option(WITH_WEBKIT "WebKit support (for link previews)" ON)
  83
  84 if (APPLE)
  85     # Notification Center is only available in > 10.8, which is Darwin v12
  86     if (CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  87         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
  88         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
  89     endif()
  90 endif()
  91
  92 # Always embed on Windows, OSX or for a static build; never embed when enabling KDE integration
  93 set(EMBED_DEFAULT OFF)
  94 if (STATIC OR WIN32 OR APPLE)
  95     set(EMBED_DEFAULT ON)
  96 endif()
  97 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
  98                                    "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
  99 if (NOT EMBED_DEFAULT)
 100     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
 101 endif()
 102
 103 # The following options are not for end-user consumption, so don't list them in the feature summary
 104 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
 105
 106 # Handle with care
 107 set(QT_PATH "" CACHE PATH "Path to a Qt4 installation to use instead of the system Qt (e.g. for static builds)")
 108
 109 # Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
 110 cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
 111
 112 # For static builds, arbitrary extra libs might need to be linked
 113 # Define a comma-separated list here
 114 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 115 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 116 if (LINK_EXTRA)
 117     string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 118     link_libraries(${LINK_EXTRA})
 119 endif()
 120
 121
 122 # Simplify later checks
 123 #####################################################################
 124
 125 if (WANT_MONO OR WANT_QTCLIENT)
 126     set(BUILD_GUI true)
 127 endif()
 128 if (WANT_MONO OR WANT_CORE)
 129     set(BUILD_CORE true)
 130 endif()
 131
 132
 133 # Set up Qt
 134 #####################################################################
 135
 136 if (USE_QT5)
 137     message(STATUS "Building for Qt5...")
 138     set(QT_MIN_VERSION "5.2.0")
 139     add_definitions(-DHAVE_QT5)
 140 else()
 141     message(STATUS "Building for Qt4...")
 142     if (BUILD_GUI)
 143         set(QT_MIN_VERSION "4.6.0")
 144     else()
 145         set(QT_MIN_VERSION "4.4.0")
 146     endif()
 147
 148     # Select a Qt installation here, if you don't want to use system Qt
 149     if(QT_PATH)
 150         # FindQt4 will look for the qmake binary in $PATH, so we just prepend QT_PATH
 151         set(ENV{PATH} ${QT_PATH}/bin:$ENV{PATH})
 152     endif()
 153 endif()
 154
 155
 156 # Find package dependencies
 157 #
 158 # Note that you can forcefully disable optional packages
 159 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 160 #####################################################################
 161
 162 if (USE_QT5)
 163     find_package(Qt5Core ${QT_MIN_VERSION} QUIET)
 164     set_package_properties(Qt5Core PROPERTIES TYPE REQUIRED
 165         URL "http://qt.digia.com"
 166         DESCRIPTION "contains core functionality for Qt"
 167     )
 168     # find_package without REQUIRED won't check for the version properly; also, older Qt5 versions
 169     # used Qt5Core_VERSION_STRING... let's just make sure here that we bail out here if our Qt5 is not new enough.
 170     if (NOT Qt5Core_VERSION OR Qt5Core_VERSION VERSION_LESS ${QT_MIN_VERSION})
 171         message(FATAL_ERROR "Could NOT find Qt5 >= version ${QT_MIN_VERSION}!")
 172     endif()
 173
 174     find_package(Qt5Network QUIET)
 175     set_package_properties(Qt5Network PROPERTIES TYPE REQUIRED
 176         DESCRIPTION "the network module for Qt5"
 177     )
 178
 179     if (BUILD_GUI)
 180         find_package(Qt5Gui QUIET)
 181         set_package_properties(Qt5Gui PROPERTIES TYPE REQUIRED
 182             DESCRIPTION "the GUI module for Qt5"
 183         )
 184         find_package(Qt5Widgets QUIET)
 185         set_package_properties(Qt5Widgets PROPERTIES TYPE REQUIRED
 186             DESCRIPTION "the widgets module for Qt5"
 187         )
 188
 189         find_package(Qt5DBus QUIET)
 190         set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 191             URL "http://qt.digia.com"
 192             DESCRIPTION "D-Bus support for Qt5"
 193             PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 194         )
 195         if (Qt5DBus_FOUND)
 196             find_package(dbusmenu-qt5 QUIET CONFIG)
 197             set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 198                 URL "https://launchpad.net/libdbusmenu-qt"
 199                 DESCRIPTION "a library implementing the DBusMenu specification"
 200                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 201             )
 202         endif()
 203
 204         find_package(Phonon4Qt5 QUIET)
 205         set_package_properties(Phonon4Qt5 PROPERTIES TYPE RECOMMENDED
 206             URL "https://projects.kde.org/projects/kdesupport/phonon"
 207             DESCRIPTION "a multimedia abstraction library"
 208             PURPOSE     "Required for audio notifications"
 209         )
 210
 211         find_package(LibsnoreQt5 QUIET)
 212         set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
 213             URL "https://github.com/TheOneRing/Snorenotify"
 214             DESCRIPTION "a cross-platform notification framework"
 215             PURPOSE     "Enable support for the snorenotify framework"
 216         )
 217
 218         if (WITH_WEBKIT)
 219             find_package(Qt5WebKit QUIET)
 220             set_package_properties(Qt5WebKit PROPERTIES TYPE RECOMMENDED
 221                 URL "http://qt.digia.com"
 222                 DESCRIPTION "a WebKit implementation for Qt"
 223                 PURPOSE     "Needed for displaying previews for URLs in chat"
 224             )
 225             if (Qt5WebKit_FOUND)
 226                 find_package(Qt5WebKitWidgets QUIET)
 227                 set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE RECOMMENDED
 228                     URL "http://qt.digia.com"
 229                     DESCRIPTION "widgets for Qt's WebKit implementation"
 230                     PURPOSE     "Needed for displaying previews for URLs in chat"
 231                 )
 232             endif()
 233         endif()
 234         add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" Qt5WebKitWidgets_FOUND "Support showing previews for URLs in chat")
 235
 236         # KDE Frameworks
 237         ################
 238
 239         if (WITH_KDE)
 240             set(ecm_find_type "REQUIRED")
 241         else()
 242             # Even with KDE integration disabled, we optionally use tier1 frameworks if we find them
 243             set(ecm_find_type "RECOMMENDED")
 244         endif()
 245
 246         # extra-cmake-modules
 247         find_package(ECM NO_MODULE QUIET)
 248         set_package_properties(ECM PROPERTIES TYPE ${ecm_find_type}
 249             URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules"
 250             DESCRIPTION "extra modules for CMake, maintained by the KDE project"
 251             PURPOSE     "Required to find KDE Frameworks components"
 252         )
 253
 254         if (ECM_FOUND)
 255             list(APPEND CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
 256         endif()
 257
 258         if (WITH_KDE)
 259             find_package(KF5TextWidgets QUIET)
 260             set_package_properties(KF5TextWidgets PROPERTIES TYPE REQUIRED
 261                 URL "http://inqlude.org/libraries/ktextwidgets.html"
 262                 DESCRIPTION "framework providing an assortment of widgets for displaying and editing text"
 263                 PURPOSE     "Allows to use extra features provided by KDE Frameworks in input widgets"
 264             )
 265
 266         endif()
 267
 268     endif(BUILD_GUI)
 269     if (BUILD_CORE)
 270         find_package(Qt5Script QUIET)
 271         set_package_properties(Qt5Script PROPERTIES TYPE REQUIRED
 272             DESCRIPTION "provides scripting support for Qt5"
 273         )
 274         find_package(Qt5Sql QUIET)
 275         set_package_properties(Qt5Sql PROPERTIES TYPE REQUIRED
 276             DESCRIPTION "the database support module for Qt5"
 277         )
 278
 279         # While QCA2 seems to support Qt5, it is not actually co-installable or distinguishable from the Qt4 version...
 280         # In order to avoid linking against the Qt4 version (which is probably the one installed), disable this for now
 281         #find_package(QCA2 QUIET)
 282         #set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 283         #    URL "https://projects.kde.org/projects/kdesupport/qca"
 284         #    DESCRIPTION "Qt Cryptographic Architecture"
 285         #    PURPOSE "Required for encryption support"
 286         #)
 287
 288     endif(BUILD_CORE)
 289
 290     find_package(Qt5LinguistTools QUIET)
 291     set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 292                            DESCRIPTION "contains tools for handling translation files"
 293                            PURPOSE "Required for having translations"
 294     )
 295     # Some Qt5 versions do not define a target for lconvert, so we need to find it ourselves
 296     if (Qt5LinguistTools_FOUND)
 297         if (NOT TARGET Qt5::lconvert AND TARGET Qt5::lrelease)
 298             get_target_property(_lrelease_location Qt5::lrelease LOCATION)
 299             get_filename_component(_lrelease_path ${_lrelease_location} PATH)
 300             find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 301         elseif(TARGET Qt5::lconvert AND NOT Qt5_LCONVERT_EXECUTABLE)
 302             # Newer Qt5 versions define the target, but not the Qt5_LCONVERT_EXECUTABLE variable for some reason
 303             get_target_property(QT_LCONVERT_EXECUTABLE Qt5::lconvert LOCATION)
 304         endif()
 305
 306         # Compatibility with the Qt4 variables
 307         set(QT_LRELEASE_EXECUTABLE ${Qt5_LRELEASE_EXECUTABLE})
 308         set(QT_LUPDATE_EXECUTABLE ${Qt5_LUPDATE_EXECUTABLE})
 309         if (Qt5_LCONVERT_EXECUTABLE)
 310             set(QT_LCONVERT_EXECUTABLE ${Qt5_LCONVERT_EXECUTABLE})
 311         endif()
 312     endif()
 313
 314 else(USE_QT5)
 315     find_package(Qt4 ${QT_MIN_VERSION} QUIET REQUIRED)
 316
 317     if (BUILD_GUI)
 318         add_feature_info("QtDBus module" QT_QTDBUS_FOUND "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments")
 319         if (QT_QTDBUS_FOUND)
 320             find_package(dbusmenu-qt QUIET CONFIG)
 321             set_package_properties(dbusmenu-qt PROPERTIES TYPE RECOMMENDED
 322                 URL "https://launchpad.net/libdbusmenu-qt"
 323                 DESCRIPTION "a library implementing the DBusMenu specification"
 324                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 325             )
 326         endif()
 327
 328         if (WITH_WEBKIT AND QT_QTWEBKIT_FOUND)
 329             set(HAVE_WEBKIT true)
 330         endif()
 331         add_feature_info("WITH_WEBKIT and QtWebKit module" HAVE_WEBKIT "Support showing previews for URLs in chat")
 332
 333         if (WITH_KDE)
 334             # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 335             set(_cflags ${CMAKE_C_FLAGS})
 336             find_package(KDE4 4.4 QUIET)
 337             set_package_properties(KDE4 PROPERTIES TYPE REQUIRED
 338                 URL "http://www.kde.org"
 339                 DESCRIPTION "a world-class desktop environment"
 340                 PURPOSE "Enables various bits for improving integration with KDE"
 341             )
 342             set(CMAKE_C_FLAGS ${_cflags})
 343
 344         else(WITH_KDE)
 345             find_package(Phonon QUIET)
 346             set_package_properties(Phonon PROPERTIES TYPE RECOMMENDED
 347                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 348                 DESCRIPTION "a multimedia abstraction library"
 349                 PURPOSE     "Required for audio notifications"
 350             )
 351
 352             find_package(Libsnore QUIET)
 353             set_package_properties(Libsnore PROPERTIES TYPE OPTIONAL
 354                 URL "https://github.com/TheOneRing/Snorenotify"
 355                 DESCRIPTION "a cross-platform notification framework"
 356                 PURPOSE     "Enable support for the snorenotify framework"
 357             )
 358         endif(WITH_KDE)
 359
 360         find_package(IndicateQt QUIET)
 361         set_package_properties(IndicateQt PROPERTIES TYPE OPTIONAL
 362             URL "https://launchpad.net/libindicate-qt/"
 363             DESCRIPTION "a library to raise flags on DBus for other components of the desktop to pick up and visualize"
 364             PURPOSE     "Provides integration into the Ayatana notification system used by e.g. Ubuntu"
 365         )
 366
 367     endif(BUILD_GUI)
 368
 369     if (BUILD_CORE)
 370
 371         find_package(QCA2 QUIET)
 372         set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 373             URL "https://projects.kde.org/projects/kdesupport/qca"
 374             DESCRIPTION "Qt Cryptographic Architecture"
 375             PURPOSE     "Required for encryption support"
 376         )
 377
 378
 379     endif()
 380
 381     # Qt4 does not consider lconvert relevant, so they don't support finding it...
 382     # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 383     if (QT_LRELEASE_EXECUTABLE)
 384         get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 385         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 386     endif()
 387 endif()
 388
 389
 390 # Non-Qt-based packages
 391
 392 # zlib for compression, however we can always fall back to miniz
 393 find_package(ZLIB QUIET)
 394 set_package_properties(ZLIB PROPERTIES TYPE RECOMMENDED
 395     URL "http://www.zlib.net"
 396     DESCRIPTION "a popular compression library"
 397     PURPOSE     "Use the most common library for protocol compression, instead of the bundled miniz implementation"
 398 )
 399
 400
 401 if (NOT WIN32)
 402     # Execinfo is needed for generating backtraces
 403     find_package(ExecInfo QUIET)
 404     set_package_properties(ExecInfo PROPERTIES TYPE OPTIONAL
 405         DESCRIPTION "a library for inspecting backtraces"
 406         PURPOSE "Used for generating backtraces in case of a crash"
 407     )
 408 endif()
 409
 410
 411 # Additional compile settings
 412 #####################################################################
 413
 414 # This sets -fPIC and friends if required by the installed Qt5 library
 415 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 416     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 417 endif()
 418
 419 # Needed to compile with mingw without kde
 420 if (MINGW AND NOT KDE4_FOUND)
 421     add_definitions(-D_WIN32_WINNT=0x0500)
 422     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 423     # workaround for bug in mingw gcc 4.0
 424     add_definitions(-U__STRICT_ANSI__)
 425 endif()
 426
 427
 428 # Setup KDE / KDE Frameworks
 429 #####################################################################
 430
 431 # We want to do this up here, so we have the necessary variables and defines set before
 432 # compiling anything
 433
 434 if (KDE4_FOUND)
 435     # We always use external icons for KDE4 support, since we use its iconloader rather than Qt's
 436     set(EMBED_DATA OFF)
 437
 438     # Better have the compile flags global, even for the core, to avoid problems with linking the mono client
 439     add_definitions(-DHAVE_KDE -DHAVE_KDE4 ${KDE4_DEFINITIONS})
 440     set(WITH_KDE4 TRUE)
 441 endif()
 442
 443 if (USE_QT5 AND WITH_KDE)
 444     # If KDE Frameworks are present, they're most probably providing Qt5 integration including icon loading
 445     set(EMBED_DATA OFF)
 446
 447     include(KDEInstallDirs)
 448     include(KDECompilerSettings)
 449     include(KDECMakeSettings)
 450
 451     add_definitions(-DHAVE_KDE -DHAVE_KF5)
 452     set(WITH_KF5 TRUE)
 453 endif()
 454
 455 # This needs to come after setting up KDE integration, so we can use KDE-specific paths
 456 include(QuasselInstallDirs)
 457
 458 # Various config-dependent checks and settings
 459 #####################################################################
 460
 461 if (NOT ZLIB_FOUND)
 462     message(STATUS "zlib NOT found, using bundled miniz for compression")
 463     if (${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 464         message(STATUS "WARNING: This may be slow on 32 bit systems!")
 465     endif()
 466 endif()
 467
 468 # Check for SSL support in Qt
 469 # As there's no easy way to get Qt's configuration in particular for Qt5, let's just compile
 470 # a small test program checking the defines. This works for both Qt4 and Qt5.
 471 cmake_push_check_state(RESET)
 472 set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES} ${Qt5Core_INCLUDE_DIRS})
 473 check_cxx_source_compiles("
 474     #include \"qglobal.h\"
 475     #if defined QT_NO_OPENSSL || defined QT_NO_SSL
 476     #  error \"No SSL support\"
 477     #endif
 478     int main() {}"
 479     HAVE_SSL)
 480 cmake_pop_check_state()
 481
 482 if (HAVE_SSL)
 483     add_definitions(-DHAVE_SSL)
 484 endif()
 485 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 486
 487 # Check for syslog support
 488 if (NOT WIN32)
 489     check_include_file(syslog.h HAVE_SYSLOG)
 490     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 491 endif()
 492
 493 add_feature_info("Qt Linguist Tools" QT_LCONVERT_EXECUTABLE "Translation support for Quassel")
 494
 495 if (EMBED_DATA)
 496     message(STATUS "Embedding data files into the binary")
 497 else()
 498     message(STATUS "Installing data files separately")
 499 endif()
 500
 501 if (INDICATEQT_FOUND)
 502     add_definitions(-DXDG_APPS_INSTALL_DIR=${CMAKE_INSTALL_APPDIR})
 503 endif()
 504
 505 if (NOT WIN32)
 506     check_function_exists(umask HAVE_UMASK)
 507     if(HAVE_UMASK)
 508         add_definitions(-DHAVE_UMASK)
 509     endif(HAVE_UMASK)
 510 endif()
 511
 512
 513 # Windows-specific stuff
 514 #####################################################################
 515
 516 if (WIN32)
 517     link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 518     if (MSVC)
 519         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /DNOMINMAX")
 520         set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 521         set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 522         set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 523         link_libraries(Version dwmapi shlwapi)
 524         if (USE_QT5)
 525             set(QT_QTMAIN_LIBRARY Qt5::WinMain)
 526         endif()
 527     endif()
 528     if(HAVE_SSL AND STATIC)
 529         find_package(OpenSSL REQUIRED)
 530         link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 531     endif()
 532 endif()
 533
 534
 535 # Static builds (very much non-portable, so don't use -DSTATIC
 536 # unless you know what you do!)
 537 #####################################################################
 538
 539 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 540     set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 541     link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 542     if (HAVE_SSL)
 543         set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 544     endif()
 545 endif()
 546
 547
 548 # Generate version information from Git
 549 #####################################################################
 550
 551 include(GetGitRevisionDescription)
 552 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 553 git_describe(GIT_DESCRIBE --long)
 554
 555 # If not in a Git repo try to read GIT_HEAD and GIT_DESCRIBE from
 556 # enviroment
 557 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 558   if (ENV_GIT_HEAD)
 559       set(GIT_HEAD ${ENV_GIT_HEAD})
 560   endif ()
 561   if (ENV_GIT_DESCRIBE)
 562      set(GIT_DESCRIBE ${ENV_GIT_DESCRIBE})
 563   endif()
 564 endif()
 565
 566 # Sanitize things if we're not in a Git repo
 567 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 568     set(GIT_HEAD "")
 569     set(GIT_DESCRIBE "")
 570 endif()
 571
 572 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 573
 574 # Prepare the build
 575 #####################################################################
 576
 577 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 578 set(COMMON_DEPS ${RC_WIN32})
 579 set(CORE_DEPS )
 580 set(CLIENT_DEPS )
 581
 582 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 583 add_subdirectory(data)
 584 add_subdirectory(icons)
 585 add_subdirectory(pics)
 586 add_subdirectory(po)
 587
 588
 589 # Set up and display feature summary
 590 #####################################################################
 591
 592 feature_summary(WHAT ALL
 593                 INCLUDE_QUIET_PACKAGES
 594                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 595 )
 596
 597 # Finally, compile the sources
 598 # We want this after displaying the feature summary to avoid ugly
 599 # CMake backtraces in case a required Qt5 module is missing
 600 #####################################################################
 601
 602 add_subdirectory(src)