CMakeLists.txt

   1 # This is the cmake-based build system for Quassel IRC.
   2 #
   3 # You may pass various options to cmake:
   4 #
   5 # -DWANT_(CORE|QTCLIENT|MONO)=(ON|OFF)
   6 #                        : select binaries to build
   7 # -DWITH_OPENSSL=OFF     : Disable OpenSSL support
   8 # -DWITH_DBUS=OFF        : Disable D-Bus support (dbus notifications)
   9 # -DWITH_WEBKIT=OFF      : Disable WebKit support (link previews)
  10 # -DWITH_PHONON=OFF      : Disable Phonon support (audio notifications)
  11 # -DWITH_LIBINDICATE=OFF : Disable libindicate support (Ayatana notifications)
  12 # -DWITH_KDE=ON          : Enable KDE4 support
  13 # -DWITH_CRYPT=OFF       : Disable encryption support
  14 # -DWITH_OXYGEN=(ON|OFF) : Whether to install Oxygen icons (default: yes, unless KDE > 4.3.0 is present and enabled)
  15 # -DWITH_SYSLOG=OFF      : Disable syslog support
  16 #
  17 # -DEMBED_DATA=ON        : Embed all data files in icons the binary, rather than installing them separately
  18 #
  19 # -DQT=/path/to/qt       : Choose a Qt4 installation to use instead of the system Qt4
  20 # -DSTATIC=ON            : Enable static building of Quassel. Use with care.
  21 # -DDEPLOY=ON            : Mac OS X only. Use only for creating Quassel Packages!
  22 #
  23 # -DWITH_QT5=ON          : Enable (very) experimental support for Qt5 (see doc/README.Qt5!)
  24 #
  25 # NOTE: You should remove CMakeCache.txt if you plan to change any of these values!
  26
  27
  28 project(QuasselIRC)
  29
  30 include(CheckFunctionExists)
  31 include(CheckIncludeFile)
  32 include(CheckCXXCompilerFlag)
  33
  34 # For building against Qt5, we check for an even newer cmake version below!
  35 cmake_minimum_required(VERSION 2.8.1 FATAL_ERROR)
  36
  37 if(COMMAND cmake_policy)
  38    cmake_policy(SET CMP0003 NEW)
  39 endif(COMMAND cmake_policy)
  40
  41 # Use our own (well, and KDE's) version of some modules
  42 # In particular cmake's own FindQt4 and FindOpenSSL are quite buggy
  43 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  44 include(QuasselMacros)
  45
  46 # Various options and variables that can be set on the command line
  47 option(WANT_CORE     "Build the core (server) binary"           ON)
  48 option(WANT_QTCLIENT "Build the Qt4 GUI client binary"          ON)
  49 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  50
  51 option(WITH_OPENSSL  "Enable OpenSSL support if present on the system"  ON)
  52 option(WITH_DBUS     "Enable D-Bus support if present on the system"    ON)
  53 option(WITH_WEBKIT   "Enable WebKit support (for link previews)"        ON)
  54 option(WITH_PHONON   "Enable Phonon support (for audio notifications)"  ON)
  55 option(WITH_LIBINDICATE "Enable Ayatana notification support"           ON)
  56 option(WITH_KDE      "Enable KDE4 integration"                          OFF)
  57 option(WITH_CRYPT    "Enable encryption support if present on system"   ON)
  58 option(WITH_SYSLOG   "Use syslog for storing log data"                  ON)
  59
  60 # We use icon paths from KDE 4.3.x, which are partially invalid on older and possibly
  61 # even on newer KDE versions. Do not disable this unless you are sure that your Quassel will
  62 # run on a matching KDE version only.
  63 set(WITH_OXYGEN AUTO CACHE STRING "Install Oxygen icons (default is \"AUTO\" to install when KDE 4.3 or later is present")
  64
  65 # Enable very experimental support for Qt5. Might break the compilation, or even more!
  66 option(WITH_QT5      "Enable (very) experimental support for Qt5"       OFF)
  67
  68 option(STATIC        "Enable static building (might not be portable)" OFF)
  69
  70 if(APPLE)
  71   option(DEPLOY        "Mac OS X only! Adds required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF)
  72   # Notification Center is only available in > 10.8, which is Darwin v12
  73   if(CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  74     option(WITH_NOTIFICATION_CENTER "Enable OS X Notification Center support" ON)
  75   endif(CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  76 endif(APPLE)
  77
  78 # Default to embedding data in the static case
  79 if(STATIC OR WIN32)
  80   set(EMBED_DEFAULT ON)
  81 else(STATIC OR WIN32)
  82   set(EMBED_DEFAULT ON) # should be OFF as soon as everything works
  83 endif(STATIC OR WIN32)
  84
  85 option(EMBED_DATA    "Embed all data files in the binary (rather than installing them separately)"   ${EMBED_DEFAULT})
  86
  87 set(QT "" CACHE STRING "Path to a Qt installation to use instead of the system Qt (e.g. for static builds)")
  88
  89 # Some settings imply others
  90 if(STATIC)
  91   add_definitions(-DSTATIC)
  92   set(WITH_KDE OFF CACHE BOOL "Static building with KDE is not supported")
  93 endif(STATIC)
  94
  95 if(WIN32)
  96   # We don't support separately installed resources yet on Win32
  97   set(EMBED_DATA ON)
  98 endif(WIN32)
  99
 100 # For static builds, arbitrary extra libs might need to be linked
 101 # Define a comma-separated list here
 102 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 103 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 104 if(LINK_EXTRA)
 105   string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 106   link_libraries(${LINK_EXTRA})
 107 endif(LINK_EXTRA)
 108
 109 # Build Types
 110
 111 if(CMAKE_CONFIGURATION_TYPES)
 112    set(CMAKE_CONFIGURATION_TYPES Release RelWithDebInfo Debug Debugfull Profile MinSizeRel)
 113    set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 114      "Reset the configurations to what we need"
 115      FORCE)
 116 endif()
 117
 118 if(NOT CMAKE_BUILD_TYPE)
 119   SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 120      "Choose the type of build, options are: None Debug Release RelWithDebInfo Debug Debugfull Profile MinSizeRel."
 121      FORCE)
 122 endif()
 123
 124 # Qt debug flags
 125 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_DEBUG QT_DEBUG)
 126 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_DEBUGFULL QT_DEBUG)
 127 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_RELEASE QT_NO_DEBUG NDEBUG)
 128 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_RELWITHDEBINFO QT_NO_DEBUG NDEBUG)
 129 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_PROFILE QT_NO_DEBUG NDEBUG)
 130 set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_MINSIZEREL QT_NO_DEBUG NDEBUG)
 131
 132 if(NOT CMAKE_CONFIGURATION_TYPES AND NOT CMAKE_BUILD_TYPE)
 133   set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_DEBUG NDEBUG)
 134 endif()
 135
 136 # Enable various flags on gcc
 137 if(CMAKE_COMPILER_IS_GNUCXX)
 138   # Let's just hope that all gccs support these options and skip the tests...
 139   # -fno-strict-aliasing is needed apparently for Qt < 4.6
 140   set(CMAKE_CXX_FLAGS                  "${CMAKE_CXX_FLAGS} -ansi -Wall -Wextra -Wnon-virtual-dtor -fno-strict-aliasing")
 141 #  set(CMAKE_CXX_FLAGS_RELEASE          "-O2")   # use CMake default
 142 #  set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "-g -O2")  # use CMake default
 143   set(CMAKE_CXX_FLAGS_DEBUG             "-g -ggdb -O2 -fno-reorder-blocks -fno-schedule-insns -fno-inline")
 144   set(CMAKE_CXX_FLAGS_DEBUGFULL         "-g3 -ggdb -fno-inline")
 145   set(CMAKE_CXX_FLAGS_PROFILE           "-g3 -ggdb -fno-inline -ftest-coverage -fprofile-arcs")
 146
 147   set(CMAKE_CXX_FLAGS                  "${CMAKE_CXX_FLAGS} -ansi -W -Wall -Wextra -Wnon-virtual-dtor -fno-strict-aliasing -Wundef -Wcast-align -Wpointer-arith -Wformat-security -fno-check-new -fno-common")
 148
 149   check_cxx_compiler_flag(-Woverloaded-virtual CXX_W_OVERLOADED_VIRTUAL)
 150   if(CXX_W_OVERLOADED_VIRTUAL)
 151     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Woverloaded-virtual")
 152   endif()
 153 endif(CMAKE_COMPILER_IS_GNUCXX)
 154
 155 # ... and for Clang
 156 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 157   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wnon-virtual-dtor -Wno-long-long -Wundef -Wcast-align -Wchar-subscripts -Wall -W -Wextra -Wpointer-arith -Wformat-security -Woverloaded-virtual -fno-common -Werror=return-type")
 158 #  set(CMAKE_CXX_FLAGS_RELEASE        "-O2 -DNDEBUG -DQT_NO_DEBUG")     # Use CMake default
 159 #  set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "-O2 -g -DNDEBUG -DQT_NO_DEBUG")  # Use CMake default
 160   set(CMAKE_CXX_FLAGS_DEBUG          "-g -O2 -fno-inline")
 161   set(CMAKE_CXX_FLAGS_DEBUGFULL      "-g3 -fno-inline")
 162   set(CMAKE_CXX_FLAGS_PROFILE        "-g3 -fno-inline -ftest-coverage -fprofile-arcs")
 163 endif()
 164
 165 # Mac build stuff
 166 if(APPLE AND DEPLOY)
 167   set(CMAKE_OSX_ARCHITECTURES "x86_64")
 168   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.6")
 169   set(CMAKE_OSX_SYSROOT "/Developer/SDKs/MacOSX10.6.sdk/")
 170   add_definitions(-DMAC_10_6_SDK)
 171 endif(APPLE AND DEPLOY)
 172
 173 # Simplify checks
 174 if(WANT_MONO OR WANT_QTCLIENT)
 175   set(BUILD_GUI true)
 176 endif(WANT_MONO OR WANT_QTCLIENT)
 177 if(WANT_MONO OR WANT_CORE)
 178   set(BUILD_CORE true)
 179 endif(WANT_MONO OR WANT_CORE)
 180
 181
 182 # Version checks
 183 ################
 184
 185 if(WITH_QT5)
 186   set(QT_MIN_VERSION "5.0.0")
 187   add_definitions(-DHAVE_QT5)
 188
 189   # Qt5 needs a new enough cmake...
 190   cmake_minimum_required(VERSION 2.8.6 FATAL_ERROR)
 191
 192   # ... for automoc
 193   set(CMAKE_AUTOMOC ON)
 194 else(WITH_QT5)
 195
 196   # GUI stuff needs some new features
 197   if(BUILD_GUI)
 198     set(QT_MIN_VERSION "4.6.0")
 199   else(BUILD_GUI)
 200     set(QT_MIN_VERSION "4.4.0")
 201   endif(BUILD_GUI)
 202 endif(WITH_QT5)
 203
 204
 205 # Dependencies
 206 ##############
 207
 208 if(WITH_QT5)
 209   find_package(Qt5Core ${QT_MIN_VERSION} REQUIRED)
 210   # We need QtWidgets
 211   set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} Widgets)
 212
 213   # Setup the i18n-related variables
 214   find_package(Qt5LinguistTools)
 215
 216 else(WITH_QT5)
 217   # Select a Qt installation here, if you don't want to use system Qt
 218   if(QT)
 219     # FindQt4 will look for the qmake binary in $PATH, so we just prepend the Qt dir
 220     set(ENV{PATH} ${QT}/bin:$ENV{PATH})
 221   endif(QT)
 222
 223   # Now that we have the correct $PATH, lets find Qt!
 224   find_package(Qt4 ${QT_MIN_VERSION} REQUIRED)
 225 endif(WITH_QT5)
 226
 227
 228 # Neither Qt4 nor Qt5 consider lconvert relevant, so they don't support finding it...
 229 # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 230 if(QT_LRELEASE_EXECUTABLE)
 231   get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 232   if(WITH_QT5)
 233     find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 234   else(WITH_QT5)
 235     find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 236   endif(WITH_QT5)
 237 endif(QT_LRELEASE_EXECUTABLE)
 238
 239
 240 # Execinfo is needed for generating backtraces
 241 find_package(ExecInfo)
 242 if(EXECINFO_FOUND)
 243   add_definitions(-DHAVE_EXECINFO)
 244   include_directories(${EXECINFO_INCLUDES})
 245   link_libraries(${EXECINFO_LIBRARIES})
 246 endif(EXECINFO_FOUND)
 247
 248
 249 # PkgConfig isn't strictly required.
 250 # However, some optional deps might not be found if it's not present, so warn!
 251 find_package(PkgConfig)
 252 if(NOT PKG_CONFIG_FOUND)
 253   message(STATUS "WARNING: PkgConfig not available! Some dependencies for optional features might not be found.")
 254   message(STATUS "         Affected features might include encryption support, DBus menus and Ayatana notifications.")
 255 endif(NOT PKG_CONFIG_FOUND)
 256
 257
 258 # Setup OpenSSL
 259 # We don't link to or include OpenSSL ourselves, but use exclusively the Qt API.
 260 # Thus, we simply check if OpenSSL support is present in Qt's config and enable our
 261 # own SSL stuff in this case. Qt should care for adding what it needs itself.
 262 if(WITH_OPENSSL)
 263   if(QT_QCONFIG MATCHES "openssl")
 264     message(STATUS "Found OpenSSL support in Qt, enabling SSL")
 265     add_definitions(-DHAVE_SSL)
 266     set(HAVE_SSL true)
 267   else(QT_QCONFIG MATCHES "openssl")
 268     message(STATUS "No OpenSSL support found in Qt, disabling SSL")
 269     add_definitions(-DQT_NO_OPENSSL)
 270   endif(QT_QCONFIG MATCHES "openssl")
 271 else(WITH_OPENSSL)
 272   message(STATUS "Not enabling OpenSSL support")
 273 endif(WITH_OPENSSL)
 274
 275
 276 # Check for GUI specific stuff
 277 if(BUILD_GUI)
 278
 279   # Setup D-Bus support
 280   if(WITH_DBUS)
 281     if(WITH_QT5)
 282       find_package(Qt5DBus ${QT_MIN_VERSION})
 283       find_package(Qt5DBusTools)
 284     endif(WITH_QT5)
 285
 286     if(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 287       message(STATUS "Found QtDBus, enabling D-Bus support")
 288       add_definitions(-DHAVE_DBUS)
 289       set(HAVE_DBUS true)
 290       set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} DBus)
 291
 292       # check if we have dbusmenu as well
 293       if(NOT WITH_QT5)
 294         find_package(DBusMenuQt)
 295         if(DBUSMENUQT_FOUND)
 296           message(STATUS "Enabling support for exporting the tray menu via D-Bus")
 297           add_definitions(-DHAVE_DBUSMENU)
 298           include_directories(${DBUSMENUQT_INCLUDE_DIR})
 299           set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${DBUSMENUQT_LIBRARIES})
 300           set(CLIENT_COMPILE_FLAGS "${CLIENT_COMPILE_FLAGS} ${DBUSMENUQT_DEFINITIONS}")
 301         else(DBUSMENUQT_FOUND)
 302           message(STATUS "Disabling support for exporting the tray menu via D-Bus")
 303         endif(DBUSMENUQT_FOUND)
 304       endif(NOT WITH_QT5)
 305
 306     else(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 307       message(STATUS "QtDBus not found, disabling D-Bus support")
 308     endif(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 309   else(WITH_DBUS)
 310     message(STATUS "Not enabling D-Bus support")
 311   endif(WITH_DBUS)
 312
 313   # Setup QtWebkit support
 314   if(WITH_WEBKIT)
 315     if(WITH_QT5)
 316       find_package(Qt5Webkit ${QT_MIN_VERSION} QUIET)
 317     endif(WITH_QT5)
 318     if(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 319       message(STATUS "Found QtWebKit, enabling WebKit support")
 320       add_definitions(-DHAVE_WEBKIT)
 321       set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} Webkit XmlPatterns)
 322       set(HAVE_WEBKIT true)
 323     else(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 324       message(STATUS "QtWebkit not found, disabling Webkit support")
 325     endif(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 326   else(WITH_WEBKIT)
 327     message(STATUS "Not enabling Webkit support")
 328   endif(WITH_WEBKIT)
 329
 330   # Setup KDE4 support
 331   if(WITH_KDE AND NOT WITH_QT5)
 332     find_package(KDE4)
 333     if(KDE4_FOUND)
 334       message(STATUS "Enabling KDE4 integration")
 335       include_directories(${KDE4_INCLUDES})
 336       add_definitions(-DHAVE_KDE ${KDE4_DEFINITIONS})
 337       set(HAVE_KDE 1)
 338       set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${KDE4_KDECORE_LIBS} ${KDE4_KDEUI_LIBRARY} ${KDE4_SOLID_LIBS} ${KDE4_KNOTIFYCONFIG_LIBRARY})
 339       # We always use external icons for KDE4 support, since we use its iconloader rather than our own
 340       set(EMBED_DATA OFF)
 341     else(KDE4_FOUND)
 342       message(STATUS "KDE4 not found, disabling KDE integration")
 343     endif(KDE4_FOUND)
 344   else(WITH_KDE AND NOT WITH_QT5)
 345     message(STATUS "Not enabling KDE4 integration")
 346   endif(WITH_KDE AND NOT WITH_QT5)
 347
 348   # Setup Phonon support - we only need this if we don't have or want KDE4
 349   if(NOT HAVE_KDE)
 350     if(WITH_PHONON)
 351       if(WITH_QT5)
 352         find_package(Qt5phonon)
 353         if(Qt5phonon_FOUND)
 354           message(STATUS "Enabling Phonon support")
 355           add_definitions(-DHAVE_PHONON)
 356           set(HAVE_PHONON true)
 357           set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} phonon)
 358         else(Qt5phonon_FOUND)
 359           message(STATUS "Phonon not found, disabling audio notifications")
 360         endif(Qt5phonon_FOUND)
 361       else(WITH_QT5)
 362         find_package(Phonon)
 363         if(PHONON_FOUND)
 364           message(STATUS "Enabling Phonon support")
 365           add_definitions(-DHAVE_PHONON)
 366           include_directories(${PHONON_INCLUDES})
 367           set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${PHONON_LIBS})
 368           set(HAVE_PHONON true)
 369         else(PHONON_FOUND)
 370           message(STATUS "Phonon not found, disabling audio notifications")
 371         endif(PHONON_FOUND)
 372       endif(WITH_QT5)
 373     else(WITH_PHONON)
 374       message(STATUS "Not enabling Phonon support")
 375     endif(WITH_PHONON)
 376   endif(NOT HAVE_KDE)
 377
 378   # Setup libindicate-qt support
 379   if(WITH_LIBINDICATE AND NOT WITH_QT5)
 380     pkg_check_modules(INDICATEQT QUIET indicate-qt>=0.2.1)
 381     if(INDICATEQT_FOUND)
 382       message(STATUS "Enabling Ayatana notification support")
 383       set(HAVE_INDICATEQT true)
 384       add_definitions(-DHAVE_INDICATEQT)
 385       link_directories(${INDICATEQT_LIBRARY_DIRS})
 386       set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${INDICATEQT_LIBRARIES})
 387     else(INDICATEQT_FOUND)
 388       message(STATUS "Disabling Ayatana notification support")
 389     endif(INDICATEQT_FOUND)
 390   else(WITH_LIBINDICATE AND NOT WITH_QT5)
 391     message(STATUS "Not enabling Ayatana notification support")
 392     # We don't want to link against it even if another package has found it
 393     set(INDICATEQT_LIBRARIES "")
 394   endif(WITH_LIBINDICATE AND NOT WITH_QT5)
 395
 396   # Setup OS X notification center support
 397   if(WITH_NOTIFICATION_CENTER AND APPLE)
 398     set(HAVE_NOTIFICATION_CENTER true)
 399     add_definitions(-DHAVE_NOTIFICATION_CENTER)
 400     set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES}
 401       /System/Library/Frameworks/Foundation.framework
 402     )
 403   endif()
 404
 405 find_package(Libsnore)
 406 if(LIBSNORE_FOUND)
 407     add_definitions(-DHAVE_LIBSNORE -DLIBSNORE_PLUGIN_PATH="${LIBSNORE_PLUGIN_PATH}")
 408     set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${LIBSNORE_LIBRARIES})
 409     set(HAVE_SNORENOTIFY true)
 410 endif(LIBSNORE_FOUND)
 411 endif(BUILD_GUI)
 412
 413 # Core-only deps
 414 if(BUILD_CORE)
 415
 416   # Setup encryption support
 417   if(WITH_CRYPT AND NOT WITH_QT5)
 418     find_package(QCA2)
 419     if(QCA2_FOUND)
 420       message(STATUS "Enabling encryption support")
 421       add_definitions(-DHAVE_QCA2)
 422       set(LINK_QCA2 QCA2)
 423       set(HAVE_QCA2 true)
 424       set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_QCA2)
 425     else(QCA2_FOUND)
 426       message(STATUS "Disabling encryption support")
 427     endif(QCA2_FOUND)
 428   else(WITH_CRYPT AND NOT WITH_QT5)
 429     message(STATUS "Not enabling encryption support")
 430   endif(WITH_CRYPT AND NOT WITH_QT5)
 431
 432   # Setup syslog support
 433   if(WITH_SYSLOG)
 434     check_include_file(syslog.h HAVE_SYSLOG_H)
 435     if(HAVE_SYSLOG_H)
 436       message(STATUS "Enabling syslog support")
 437       set(HAVE_SYSLOG true)
 438       add_definitions(-DHAVE_SYSLOG)
 439     else(HAVE_SYSLOG_H)
 440       message(STATUS "Disabling syslog support")
 441     endif(HAVE_SYSLOG_H)
 442   else(WITH_SYSLOG)
 443     message(STATUS "Not enabling syslog support")
 444   endif(WITH_SYSLOG)
 445
 446 endif(BUILD_CORE)
 447
 448
 449 # Various settings
 450 ##################
 451
 452 # needed to compile with mingw without kde
 453 if(MINGW AND NOT HAVE_KDE)
 454     add_definitions(-D_WIN32_WINNT=0x0500)
 455     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 456 # workaround for bug in mingw gcc 4.0
 457     add_definitions(-U__STRICT_ANSI__)
 458 endif(MINGW AND NOT HAVE_KDE)
 459
 460 # Now set up install locations; those are set by KDE if integration is enabled
 461 if(NOT HAVE_KDE)
 462   if(WIN32)
 463     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX} CACHE FILEPATH "Install path for binaries")
 464     set(DATA_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/apps CACHE FILEPATH "Install path for data files")
 465     set(ICON_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/icons CACHE FILEPATH "Global icon install path")
 466     set(XDG_APPS_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/applications CACHE FILEPATH "Install path for .desktop files")
 467   else(WIN32)
 468     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin CACHE FILEPATH "Install path for binaries")
 469     set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps CACHE FILEPATH "Install path for data files")
 470     set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons CACHE FILEPATH "Global icon install path")
 471     set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications CACHE FILEPATH "Install path for .desktop files")
 472   endif(WIN32)
 473 endif(NOT HAVE_KDE)
 474
 475 if(EMBED_DATA)
 476   message(STATUS "Embedding data files into the binary")
 477 else(EMBED_DATA)
 478   message(STATUS "Installing data files separately")
 479 endif(EMBED_DATA)
 480
 481 # RPATH needs to be set correctly
 482 # Do this down here, since otherwise KDE wants to handle it itself, and fails
 483 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
 484 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
 485
 486 # Set global buildflags
 487 # This is very much non-portable, so don't use -DSTATIC until you know what
 488 # you do.
 489 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 490   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 491   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 492   if(HAVE_SSL)
 493     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 494   endif(HAVE_SSL)
 495 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 496
 497 if(WIN32)
 498   link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 499   if(MSVC)
 500     set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 501     set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 502     set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 503     link_libraries(Version dwmapi shlwapi)
 504   endif(MSVC)
 505   if(HAVE_SSL AND STATIC)
 506      find_package(OpenSSL REQUIRED)
 507      link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 508   endif(HAVE_SSL AND STATIC)
 509 endif(WIN32)
 510
 511 if(HAVE_INDICATEQT)
 512   add_definitions(-DXDG_APPS_INSTALL_DIR=${XDG_APPS_INSTALL_DIR})
 513 endif(HAVE_INDICATEQT)
 514
 515 if(NOT WIN32)
 516   check_function_exists(umask HAVE_UMASK)
 517   if(HAVE_UMASK)
 518     add_definitions(-DHAVE_UMASK)
 519   endif(HAVE_UMASK)
 520 endif(NOT WIN32)
 521
 522 # We need to create a version.gen
 523 # For this, we create our genversion binary and make sure it is run every time.
 524
 525 setup_qt_variables()
 526 include_directories(${QUASSEL_QT_INCLUDES})
 527
 528 add_executable(genversion ${CMAKE_SOURCE_DIR}/src/common/genversion.cpp)
 529 target_link_libraries(genversion ${QUASSEL_QT_LIBRARIES})
 530 set_target_properties(genversion PROPERTIES COMPILE_FLAGS "${QUASSEL_QT_COMPILEFLAGS}")
 531
 532 get_target_property(GENVERSION_EXECUTABLE genversion LOCATION)
 533 add_custom_target(genversion_run ALL ${GENVERSION_EXECUTABLE}
 534                   ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR}/src/version.gen)
 535 add_dependencies(genversion_run genversion)
 536
 537 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 538 set(COMMON_DEPS ${RC_WIN32})
 539 set(CORE_DEPS )
 540 set(CLIENT_DEPS )
 541
 542 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 543 add_subdirectory(data)
 544 add_subdirectory(icons)
 545 add_subdirectory(pics)
 546 add_subdirectory(po)
 547 add_subdirectory(src)