CMakeLists.txt

   1 # This is the cmake-based build system for Quassel IRC.
   2 #
   3 # You may pass various options to cmake:
   4 #
   5 # -DWANT_(CORE|QTCLIENT|MONO)=(ON|OFF)
   6 #                        : select binaries to build
   7 # -DWITH_OPENSSL=OFF     : Disable OpenSSL support
   8 # -DWITH_DBUS=OFF        : Disable D-Bus support (dbus notifications)
   9 # -DWITH_WEBKIT=OFF      : Disable WebKit support (link previews)
  10 # -DWITH_PHONON=OFF      : Disable Phonon support (audio notifications)
  11 # -DWITH_LIBINDICATE=OFF : Disable libindicate support (Ayatana notifications)
  12 # -DWITH_KDE=ON          : Enable KDE4 support
  13 # -DWITH_CRYPT=OFF       : Disable encryption support
  14 # -DWITH_OXYGEN=(ON|OFF) : Whether to install Oxygen icons (default: yes, unless KDE > 4.3.0 is present and enabled)
  15 # -DWITH_SYSLOG=OFF      : Disable syslog support
  16 #
  17 # -DEMBED_DATA=ON        : Embed all data files in icons the binary, rather than installing them separately
  18 #
  19 # -DQT=/path/to/qt       : Choose a Qt4 installation to use instead of the system Qt4
  20 # -DSTATIC=ON            : Enable static building of Quassel. Use with care.
  21 # -DDEPLOY=ON            : Mac OS X only. Use only for creating Quassel Packages!
  22 #
  23 # -DWITH_QT5=ON          : Enable (very) experimental support for Qt5 (see doc/README.Qt5!)
  24 #
  25 # NOTE: You should remove CMakeCache.txt if you plan to change any of these values!
  26
  27
  28 project(QuasselIRC)
  29
  30 include(CheckFunctionExists)
  31 include(CheckIncludeFile)
  32 include(CheckCXXCompilerFlag)
  33
  34 # For building against Qt5, we check for an even newer cmake version below!
  35 cmake_minimum_required(VERSION 2.8.1 FATAL_ERROR)
  36
  37 if(COMMAND cmake_policy)
  38    cmake_policy(SET CMP0003 NEW)
  39 endif(COMMAND cmake_policy)
  40
  41 # Use our own (well, and KDE's) version of some modules
  42 # In particular cmake's own FindQt4 and FindOpenSSL are quite buggy
  43 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  44 include(QuasselMacros)
  45
  46 # Various options and variables that can be set on the command line
  47 option(WANT_CORE     "Build the core (server) binary"           ON)
  48 option(WANT_QTCLIENT "Build the Qt4 GUI client binary"          ON)
  49 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  50
  51 option(WITH_OPENSSL  "Enable OpenSSL support if present on the system"  ON)
  52 option(WITH_DBUS     "Enable D-Bus support if present on the system"    ON)
  53 option(WITH_WEBKIT   "Enable WebKit support (for link previews)"        ON)
  54 option(WITH_PHONON   "Enable Phonon support (for audio notifications)"  ON)
  55 option(WITH_LIBINDICATE "Enable Ayatana notification support"           ON)
  56 option(WITH_KDE      "Enable KDE4 integration"                          OFF)
  57 option(WITH_CRYPT    "Enable encryption support if present on system"   ON)
  58 option(WITH_SYSLOG   "Use syslog for storing log data"                  ON)
  59
  60 # We use icon paths from KDE 4.3.x, which are partially invalid on older and possibly
  61 # even on newer KDE versions. Do not disable this unless you are sure that your Quassel will
  62 # run on a matching KDE version only.
  63 set(WITH_OXYGEN AUTO CACHE STRING "Install Oxygen icons (default is \"AUTO\" to install when KDE 4.3 or later is present")
  64
  65 # Enable very experimental support for Qt5. Might break the compilation, or even more!
  66 option(WITH_QT5      "Enable (very) experimental support for Qt5"       OFF)
  67
  68 option(STATIC        "Enable static building (might not be portable)" OFF)
  69
  70 if(APPLE)
  71   option(DEPLOY        "Mac OS X only! Adds required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF)
  72   # Notification Center is only available in > 10.8, which is Darwin v12
  73   if(CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  74     option(WITH_NOTIFICATION_CENTER "Enable OS X Notification Center support" ON)
  75   endif(CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  76 endif(APPLE)
  77
  78 # Default to embedding data in the static case
  79 if(STATIC OR WIN32)
  80   set(EMBED_DEFAULT ON)
  81 else(STATIC OR WIN32)
  82   set(EMBED_DEFAULT ON) # should be OFF as soon as everything works
  83 endif(STATIC OR WIN32)
  84
  85 option(EMBED_DATA    "Embed all data files in the binary (rather than installing them separately)"   ${EMBED_DEFAULT})
  86
  87 set(QT "" CACHE STRING "Path to a Qt installation to use instead of the system Qt (e.g. for static builds)")
  88
  89 # Some settings imply others
  90 if(STATIC)
  91   add_definitions(-DSTATIC)
  92   set(WITH_KDE OFF CACHE BOOL "Static building with KDE is not supported")
  93 endif(STATIC)
  94
  95 if(WIN32)
  96   # We don't support separately installed resources yet on Win32
  97   set(EMBED_DATA ON)
  98 endif(WIN32)
  99
 100 # For static builds, arbitrary extra libs might need to be linked
 101 # Define a comma-separated list here
 102 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 103 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 104 if(LINK_EXTRA)
 105   string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 106   link_libraries(${LINK_EXTRA})
 107 endif(LINK_EXTRA)
 108
 109 # Build Types
 110
 111 if(CMAKE_CONFIGURATION_TYPES)
 112    set(CMAKE_CONFIGURATION_TYPES Release RelWithDebInfo Debug Debugfull Profile MinSizeRel)
 113    set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 114      "Reset the configurations to what we need"
 115      FORCE)
 116 endif()
 117
 118 if(NOT CMAKE_BUILD_TYPE)
 119   SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 120      "Choose the type of build, options are: None Debug Release RelWithDebInfo Debug Debugfull Profile MinSizeRel."
 121      FORCE)
 122 endif()
 123
 124 # Qt debug flags
 125 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_DEBUG QT_DEBUG)
 126 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_DEBUGFULL QT_DEBUG)
 127 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_RELEASE QT_NO_DEBUG NDEBUG)
 128 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_RELWITHDEBINFO QT_NO_DEBUG NDEBUG)
 129 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_PROFILE QT_NO_DEBUG NDEBUG)
 130 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_MINSIZEREL QT_NO_DEBUG NDEBUG)
 131
 132 if(NOT CMAKE_CONFIGURATION_TYPES AND NOT CMAKE_BUILD_TYPE)
 133   set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_DEBUG NDEBUG)
 134 endif()
 135
 136 # Enable various flags on gcc
 137 if(CMAKE_COMPILER_IS_GNUCXX)
 138   # Let's just hope that all gccs support these options and skip the tests...
 139   # -fno-strict-aliasing is needed apparently for Qt < 4.6
 140   set(CMAKE_CXX_FLAGS                  "${CMAKE_CXX_FLAGS} -ansi -Wall -Wextra -Wnon-virtual-dtor -fno-strict-aliasing")
 141 #  set(CMAKE_CXX_FLAGS_RELEASE          "-O2")   # use CMake default
 142 #  set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "-g -O2")  # use CMake default
 143   set(CMAKE_CXX_FLAGS_DEBUG             "-g -ggdb -O2 -fno-reorder-blocks -fno-schedule-insns -fno-inline")
 144   set(CMAKE_CXX_FLAGS_DEBUGFULL         "-g3 -ggdb -fno-inline")
 145   set(CMAKE_CXX_FLAGS_PROFILE           "-g3 -ggdb -fno-inline -ftest-coverage -fprofile-arcs")
 146
 147   set(CMAKE_CXX_FLAGS                  "${CMAKE_CXX_FLAGS} -ansi -W -Wall -Wextra -Wnon-virtual-dtor -fno-strict-aliasing -Wundef -Wcast-align -Wpointer-arith -Wformat-security -fno-check-new -fno-common")
 148
 149   check_cxx_compiler_flag(-Woverloaded-virtual CXX_W_OVERLOADED_VIRTUAL)
 150   if(CXX_W_OVERLOADED_VIRTUAL)
 151     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Woverloaded-virtual")
 152   endif()
 153 endif(CMAKE_COMPILER_IS_GNUCXX)
 154
 155 # Mac build stuff
 156 if(APPLE AND DEPLOY)
 157   set(CMAKE_OSX_ARCHITECTURES "x86_64")
 158   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.6")
 159   set(CMAKE_OSX_SYSROOT "/Developer/SDKs/MacOSX10.6.sdk/")
 160   add_definitions(-DMAC_10_6_SDK)
 161 endif(APPLE AND DEPLOY)
 162
 163 # Simplify checks
 164 if(WANT_MONO OR WANT_QTCLIENT)
 165   set(BUILD_GUI true)
 166 endif(WANT_MONO OR WANT_QTCLIENT)
 167 if(WANT_MONO OR WANT_CORE)
 168   set(BUILD_CORE true)
 169 endif(WANT_MONO OR WANT_CORE)
 170
 171
 172 # Version checks
 173 ################
 174
 175 if(WITH_QT5)
 176   set(QT_MIN_VERSION "5.0.0")
 177   add_definitions(-DHAVE_QT5)
 178
 179   # Qt5 needs a new enough cmake...
 180   cmake_minimum_required(VERSION 2.8.6 FATAL_ERROR)
 181
 182   # ... for automoc
 183   set(CMAKE_AUTOMOC ON)
 184 else(WITH_QT5)
 185
 186   # GUI stuff needs some new features
 187   if(BUILD_GUI)
 188     set(QT_MIN_VERSION "4.6.0")
 189   else(BUILD_GUI)
 190     set(QT_MIN_VERSION "4.4.0")
 191   endif(BUILD_GUI)
 192 endif(WITH_QT5)
 193
 194
 195 # Dependencies
 196 ##############
 197
 198 if(WITH_QT5)
 199   find_package(Qt5Core ${QT_MIN_VERSION} REQUIRED)
 200   # We need QtWidgets
 201   set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} Widgets)
 202
 203   # Setup the i18n-related variables
 204   find_package(Qt5LinguistTools)
 205
 206 else(WITH_QT5)
 207   # Select a Qt installation here, if you don't want to use system Qt
 208   if(QT)
 209     # FindQt4 will look for the qmake binary in $PATH, so we just prepend the Qt dir
 210     set(ENV{PATH} ${QT}/bin:$ENV{PATH})
 211   endif(QT)
 212
 213   # Now that we have the correct $PATH, lets find Qt!
 214   find_package(Qt4 ${QT_MIN_VERSION} REQUIRED)
 215 endif(WITH_QT5)
 216
 217
 218 # Neither Qt4 nor Qt5 consider lconvert relevant, so they don't support finding it...
 219 # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 220 if(QT_LRELEASE_EXECUTABLE)
 221   get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 222   if(WITH_QT5)
 223     find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 224   else(WITH_QT5)
 225     find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 226   endif(WITH_QT5)
 227 endif(QT_LRELEASE_EXECUTABLE)
 228
 229
 230 # Execinfo is needed for generating backtraces
 231 find_package(ExecInfo)
 232 if(EXECINFO_FOUND)
 233   add_definitions(-DHAVE_EXECINFO)
 234   include_directories(${EXECINFO_INCLUDES})
 235   link_libraries(${EXECINFO_LIBRARIES})
 236 endif(EXECINFO_FOUND)
 237
 238
 239 # PkgConfig isn't strictly required.
 240 # However, some optional deps might not be found if it's not present, so warn!
 241 find_package(PkgConfig)
 242 if(NOT PKG_CONFIG_FOUND)
 243   message(STATUS "WARNING: PkgConfig not available! Some dependencies for optional features might not be found.")
 244   message(STATUS "         Affected features might include encryption support, DBus menus and Ayatana notifications.")
 245 endif(NOT PKG_CONFIG_FOUND)
 246
 247
 248 # Setup OpenSSL
 249 # We don't link to or include OpenSSL ourselves, but use exclusively the Qt API.
 250 # Thus, we simply check if OpenSSL support is present in Qt's config and enable our
 251 # own SSL stuff in this case. Qt should care for adding what it needs itself.
 252 if(WITH_OPENSSL)
 253   if(QT_QCONFIG MATCHES "openssl")
 254     message(STATUS "Found OpenSSL support in Qt, enabling SSL")
 255     add_definitions(-DHAVE_SSL)
 256     set(HAVE_SSL true)
 257   else(QT_QCONFIG MATCHES "openssl")
 258     message(STATUS "No OpenSSL support found in Qt, disabling SSL")
 259     add_definitions(-DQT_NO_OPENSSL)
 260   endif(QT_QCONFIG MATCHES "openssl")
 261 else(WITH_OPENSSL)
 262   message(STATUS "Not enabling OpenSSL support")
 263 endif(WITH_OPENSSL)
 264
 265
 266 # Check for GUI specific stuff
 267 if(BUILD_GUI)
 268
 269   # Setup D-Bus support
 270   if(WITH_DBUS)
 271     if(WITH_QT5)
 272       find_package(Qt5DBus ${QT_MIN_VERSION})
 273       find_package(Qt5DBusTools)
 274     endif(WITH_QT5)
 275
 276     if(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 277       message(STATUS "Found QtDBus, enabling D-Bus support")
 278       add_definitions(-DHAVE_DBUS)
 279       set(HAVE_DBUS true)
 280       set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} DBus)
 281
 282       # check if we have dbusmenu as well
 283       if(NOT WITH_QT5)
 284         find_package(DBusMenuQt)
 285         if(DBUSMENUQT_FOUND)
 286           message(STATUS "Enabling support for exporting the tray menu via D-Bus")
 287           add_definitions(-DHAVE_DBUSMENU)
 288           include_directories(${DBUSMENUQT_INCLUDE_DIR})
 289           set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${DBUSMENUQT_LIBRARIES})
 290           set(CLIENT_COMPILE_FLAGS "${CLIENT_COMPILE_FLAGS} ${DBUSMENUQT_DEFINITIONS}")
 291         else(DBUSMENUQT_FOUND)
 292           message(STATUS "Disabling support for exporting the tray menu via D-Bus")
 293         endif(DBUSMENUQT_FOUND)
 294       endif(NOT WITH_QT5)
 295
 296     else(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 297       message(STATUS "QtDBus not found, disabling D-Bus support")
 298     endif(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 299   else(WITH_DBUS)
 300     message(STATUS "Not enabling D-Bus support")
 301   endif(WITH_DBUS)
 302
 303   # Setup QtWebkit support
 304   if(WITH_WEBKIT)
 305     if(WITH_QT5)
 306       find_package(Qt5Webkit ${QT_MIN_VERSION} QUIET)
 307     endif(WITH_QT5)
 308     if(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 309       message(STATUS "Found QtWebKit, enabling WebKit support")
 310       add_definitions(-DHAVE_WEBKIT)
 311       set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} Webkit XmlPatterns)
 312       set(HAVE_WEBKIT true)
 313     else(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 314       message(STATUS "QtWebkit not found, disabling Webkit support")
 315     endif(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 316   else(WITH_WEBKIT)
 317     message(STATUS "Not enabling Webkit support")
 318   endif(WITH_WEBKIT)
 319
 320   # Setup KDE4 support
 321   if(WITH_KDE AND NOT WITH_QT5)
 322     find_package(KDE4)
 323     if(KDE4_FOUND)
 324       message(STATUS "Enabling KDE4 integration")
 325       include_directories(${KDE4_INCLUDES})
 326       add_definitions(-DHAVE_KDE ${KDE4_DEFINITIONS})
 327       set(HAVE_KDE 1)
 328       set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${KDE4_KDECORE_LIBS} ${KDE4_KDEUI_LIBRARY} ${KDE4_SOLID_LIBS} knotifyconfig)
 329       # We always use external icons for KDE4 support, since we use its iconloader rather than our own
 330       set(EMBED_DATA OFF)
 331     else(KDE4_FOUND)
 332       message(STATUS "KDE4 not found, disabling KDE integration")
 333     endif(KDE4_FOUND)
 334   else(WITH_KDE AND NOT WITH_QT5)
 335     message(STATUS "Not enabling KDE4 integration")
 336   endif(WITH_KDE AND NOT WITH_QT5)
 337
 338   # Setup Phonon support - we only need this if we don't have or want KDE4
 339   if(NOT HAVE_KDE)
 340     if(WITH_PHONON)
 341       if(WITH_QT5)
 342         find_package(Qt5phonon)
 343         if(Qt5phonon_FOUND)
 344           message(STATUS "Enabling Phonon support")
 345           add_definitions(-DHAVE_PHONON)
 346           set(HAVE_PHONON true)
 347           set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} phonon)
 348         else(Qt5phonon_FOUND)
 349           message(STATUS "Phonon not found, disabling audio notifications")
 350         endif(Qt5phonon_FOUND)
 351       else(WITH_QT5)
 352         find_package(Phonon)
 353         if(PHONON_FOUND)
 354           message(STATUS "Enabling Phonon support")
 355           add_definitions(-DHAVE_PHONON)
 356           include_directories(${PHONON_INCLUDES})
 357           set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${PHONON_LIBS})
 358           set(HAVE_PHONON true)
 359         else(PHONON_FOUND)
 360           message(STATUS "Phonon not found, disabling audio notifications")
 361         endif(PHONON_FOUND)
 362       endif(WITH_QT5)
 363     else(WITH_PHONON)
 364       message(STATUS "Not enabling Phonon support")
 365     endif(WITH_PHONON)
 366   endif(NOT HAVE_KDE)
 367
 368   # Setup libindicate-qt support
 369   if(WITH_LIBINDICATE AND NOT WITH_QT5)
 370     pkg_check_modules(INDICATEQT QUIET indicate-qt>=0.2.1)
 371     if(INDICATEQT_FOUND)
 372       message(STATUS "Enabling Ayatana notification support")
 373       set(HAVE_INDICATEQT true)
 374       add_definitions(-DHAVE_INDICATEQT)
 375       link_directories(${INDICATEQT_LIBRARY_DIRS})
 376       set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${INDICATEQT_LIBRARIES})
 377     else(INDICATEQT_FOUND)
 378       message(STATUS "Disabling Ayatana notification support")
 379     endif(INDICATEQT_FOUND)
 380   else(WITH_LIBINDICATE AND NOT WITH_QT5)
 381     message(STATUS "Not enabling Ayatana notification support")
 382     # We don't want to link against it even if another package has found it
 383     set(INDICATEQT_LIBRARIES "")
 384   endif(WITH_LIBINDICATE AND NOT WITH_QT5)
 385
 386   # Setup OS X notification center support
 387   if(WITH_NOTIFICATION_CENTER AND APPLE)
 388     set(HAVE_NOTIFICATION_CENTER true)
 389     add_definitions(-DHAVE_NOTIFICATION_CENTER)
 390     set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES}
 391       /System/Library/Frameworks/Foundation.framework
 392     )
 393   endif()
 394
 395 endif(BUILD_GUI)
 396
 397 # Core-only deps
 398 if(BUILD_CORE)
 399
 400   # Setup encryption support
 401   if(WITH_CRYPT AND NOT WITH_QT5)
 402     find_package(QCA2)
 403     if(QCA2_FOUND)
 404       message(STATUS "Enabling encryption support")
 405       add_definitions(-DHAVE_QCA2)
 406       set(LINK_QCA2 QCA2)
 407       set(HAVE_QCA2 true)
 408       set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_QCA2)
 409     else(QCA2_FOUND)
 410       message(STATUS "Disabling encryption support")
 411     endif(QCA2_FOUND)
 412   else(WITH_CRYPT AND NOT WITH_QT5)
 413     message(STATUS "Not enabling encryption support")
 414   endif(WITH_CRYPT AND NOT WITH_QT5)
 415
 416   # Setup syslog support
 417   if(WITH_SYSLOG)
 418     check_include_file(syslog.h HAVE_SYSLOG_H)
 419     if(HAVE_SYSLOG_H)
 420       message(STATUS "Enabling syslog support")
 421       set(HAVE_SYSLOG true)
 422       add_definitions(-DHAVE_SYSLOG)
 423     else(HAVE_SYSLOG_H)
 424       message(STATUS "Disabling syslog support")
 425     endif(HAVE_SYSLOG_H)
 426   else(WITH_SYSLOG)
 427     message(STATUS "Not enabling syslog support")
 428   endif(WITH_SYSLOG)
 429
 430 endif(BUILD_CORE)
 431
 432
 433 # Various settings
 434 ##################
 435
 436 # needed to compile with mingw without kde
 437 if(MINGW AND NOT HAVE_KDE)
 438     add_definitions(-D_WIN32_WINNT=0x0500)
 439     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 440 # workaround for bug in mingw gcc 4.0
 441     add_definitions(-U__STRICT_ANSI__)
 442 endif(MINGW AND NOT HAVE_KDE)
 443
 444 # Now set up install locations; those are set by KDE if integration is enabled
 445 if(NOT HAVE_KDE)
 446   if(WIN32)
 447     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX} CACHE FILEPATH "Install path for binaries")
 448     set(DATA_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/apps CACHE FILEPATH "Install path for data files")
 449     set(ICON_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/icons CACHE FILEPATH "Global icon install path")
 450     set(XDG_APPS_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/applications CACHE FILEPATH "Install path for .desktop files")
 451   else(WIN32)
 452     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin CACHE FILEPATH "Install path for binaries")
 453     set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps CACHE FILEPATH "Install path for data files")
 454     set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons CACHE FILEPATH "Global icon install path")
 455     set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications CACHE FILEPATH "Install path for .desktop files")
 456   endif(WIN32)
 457 endif(NOT HAVE_KDE)
 458
 459 if(EMBED_DATA)
 460   message(STATUS "Embedding data files into the binary")
 461 else(EMBED_DATA)
 462   message(STATUS "Installing data files separately")
 463 endif(EMBED_DATA)
 464
 465 # RPATH needs to be set correctly
 466 # Do this down here, since otherwise KDE wants to handle it itself, and fails
 467 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
 468 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
 469
 470 # Set global buildflags
 471 # This is very much non-portable, so don't use -DSTATIC until you know what
 472 # you do.
 473 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 474   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 475   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 476   if(HAVE_SSL)
 477     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 478   endif(HAVE_SSL)
 479 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 480
 481 if(WIN32)
 482   link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 483   if(MSVC)
 484     set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 485     set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 486     set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 487     link_libraries(Version dwmapi shlwapi)
 488   endif(MSVC)
 489   if(HAVE_SSL AND STATIC)
 490      find_package(OpenSSL REQUIRED)
 491      link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 492   endif(HAVE_SSL AND STATIC)
 493 endif(WIN32)
 494
 495 if(HAVE_INDICATEQT)
 496   add_definitions(-DXDG_APPS_INSTALL_DIR=${XDG_APPS_INSTALL_DIR})
 497 endif(HAVE_INDICATEQT)
 498
 499 if(NOT WIN32)
 500   check_function_exists(umask HAVE_UMASK)
 501   if(HAVE_UMASK)
 502     add_definitions(-DHAVE_UMASK)
 503   endif(HAVE_UMASK)
 504 endif(NOT WIN32)
 505
 506 # We need to create a version.gen
 507 # For this, we create our genversion binary and make sure it is run every time.
 508
 509 setup_qt_variables()
 510 include_directories(${QUASSEL_QT_INCLUDES})
 511
 512 add_executable(genversion ${CMAKE_SOURCE_DIR}/src/common/genversion.cpp)
 513 target_link_libraries(genversion ${QUASSEL_QT_LIBRARIES})
 514 set_target_properties(genversion PROPERTIES COMPILE_FLAGS "${QUASSEL_QT_COMPILEFLAGS}")
 515
 516 get_target_property(GENVERSION_EXECUTABLE genversion LOCATION)
 517 add_custom_target(genversion_run ALL ${GENVERSION_EXECUTABLE}
 518                   ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR}/src/version.gen)
 519 add_dependencies(genversion_run genversion)
 520
 521 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 522 set(COMMON_DEPS ${RC_WIN32})
 523 set(CORE_DEPS )
 524 set(CLIENT_DEPS )
 525
 526 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 527 add_subdirectory(data)
 528 add_subdirectory(icons)
 529 add_subdirectory(pics)
 530 add_subdirectory(po)
 531 add_subdirectory(src)