CMakeLists.txt

   1 # This is the cmake-based build system for Quassel IRC.
   2 #
   3 # You may pass various options to cmake:
   4 #
   5 # -DWANT_(CORE|QTCLIENT|MONO)=(ON|OFF)
   6 #                        : select binaries to build
   7 # -DWITH_OPENSSL=OFF     : Disable OpenSSL support
   8 # -DWITH_DBUS=OFF        : Disable D-Bus support (dbus notifications)
   9 # -DWITH_WEBKIT=OFF      : Disable WebKit support (link previews)
  10 # -DWITH_PHONON=OFF      : Disable Phonon support (audio notifications)
  11 # -DWITH_LIBINDICATE=OFF : Disable libindicate support (Ayatana notifications)
  12 # -DWITH_KDE=ON          : Enable KDE4 support
  13 # -DWITH_CRYPT=OFF       : Disable encryption support
  14 # -DWITH_OXYGEN=(ON|OFF) : Whether to install Oxygen icons (default: yes, unless KDE > 4.3.0 is present and enabled)
  15 # -DWITH_SYSLOG=OFF      : Disable syslog support
  16 #
  17 # -DEMBED_DATA=ON        : Embed all data files in icons the binary, rather than installing them separately
  18 #
  19 # -DQT=/path/to/qt       : Choose a Qt4 installation to use instead of the system Qt4
  20 # -DSTATIC=ON            : Enable static building of Quassel. Use with care.
  21 # -DDEPLOY=ON            : Mac OS X only. Use only for creating Quassel Packages!
  22 #
  23 # -DWITH_QT5=ON          : Enable (very) experimental support for Qt5 (see doc/README.Qt5!)
  24 #
  25 # NOTE: You should remove CMakeCache.txt if you plan to change any of these values!
  26
  27
  28 cmake_minimum_required(VERSION 2.8.9)
  29 project(QuasselIRC)
  30
  31 # Versions
  32 set(QUASSEL_MAJOR  0)
  33 set(QUASSEL_MINOR 11)
  34 set(QUASSEL_PATCH  0)
  35 set(QUASSEL_VERSION_STRING "0.11-pre")
  36
  37 # Tell CMake about or own stuff
  38 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  39
  40 include(CheckFunctionExists)
  41 include(CheckIncludeFile)
  42
  43 include(QuasselCompileSettings)
  44 include(QuasselMacros)
  45
  46 # Various options and variables that can be set on the command line
  47 option(WANT_CORE     "Build the core (server) binary"           ON)
  48 option(WANT_QTCLIENT "Build the Qt4 GUI client binary"          ON)
  49 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  50
  51 option(WITH_OPENSSL  "Enable OpenSSL support if present on the system"  ON)
  52 option(WITH_DBUS     "Enable D-Bus support if present on the system"    ON)
  53 option(WITH_WEBKIT   "Enable WebKit support (for link previews)"        ON)
  54 option(WITH_PHONON   "Enable Phonon support (for audio notifications)"  ON)
  55 option(WITH_LIBINDICATE "Enable Ayatana notification support"           ON)
  56 option(WITH_KDE      "Enable KDE4 integration"                          OFF)
  57 option(WITH_CRYPT    "Enable encryption support if present on system"   ON)
  58 option(WITH_SYSLOG   "Use syslog for storing log data"                  ON)
  59
  60 # We use icon paths from KDE 4.3.x, which are partially invalid on older and possibly
  61 # even on newer KDE versions. Do not disable this unless you are sure that your Quassel will
  62 # run on a matching KDE version only.
  63 set(WITH_OXYGEN AUTO CACHE STRING "Install Oxygen icons (default is \"AUTO\" to install when KDE 4.3 or later is present")
  64
  65 # Enable very experimental support for Qt5. Might break the compilation, or even more!
  66 option(WITH_QT5      "Enable (very) experimental support for Qt5"       OFF)
  67
  68 option(STATIC        "Enable static building (might not be portable)" OFF)
  69
  70 if(APPLE)
  71   option(DEPLOY        "Mac OS X only! Adds required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF)
  72   # Notification Center is only available in > 10.8, which is Darwin v12
  73   if(CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  74     option(WITH_NOTIFICATION_CENTER "Enable OS X Notification Center support" ON)
  75   endif(CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  76 endif(APPLE)
  77
  78 # Default to embedding data in the static case
  79 if(STATIC OR WIN32)
  80   set(EMBED_DEFAULT ON)
  81 else(STATIC OR WIN32)
  82   set(EMBED_DEFAULT ON) # should be OFF as soon as everything works
  83 endif(STATIC OR WIN32)
  84
  85 option(EMBED_DATA    "Embed all data files in the binary (rather than installing them separately)"   ${EMBED_DEFAULT})
  86
  87 set(QT "" CACHE STRING "Path to a Qt installation to use instead of the system Qt (e.g. for static builds)")
  88
  89 # Some settings imply others
  90 if(STATIC)
  91   add_definitions(-DSTATIC)
  92   set(WITH_KDE OFF CACHE BOOL "Static building with KDE is not supported")
  93 endif(STATIC)
  94
  95 if(WIN32)
  96   # We don't support separately installed resources yet on Win32
  97   set(EMBED_DATA ON)
  98 endif(WIN32)
  99
 100 # For static builds, arbitrary extra libs might need to be linked
 101 # Define a comma-separated list here
 102 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 103 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 104 if(LINK_EXTRA)
 105   string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 106   link_libraries(${LINK_EXTRA})
 107 endif(LINK_EXTRA)
 108
 109 # Build Types
 110
 111
 112 # Simplify checks
 113 if(WANT_MONO OR WANT_QTCLIENT)
 114   set(BUILD_GUI true)
 115 endif(WANT_MONO OR WANT_QTCLIENT)
 116 if(WANT_MONO OR WANT_CORE)
 117   set(BUILD_CORE true)
 118 endif(WANT_MONO OR WANT_CORE)
 119
 120
 121 # Version checks
 122 ################
 123
 124 if(WITH_QT5)
 125   set(QT_MIN_VERSION "5.0.0")
 126   add_definitions(-DHAVE_QT5)
 127
 128   # Qt5 needs a new enough cmake...
 129   cmake_minimum_required(VERSION 2.8.6 FATAL_ERROR)
 130
 131   # ... for automoc
 132   set(CMAKE_AUTOMOC ON)
 133 else(WITH_QT5)
 134
 135   # GUI stuff needs some new features
 136   if(BUILD_GUI)
 137     set(QT_MIN_VERSION "4.6.0")
 138   else(BUILD_GUI)
 139     set(QT_MIN_VERSION "4.4.0")
 140   endif(BUILD_GUI)
 141 endif(WITH_QT5)
 142
 143
 144 # Dependencies
 145 ##############
 146
 147 if(WITH_QT5)
 148   find_package(Qt5Core ${QT_MIN_VERSION} REQUIRED)
 149   # We need QtWidgets
 150   set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} Widgets)
 151
 152   # Setup the i18n-related variables
 153   find_package(Qt5LinguistTools)
 154
 155 else(WITH_QT5)
 156   # Select a Qt installation here, if you don't want to use system Qt
 157   if(QT)
 158     # FindQt4 will look for the qmake binary in $PATH, so we just prepend the Qt dir
 159     set(ENV{PATH} ${QT}/bin:$ENV{PATH})
 160   endif(QT)
 161
 162   # Now that we have the correct $PATH, lets find Qt!
 163   find_package(Qt4 ${QT_MIN_VERSION} REQUIRED)
 164 endif(WITH_QT5)
 165
 166
 167 # Neither Qt4 nor Qt5 consider lconvert relevant, so they don't support finding it...
 168 # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 169 if(QT_LRELEASE_EXECUTABLE)
 170   get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 171   if(WITH_QT5)
 172     find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 173   else(WITH_QT5)
 174     find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 175   endif(WITH_QT5)
 176 endif(QT_LRELEASE_EXECUTABLE)
 177
 178
 179 # zlib for compression, however we can always fall back to miniz
 180 find_package(ZLIB)
 181 if(ZLIB_FOUND)
 182   message(STATUS "Using system zlib for compression")
 183   add_definitions(-DHAVE_ZLIB)
 184   include_directories(${ZLIB_INCLUDE_DIRS})
 185   set(COMMON_LIBRARIES ${COMMON_LIBRARIES} ${ZLIB_LIBRARIES})
 186 else()
 187   message(STATUS "zlib NOT found, using bundled miniz for compression")
 188   if(${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 189     message(STATUS "WARNING: This may be slow on 32 bit systems!")
 190   endif()
 191 endif()
 192
 193
 194 # Execinfo is needed for generating backtraces
 195 find_package(ExecInfo)
 196 if(EXECINFO_FOUND)
 197   add_definitions(-DHAVE_EXECINFO)
 198   include_directories(${EXECINFO_INCLUDES})
 199   link_libraries(${EXECINFO_LIBRARIES})
 200 endif(EXECINFO_FOUND)
 201
 202
 203 # PkgConfig isn't strictly required.
 204 # However, some optional deps might not be found if it's not present, so warn!
 205 find_package(PkgConfig)
 206 if(NOT PKG_CONFIG_FOUND)
 207   message(STATUS "WARNING: PkgConfig not available! Some dependencies for optional features might not be found.")
 208   message(STATUS "         Affected features might include encryption support, DBus menus and Ayatana notifications.")
 209 endif(NOT PKG_CONFIG_FOUND)
 210
 211
 212 # Setup OpenSSL
 213 # We don't link to or include OpenSSL ourselves, but use exclusively the Qt API.
 214 # Thus, we simply check if OpenSSL support is present in Qt's config and enable our
 215 # own SSL stuff in this case. Qt should care for adding what it needs itself.
 216 if(WITH_OPENSSL)
 217   if(QT_QCONFIG MATCHES "openssl")
 218     message(STATUS "Found OpenSSL support in Qt, enabling SSL")
 219     add_definitions(-DHAVE_SSL)
 220     set(HAVE_SSL true)
 221   else(QT_QCONFIG MATCHES "openssl")
 222     message(STATUS "No OpenSSL support found in Qt, disabling SSL")
 223     add_definitions(-DQT_NO_OPENSSL)
 224   endif(QT_QCONFIG MATCHES "openssl")
 225 else(WITH_OPENSSL)
 226   message(STATUS "Not enabling OpenSSL support")
 227 endif(WITH_OPENSSL)
 228
 229
 230 # Check for GUI specific stuff
 231 if(BUILD_GUI)
 232
 233   # Setup D-Bus support
 234   if(WITH_DBUS)
 235     if(WITH_QT5)
 236       find_package(Qt5DBus ${QT_MIN_VERSION})
 237       find_package(Qt5DBusTools)
 238     endif(WITH_QT5)
 239
 240     if(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 241       message(STATUS "Found QtDBus, enabling D-Bus support")
 242       add_definitions(-DHAVE_DBUS)
 243       set(HAVE_DBUS true)
 244       set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} DBus)
 245
 246       # check if we have dbusmenu as well
 247       if(NOT WITH_QT5)
 248         find_package(DBusMenuQt)
 249         if(DBUSMENUQT_FOUND)
 250           message(STATUS "Enabling support for exporting the tray menu via D-Bus")
 251           add_definitions(-DHAVE_DBUSMENU)
 252           include_directories(${DBUSMENUQT_INCLUDE_DIR})
 253           set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${DBUSMENUQT_LIBRARIES})
 254           set(CLIENT_COMPILE_FLAGS "${CLIENT_COMPILE_FLAGS} ${DBUSMENUQT_DEFINITIONS}")
 255         else(DBUSMENUQT_FOUND)
 256           message(STATUS "Disabling support for exporting the tray menu via D-Bus")
 257         endif(DBUSMENUQT_FOUND)
 258       endif(NOT WITH_QT5)
 259
 260     else(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 261       message(STATUS "QtDBus not found, disabling D-Bus support")
 262     endif(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 263   else(WITH_DBUS)
 264     message(STATUS "Not enabling D-Bus support")
 265   endif(WITH_DBUS)
 266
 267   # Setup QtWebkit support
 268   if(WITH_WEBKIT)
 269     if(WITH_QT5)
 270       find_package(Qt5Webkit ${QT_MIN_VERSION} QUIET)
 271     endif(WITH_QT5)
 272     if(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 273       message(STATUS "Found QtWebKit, enabling WebKit support")
 274       add_definitions(-DHAVE_WEBKIT)
 275       set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} Webkit XmlPatterns)
 276       set(HAVE_WEBKIT true)
 277     else(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 278       message(STATUS "QtWebkit not found, disabling Webkit support")
 279     endif(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 280   else(WITH_WEBKIT)
 281     message(STATUS "Not enabling Webkit support")
 282   endif(WITH_WEBKIT)
 283
 284   # Setup KDE4 support
 285   if(WITH_KDE AND NOT WITH_QT5)
 286     # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 287     set(_cflags ${CMAKE_C_FLAGS})
 288     find_package(KDE4)
 289     if(KDE4_FOUND)
 290       message(STATUS "Enabling KDE4 integration")
 291       include_directories(${KDE4_INCLUDES})
 292       add_definitions(-DHAVE_KDE ${KDE4_DEFINITIONS})
 293       set(HAVE_KDE 1)
 294       set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${KDE4_KDECORE_LIBS} ${KDE4_KDEUI_LIBRARY} ${KDE4_SOLID_LIBS} ${KDE4_KNOTIFYCONFIG_LIBRARY})
 295       # We always use external icons for KDE4 support, since we use its iconloader rather than our own
 296       set(EMBED_DATA OFF)
 297       # Restore our old CFLAGS
 298       set(CMAKE_C_FLAGS ${_cflags})
 299     else(KDE4_FOUND)
 300       message(STATUS "KDE4 not found, disabling KDE integration")
 301     endif(KDE4_FOUND)
 302   else(WITH_KDE AND NOT WITH_QT5)
 303     message(STATUS "Not enabling KDE4 integration")
 304   endif(WITH_KDE AND NOT WITH_QT5)
 305
 306   # Setup Phonon support - we only need this if we don't have or want KDE4
 307   if(NOT HAVE_KDE)
 308     if(WITH_PHONON)
 309       if(WITH_QT5)
 310         find_package(Qt5phonon)
 311         if(Qt5phonon_FOUND)
 312           message(STATUS "Enabling Phonon support")
 313           add_definitions(-DHAVE_PHONON)
 314           set(HAVE_PHONON true)
 315           set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} phonon)
 316         else(Qt5phonon_FOUND)
 317           message(STATUS "Phonon not found, disabling audio notifications")
 318         endif(Qt5phonon_FOUND)
 319       else(WITH_QT5)
 320         find_package(Phonon)
 321         if(PHONON_FOUND)
 322           message(STATUS "Enabling Phonon support")
 323           add_definitions(-DHAVE_PHONON)
 324           include_directories(${PHONON_INCLUDES})
 325           set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${PHONON_LIBS})
 326           set(HAVE_PHONON true)
 327         else(PHONON_FOUND)
 328           message(STATUS "Phonon not found, disabling audio notifications")
 329         endif(PHONON_FOUND)
 330       endif(WITH_QT5)
 331     else(WITH_PHONON)
 332       message(STATUS "Not enabling Phonon support")
 333     endif(WITH_PHONON)
 334
 335     find_package(Libsnore)
 336     if(LIBSNORE_FOUND)
 337         add_definitions(-DHAVE_LIBSNORE)
 338         set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${LIBSNORE_LIBRARIES})
 339         set(HAVE_SNORENOTIFY true)
 340     endif(LIBSNORE_FOUND)
 341   endif(NOT HAVE_KDE)
 342
 343   # Setup libindicate-qt support
 344   if(WITH_LIBINDICATE AND NOT WITH_QT5)
 345     pkg_check_modules(INDICATEQT QUIET indicate-qt>=0.2.1)
 346     if(INDICATEQT_FOUND)
 347       message(STATUS "Enabling Ayatana notification support")
 348       set(HAVE_INDICATEQT true)
 349       add_definitions(-DHAVE_INDICATEQT)
 350       link_directories(${INDICATEQT_LIBRARY_DIRS})
 351       set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${INDICATEQT_LIBRARIES})
 352     else(INDICATEQT_FOUND)
 353       message(STATUS "Disabling Ayatana notification support")
 354     endif(INDICATEQT_FOUND)
 355   else(WITH_LIBINDICATE AND NOT WITH_QT5)
 356     message(STATUS "Not enabling Ayatana notification support")
 357     # We don't want to link against it even if another package has found it
 358     set(INDICATEQT_LIBRARIES "")
 359   endif(WITH_LIBINDICATE AND NOT WITH_QT5)
 360
 361   # Setup OS X notification center support
 362   if(WITH_NOTIFICATION_CENTER AND APPLE)
 363     set(HAVE_NOTIFICATION_CENTER true)
 364     add_definitions(-DHAVE_NOTIFICATION_CENTER)
 365     set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES}
 366       /System/Library/Frameworks/Foundation.framework
 367     )
 368   endif()
 369 endif(BUILD_GUI)
 370
 371 # Core-only deps
 372 if(BUILD_CORE)
 373
 374   # Setup encryption support
 375   if(WITH_CRYPT AND NOT WITH_QT5)
 376     find_package(QCA2)
 377     if(QCA2_FOUND)
 378       message(STATUS "Enabling encryption support")
 379       add_definitions(-DHAVE_QCA2)
 380       set(LINK_QCA2 QCA2)
 381       set(HAVE_QCA2 true)
 382       set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_QCA2)
 383     else(QCA2_FOUND)
 384       message(STATUS "Disabling encryption support")
 385     endif(QCA2_FOUND)
 386   else(WITH_CRYPT AND NOT WITH_QT5)
 387     message(STATUS "Not enabling encryption support")
 388   endif(WITH_CRYPT AND NOT WITH_QT5)
 389
 390   # Setup syslog support
 391   if(WITH_SYSLOG)
 392     check_include_file(syslog.h HAVE_SYSLOG_H)
 393     if(HAVE_SYSLOG_H)
 394       message(STATUS "Enabling syslog support")
 395       set(HAVE_SYSLOG true)
 396       add_definitions(-DHAVE_SYSLOG)
 397     else(HAVE_SYSLOG_H)
 398       message(STATUS "Disabling syslog support")
 399     endif(HAVE_SYSLOG_H)
 400   else(WITH_SYSLOG)
 401     message(STATUS "Not enabling syslog support")
 402   endif(WITH_SYSLOG)
 403
 404 endif(BUILD_CORE)
 405
 406
 407 # Various settings
 408 ##################
 409
 410 # needed to compile with mingw without kde
 411 if(MINGW AND NOT HAVE_KDE)
 412     add_definitions(-D_WIN32_WINNT=0x0500)
 413     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 414 # workaround for bug in mingw gcc 4.0
 415     add_definitions(-U__STRICT_ANSI__)
 416 endif(MINGW AND NOT HAVE_KDE)
 417
 418 # Now set up install locations; those are set by KDE if integration is enabled
 419 if(NOT HAVE_KDE)
 420   if(WIN32)
 421     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX} CACHE FILEPATH "Install path for binaries")
 422     set(DATA_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/apps CACHE FILEPATH "Install path for data files")
 423     set(ICON_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/icons CACHE FILEPATH "Global icon install path")
 424     set(XDG_APPS_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/applications CACHE FILEPATH "Install path for .desktop files")
 425   else(WIN32)
 426     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin CACHE FILEPATH "Install path for binaries")
 427     set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps CACHE FILEPATH "Install path for data files")
 428     set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons CACHE FILEPATH "Global icon install path")
 429     set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications CACHE FILEPATH "Install path for .desktop files")
 430   endif(WIN32)
 431 endif(NOT HAVE_KDE)
 432
 433 if(EMBED_DATA)
 434   message(STATUS "Embedding data files into the binary")
 435 else(EMBED_DATA)
 436   message(STATUS "Installing data files separately")
 437 endif(EMBED_DATA)
 438
 439 # RPATH needs to be set correctly
 440 # Do this down here, since otherwise KDE wants to handle it itself, and fails
 441 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
 442 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
 443
 444 # Set global buildflags
 445 # This is very much non-portable, so don't use -DSTATIC until you know what
 446 # you do.
 447 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 448   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 449   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 450   if(HAVE_SSL)
 451     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 452   endif(HAVE_SSL)
 453 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 454
 455 if(WIN32)
 456   link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 457   if(MSVC)
 458     set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 459     set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 460     set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 461     link_libraries(Version dwmapi shlwapi)
 462   endif(MSVC)
 463   if(HAVE_SSL AND STATIC)
 464      find_package(OpenSSL REQUIRED)
 465      link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 466   endif(HAVE_SSL AND STATIC)
 467 endif(WIN32)
 468
 469 if(HAVE_INDICATEQT)
 470   add_definitions(-DXDG_APPS_INSTALL_DIR=${XDG_APPS_INSTALL_DIR})
 471 endif(HAVE_INDICATEQT)
 472
 473 if(NOT WIN32)
 474   check_function_exists(umask HAVE_UMASK)
 475   if(HAVE_UMASK)
 476     add_definitions(-DHAVE_UMASK)
 477   endif(HAVE_UMASK)
 478 endif(NOT WIN32)
 479
 480 # Generate version information from Git
 481 include(GetGitRevisionDescription)
 482 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 483 git_describe(GIT_DESCRIBE --long)
 484
 485 # Sanitize things if we're not in a Git repo
 486 if(NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 487     set(GIT_HEAD "")
 488     set(GIT_DESCRIBE "")
 489 endif()
 490
 491 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 492
 493 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 494 set(COMMON_DEPS ${RC_WIN32})
 495 set(CORE_DEPS )
 496 set(CLIENT_DEPS )
 497
 498 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 499 add_subdirectory(data)
 500 add_subdirectory(icons)
 501 add_subdirectory(pics)
 502 add_subdirectory(po)
 503 add_subdirectory(src)