CMakeLists.txt

   1 # This is the cmake-based build system for Quassel IRC.
   2 #
   3 # You may pass various options to cmake:
   4 #
   5 # -DWANT_(CORE|QTCLIENT|MONO)=(ON|OFF)
   6 #                        : select binaries to build
   7 # -DWITH_OPENSSL=OFF     : Disable OpenSSL support
   8 # -DWITH_DBUS=OFF        : Disable D-Bus support (dbus notifications)
   9 # -DWITH_WEBKIT=OFF      : Disable WebKit support (link previews)
  10 # -DWITH_PHONON=OFF      : Disable Phonon support (audio notifications)
  11 # -DWITH_LIBINDICATE=OFF : Disable libindicate support (Ayatana notifications)
  12 # -DWITH_KDE=ON          : Enable KDE4 support
  13 # -DWITH_CRYPT=OFF       : Disable encryption support
  14 # -DWITH_OXYGEN=(ON|OFF) : Whether to install Oxygen icons (default: yes, unless KDE > 4.3.0 is present and enabled)
  15 # -DWITH_SYSLOG=OFF      : Disable syslog support
  16 #
  17 # -DEMBED_DATA=ON        : Embed all data files in icons the binary, rather than installing them separately
  18 #
  19 # -DQT=/path/to/qt       : Choose a Qt4 installation to use instead of the system Qt4
  20 # -DSTATIC=ON            : Enable static building of Quassel. Use with care.
  21 # -DDEPLOY=ON            : Mac OS X only. Use only for creating Quassel Packages!
  22 #
  23 # -DWITH_QT5=ON          : Enable (very) experimental support for Qt5 (see doc/README.Qt5!)
  24 #
  25 # NOTE: You should remove CMakeCache.txt if you plan to change any of these values!
  26
  27
  28 project(QuasselIRC)
  29
  30 include(CheckFunctionExists)
  31 include(CheckIncludeFile)
  32
  33 # For building against Qt5, we check for an even newer cmake version below!
  34 cmake_minimum_required(VERSION 2.8.1 FATAL_ERROR)
  35
  36 if(COMMAND cmake_policy)
  37    cmake_policy(SET CMP0003 NEW)
  38 endif(COMMAND cmake_policy)
  39
  40 # Use our own (well, and KDE's) version of some modules
  41 # In particular cmake's own FindQt4 and FindOpenSSL are quite buggy
  42 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  43 include(QuasselMacros)
  44
  45 # Various options and variables that can be set on the command line
  46 option(WANT_CORE     "Build the core (server) binary"           ON)
  47 option(WANT_QTCLIENT "Build the Qt4 GUI client binary"          ON)
  48 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  49
  50 option(WITH_OPENSSL  "Enable OpenSSL support if present on the system"  ON)
  51 option(WITH_DBUS     "Enable D-Bus support if present on the system"    ON)
  52 option(WITH_WEBKIT   "Enable WebKit support (for link previews)"        ON)
  53 option(WITH_PHONON   "Enable Phonon support (for audio notifications)"  ON)
  54 option(WITH_LIBINDICATE "Enable Ayatana notification support"           ON)
  55 option(WITH_KDE      "Enable KDE4 integration"                          OFF)
  56 option(WITH_CRYPT    "Enable encryption support if present on system"   ON)
  57 option(WITH_SYSLOG   "Use syslog for storing log data"                  ON)
  58
  59 # We use icon paths from KDE 4.3.x, which are partially invalid on older and possibly
  60 # even on newer KDE versions. Do not disable this unless you are sure that your Quassel will
  61 # run on a matching KDE version only.
  62 set(WITH_OXYGEN AUTO CACHE STRING "Install Oxygen icons (default is \"AUTO\" to install when KDE 4.3 or later is present")
  63
  64 # Enable very experimental support for Qt5. Might break the compilation, or even more!
  65 option(WITH_QT5      "Enable (very) experimental support for Qt5"       OFF)
  66
  67 option(STATIC        "Enable static building (might not be portable)" OFF)
  68
  69 if(APPLE)
  70   option(DEPLOY        "Mac OS X only! Adds required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF)
  71 endif(APPLE)
  72
  73 # Default to embedding data in the static case
  74 if(STATIC OR WIN32)
  75   set(EMBED_DEFAULT ON)
  76 else(STATIC OR WIN32)
  77   set(EMBED_DEFAULT ON) # should be OFF as soon as everything works
  78 endif(STATIC OR WIN32)
  79
  80 option(EMBED_DATA    "Embed all data files in the binary (rather than installing them separately)"   ${EMBED_DEFAULT})
  81
  82 set(QT "" CACHE STRING "Path to a Qt installation to use instead of the system Qt (e.g. for static builds)")
  83
  84 # Some settings imply others
  85 if(STATIC)
  86   add_definitions(-DSTATIC)
  87   set(WITH_KDE OFF CACHE BOOL "Static building with KDE is not supported")
  88 endif(STATIC)
  89
  90 if(WIN32)
  91   # We don't support separately installed resources yet on Win32
  92   set(EMBED_DATA ON)
  93 endif(WIN32)
  94
  95 # For static builds, arbitrary extra libs might need to be linked
  96 # Define a comma-separated list here
  97 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
  98 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
  99 if(LINK_EXTRA)
 100   string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 101   link_libraries(${LINK_EXTRA})
 102 endif(LINK_EXTRA)
 103
 104 # Build Type
 105 # We need to make sure it's not empty
 106 # Supported: Release, RelWithDebugInfo, Debug, Debugfull
 107
 108 # On WIN32, only Release seems to work correctly (?)
 109 if(WIN32)
 110   set(DEFAULT_BUILD_TYPE "Release")
 111 else(WIN32)
 112   set(DEFAULT_BUILD_TYPE "RelWithDebugInfo")
 113 endif(WIN32)
 114
 115 set(CMAKE_BUILD_TYPE ${DEFAULT_BUILD_TYPE} CACHE STRING "CMake Build Type")
 116 if(NOT CMAKE_BUILD_TYPE)
 117   set(CMAKE_BUILD_TYPE ${DEFAULT_BUILD_TYPE} CACHE STRING "CMake Build Type" FORCE)
 118 endif(NOT CMAKE_BUILD_TYPE)
 119
 120 # Qt debug flags
 121 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_DEBUG QT_DEBUG)
 122 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_FULLDEBUG QT_DEBUG)
 123 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_RELEASE QT_NO_DEBUG NDEBUG)
 124 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_RELWITHDEBINFO QT_NO_DEBUG NDEBUG)
 125 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_MINSIZEREL QT_NO_DEBUG NDEBUG)
 126
 127 IF(NOT CMAKE_CONFIGURATION_TYPES AND NOT CMAKE_BUILD_TYPE)
 128   set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_DEBUG NDEBUG)
 129 ENDIF()
 130
 131 # Enable various flags on gcc
 132 if(CMAKE_COMPILER_IS_GNUCXX)
 133   # Let's just hope that all gccs support these options and skip the tests...
 134   # -fno-strict-aliasing is needed apparently for Qt < 4.6
 135   set(CMAKE_CXX_FLAGS                  "${CMAKE_CXX_FLAGS} -ansi -Wall -Wextra -Wnon-virtual-dtor -fno-strict-aliasing")
 136   set(CMAKE_CXX_FLAGS_RELEASE          "-O2 ${CMAKE_CXX_FLAGS}")
 137   set(CMAKE_CXX_FLAGS_RELWITHDEBUGINFO "-g -O2 ${CMAKE_CXX_FLAGS}")
 138   set(CMAKE_CXX_FLAGS_DEBUG            "-g -ggdb -fno-reorder-blocks -fno-schedule-insns -fno-inline ${CMAKE_CXX_FLAGS}")
 139   set(CMAKE_CXX_FLAGS_DEBUGFULL        "-g3 ${CMAKE_CXX_FLAGS_DEBUG}")
 140 endif(CMAKE_COMPILER_IS_GNUCXX)
 141
 142 # Mac build stuff
 143 if(APPLE AND DEPLOY)
 144   set(CMAKE_OSX_ARCHITECTURES "x86_64")
 145   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.6")
 146   set(CMAKE_OSX_SYSROOT "/Developer/SDKs/MacOSX10.6.sdk/")
 147   add_definitions(-DMAC_10_6_SDK)
 148 endif(APPLE AND DEPLOY)
 149
 150 # Simplify checks
 151 if(WANT_MONO OR WANT_QTCLIENT)
 152   set(BUILD_GUI true)
 153 endif(WANT_MONO OR WANT_QTCLIENT)
 154 if(WANT_MONO OR WANT_CORE)
 155   set(BUILD_CORE true)
 156 endif(WANT_MONO OR WANT_CORE)
 157
 158
 159 # Version checks
 160 ################
 161
 162 if(WITH_QT5)
 163   set(QT_MIN_VERSION "5.0.0")
 164   add_definitions(-DHAVE_QT5)
 165
 166   # Qt5 needs a new enough cmake...
 167   cmake_minimum_required(VERSION 2.8.6 FATAL_ERROR)
 168
 169   # ... for automoc
 170   set(CMAKE_AUTOMOC ON)
 171 else(WITH_QT5)
 172
 173   # GUI stuff needs some new features
 174   if(BUILD_GUI)
 175     set(QT_MIN_VERSION "4.6.0")
 176   else(BUILD_GUI)
 177     set(QT_MIN_VERSION "4.4.0")
 178   endif(BUILD_GUI)
 179 endif(WITH_QT5)
 180
 181
 182 # Dependencies
 183 ##############
 184
 185 if(WITH_QT5)
 186   find_package(Qt5Core ${QT_MIN_VERSION} REQUIRED)
 187   # We need QtWidgets
 188   set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} Widgets)
 189
 190   # Setup the i18n-related variables
 191   find_package(Qt5LinguistTools)
 192
 193 else(WITH_QT5)
 194   # Select a Qt installation here, if you don't want to use system Qt
 195   if(QT)
 196     # FindQt4 will look for the qmake binary in $PATH, so we just prepend the Qt dir
 197     set(ENV{PATH} ${QT}/bin:$ENV{PATH})
 198   endif(QT)
 199
 200   # Now that we have the correct $PATH, lets find Qt!
 201   find_package(Qt4 ${QT_MIN_VERSION} REQUIRED)
 202 endif(WITH_QT5)
 203
 204
 205 # Neither Qt4 nor Qt5 consider lconvert relevant, so they don't support finding it...
 206 # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 207 if(QT_LRELEASE_EXECUTABLE)
 208   get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 209   if(WITH_QT5)
 210     find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 211   else(WITH_QT5)
 212     find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 213   endif(WITH_QT5)
 214 endif(QT_LRELEASE_EXECUTABLE)
 215
 216
 217 # Execinfo is needed for generating backtraces
 218 find_package(ExecInfo)
 219 if(EXECINFO_FOUND)
 220   add_definitions(-DHAVE_EXECINFO)
 221   include_directories(${EXECINFO_INCLUDES})
 222   link_libraries(${EXECINFO_LIBRARIES})
 223 endif(EXECINFO_FOUND)
 224
 225
 226 # PkgConfig isn't strictly required.
 227 # However, some optional deps might not be found if it's not present, so warn!
 228 find_package(PkgConfig)
 229 if(NOT PKG_CONFIG_FOUND)
 230   message(STATUS "WARNING: PkgConfig not available! Some dependencies for optional features might not be found.")
 231   message(STATUS "         Affected features might include encryption support, DBus menus and Ayatana notifications.")
 232 endif(NOT PKG_CONFIG_FOUND)
 233
 234
 235 # Setup OpenSSL
 236 # We don't link to or include OpenSSL ourselves, but use exclusively the Qt API.
 237 # Thus, we simply check if OpenSSL support is present in Qt's config and enable our
 238 # own SSL stuff in this case. Qt should care for adding what it needs itself.
 239 if(WITH_OPENSSL)
 240   if(QT_QCONFIG MATCHES "openssl")
 241     message(STATUS "Found OpenSSL support in Qt, enabling SSL")
 242     add_definitions(-DHAVE_SSL)
 243     set(HAVE_SSL true)
 244   else(QT_QCONFIG MATCHES "openssl")
 245     message(STATUS "No OpenSSL support found in Qt, disabling SSL")
 246     add_definitions(-DQT_NO_OPENSSL)
 247   endif(QT_QCONFIG MATCHES "openssl")
 248 else(WITH_OPENSSL)
 249   message(STATUS "Not enabling OpenSSL support")
 250 endif(WITH_OPENSSL)
 251
 252
 253 # Check for GUI specific stuff
 254 if(BUILD_GUI)
 255
 256   # Setup D-Bus support
 257   if(WITH_DBUS)
 258     if(WITH_QT5)
 259       find_package(Qt5DBus ${QT_MIN_VERSION})
 260       find_package(Qt5DBusTools)
 261     endif(WITH_QT5)
 262
 263     if(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 264       message(STATUS "Found QtDBus, enabling D-Bus support")
 265       add_definitions(-DHAVE_DBUS)
 266       set(HAVE_DBUS true)
 267       set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} DBus)
 268
 269       # check if we have dbusmenu as well
 270       if(NOT WITH_QT5)
 271         find_package(DBusMenuQt)
 272         if(DBUSMENUQT_FOUND)
 273           message(STATUS "Enabling support for exporting the tray menu via D-Bus")
 274           add_definitions(-DHAVE_DBUSMENU)
 275           include_directories(${DBUSMENUQT_INCLUDE_DIR})
 276           set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${DBUSMENUQT_LIBRARIES})
 277           set(CLIENT_COMPILE_FLAGS "${CLIENT_COMPILE_FLAGS} ${DBUSMENUQT_DEFINITIONS}")
 278         else(DBUSMENUQT_FOUND)
 279           message(STATUS "Disabling support for exporting the tray menu via D-Bus")
 280         endif(DBUSMENUQT_FOUND)
 281       endif(NOT WITH_QT5)
 282
 283     else(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 284       message(STATUS "QtDBus not found, disabling D-Bus support")
 285     endif(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 286   else(WITH_DBUS)
 287     message(STATUS "Not enabling D-Bus support")
 288   endif(WITH_DBUS)
 289
 290   # Setup QtWebkit support
 291   if(WITH_WEBKIT)
 292     if(WITH_QT5)
 293       find_package(Qt5Webkit ${QT_MIN_VERSION} QUIET)
 294     endif(WITH_QT5)
 295     if(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 296       message(STATUS "Found QtWebKit, enabling WebKit support")
 297       add_definitions(-DHAVE_WEBKIT)
 298       set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} Webkit XmlPatterns)
 299       set(HAVE_WEBKIT true)
 300     else(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 301       message(STATUS "QtWebkit not found, disabling Webkit support")
 302     endif(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 303   else(WITH_WEBKIT)
 304     message(STATUS "Not enabling Webkit support")
 305   endif(WITH_WEBKIT)
 306
 307   # Setup KDE4 support
 308   if(WITH_KDE AND NOT WITH_QT5)
 309     find_package(KDE4)
 310     if(KDE4_FOUND)
 311       message(STATUS "Enabling KDE4 integration")
 312       include_directories(${KDE4_INCLUDES})
 313       add_definitions(-DHAVE_KDE ${KDE4_DEFINITIONS})
 314       set(HAVE_KDE 1)
 315       set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${KDE4_KDECORE_LIBS} ${KDE4_KDEUI_LIBRARY} ${KDE4_SOLID_LIBS} knotifyconfig)
 316       # We always use external icons for KDE4 support, since we use its iconloader rather than our own
 317       set(EMBED_DATA OFF)
 318     else(KDE4_FOUND)
 319       message(STATUS "KDE4 not found, disabling KDE integration")
 320     endif(KDE4_FOUND)
 321   else(WITH_KDE AND NOT WITH_QT5)
 322     message(STATUS "Not enabling KDE4 integration")
 323   endif(WITH_KDE AND NOT WITH_QT5)
 324
 325   # Setup Phonon support - we only need this if we don't have or want KDE4
 326   if(NOT HAVE_KDE)
 327     if(WITH_PHONON)
 328       if(WITH_QT5)
 329         find_package(Qt5phonon)
 330         if(Qt5phonon_FOUND)
 331           message(STATUS "Enabling Phonon support")
 332           add_definitions(-DHAVE_PHONON)
 333           set(HAVE_PHONON true)
 334           set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} phonon)
 335         else(Qt5phonon_FOUND)
 336           message(STATUS "Phonon not found, disabling audio notifications")
 337         endif(Qt5phonon_FOUND)
 338       else(WITH_QT5)
 339         find_package(Phonon)
 340         if(PHONON_FOUND)
 341           message(STATUS "Enabling Phonon support")
 342           add_definitions(-DHAVE_PHONON)
 343           include_directories(${PHONON_INCLUDES})
 344           set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${PHONON_LIBS})
 345           set(HAVE_PHONON true)
 346         else(PHONON_FOUND)
 347           message(STATUS "Phonon not found, disabling audio notifications")
 348         endif(PHONON_FOUND)
 349       endif(WITH_QT5)
 350     else(WITH_PHONON)
 351       message(STATUS "Not enabling Phonon support")
 352     endif(WITH_PHONON)
 353   endif(NOT HAVE_KDE)
 354
 355   # Setup libindicate-qt support
 356   if(WITH_LIBINDICATE AND NOT WITH_QT5)
 357     pkg_check_modules(INDICATEQT QUIET indicate-qt>=0.2.1)
 358     if(INDICATEQT_FOUND)
 359       message(STATUS "Enabling Ayatana notification support")
 360       set(HAVE_INDICATEQT true)
 361       add_definitions(-DHAVE_INDICATEQT)
 362       link_directories(${INDICATEQT_LIBRARY_DIRS})
 363       set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${INDICATEQT_LIBRARIES})
 364     else(INDICATEQT_FOUND)
 365       message(STATUS "Disabling Ayatana notification support")
 366     endif(INDICATEQT_FOUND)
 367   else(WITH_LIBINDICATE AND NOT WITH_QT5)
 368     message(STATUS "Not enabling Ayatana notification support")
 369     # We don't want to link against it even if another package has found it
 370     set(INDICATEQT_LIBRARIES "")
 371   endif(WITH_LIBINDICATE AND NOT WITH_QT5)
 372
 373 endif(BUILD_GUI)
 374
 375 # Core-only deps
 376 if(BUILD_CORE)
 377
 378   # Setup encryption support
 379   if(WITH_CRYPT AND NOT WITH_QT5)
 380     find_package(QCA2)
 381     if(QCA2_FOUND)
 382       message(STATUS "Enabling encryption support")
 383       add_definitions(-DHAVE_QCA2)
 384       set(LINK_QCA2 QCA2)
 385       set(HAVE_QCA2 true)
 386       set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_QCA2)
 387     else(QCA2_FOUND)
 388       message(STATUS "Disabling encryption support")
 389     endif(QCA2_FOUND)
 390   else(WITH_CRYPT AND NOT WITH_QT5)
 391     message(STATUS "Not enabling encryption support")
 392   endif(WITH_CRYPT AND NOT WITH_QT5)
 393
 394   # Setup syslog support
 395   if(WITH_SYSLOG)
 396     check_include_file(syslog.h HAVE_SYSLOG_H)
 397     if(HAVE_SYSLOG_H)
 398       message(STATUS "Enabling syslog support")
 399       set(HAVE_SYSLOG true)
 400       add_definitions(-DHAVE_SYSLOG)
 401     else(HAVE_SYSLOG_H)
 402       message(STATUS "Disabling syslog support")
 403     endif(HAVE_SYSLOG_H)
 404   else(WITH_SYSLOG)
 405     message(STATUS "Not enabling syslog support")
 406   endif(WITH_SYSLOG)
 407
 408 endif(BUILD_CORE)
 409
 410
 411 # Various settings
 412 ##################
 413
 414 # needed to compile with mingw without kde
 415 if(MINGW AND NOT HAVE_KDE)
 416     add_definitions(-D_WIN32_WINNT=0x0500)
 417     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 418 # workaround for bug in mingw gcc 4.0
 419     add_definitions(-U__STRICT_ANSI__)
 420 endif(MINGW AND NOT HAVE_KDE)
 421
 422 # Now set up install locations; those are set by KDE if integration is enabled
 423 if(NOT HAVE_KDE)
 424   if(WIN32)
 425     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX} CACHE FILEPATH "Install path for binaries")
 426     set(DATA_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/apps CACHE FILEPATH "Install path for data files")
 427     set(ICON_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/icons CACHE FILEPATH "Global icon install path")
 428     set(XDG_APPS_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/applications CACHE FILEPATH "Install path for .desktop files")
 429   else(WIN32)
 430     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin CACHE FILEPATH "Install path for binaries")
 431     set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps CACHE FILEPATH "Install path for data files")
 432     set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons CACHE FILEPATH "Global icon install path")
 433     set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications CACHE FILEPATH "Install path for .desktop files")
 434   endif(WIN32)
 435 endif(NOT HAVE_KDE)
 436
 437 if(EMBED_DATA)
 438   message(STATUS "Embedding data files into the binary")
 439 else(EMBED_DATA)
 440   message(STATUS "Installing data files separately")
 441 endif(EMBED_DATA)
 442
 443 # RPATH needs to be set correctly
 444 # Do this down here, since otherwise KDE wants to handle it itself, and fails
 445 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
 446 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
 447
 448 # Set global buildflags
 449 # This is very much non-portable, so don't use -DSTATIC until you know what
 450 # you do.
 451 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 452   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 453   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 454   if(HAVE_SSL)
 455     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 456   endif(HAVE_SSL)
 457 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 458
 459 if(WIN32)
 460   link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 461   if(MSVC)
 462     set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 463     set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 464     set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 465     link_libraries(Version dwmapi shlwapi)
 466   endif(MSVC)
 467   if(HAVE_SSL AND STATIC)
 468      find_package(OpenSSL REQUIRED)
 469      link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 470   endif(HAVE_SSL AND STATIC)
 471 endif(WIN32)
 472
 473 if(HAVE_INDICATEQT)
 474   add_definitions(-DXDG_APPS_INSTALL_DIR=${XDG_APPS_INSTALL_DIR})
 475 endif(HAVE_INDICATEQT)
 476
 477 if(NOT WIN32)
 478   check_function_exists(umask HAVE_UMASK)
 479   if(HAVE_UMASK)
 480     add_definitions(-DHAVE_UMASK)
 481   endif(HAVE_UMASK)
 482 endif(NOT WIN32)
 483
 484 # We need to create a version.gen
 485 # For this, we create our genversion binary and make sure it is run every time.
 486
 487 setup_qt_variables()
 488 include_directories(${QUASSEL_QT_INCLUDES})
 489
 490 add_executable(genversion ${CMAKE_SOURCE_DIR}/src/common/genversion.cpp)
 491 target_link_libraries(genversion ${QUASSEL_QT_LIBRARIES})
 492 set_target_properties(genversion PROPERTIES COMPILE_FLAGS "${QUASSEL_QT_COMPILEFLAGS}")
 493
 494 get_target_property(GENVERSION_EXECUTABLE genversion LOCATION)
 495 add_custom_target(genversion_run ALL ${GENVERSION_EXECUTABLE}
 496                   ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR}/src/version.gen)
 497 add_dependencies(genversion_run genversion)
 498
 499 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 500 set(COMMON_DEPS ${RC_WIN32})
 501 set(CORE_DEPS )
 502 set(CLIENT_DEPS )
 503
 504 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 505 add_subdirectory(data)
 506 add_subdirectory(icons)
 507 add_subdirectory(pics)
 508 add_subdirectory(po)
 509 add_subdirectory(src)