CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 project(QuasselIRC)
  10
  11 # Versions
  12 set(QUASSEL_MAJOR  0)
  13 set(QUASSEL_MINOR 13)
  14 set(QUASSEL_PATCH  0)
  15 set(QUASSEL_VERSION_STRING "0.13-pre")
  16
  17 # Output CMake version and build type for debug reasons
  18 message(STATUS "Using CMake ${CMAKE_VERSION}")
  19 message(STATUS "CMake build type: ${CMAKE_BUILD_TYPE}")
  20
  21 # Tell CMake about or own modules
  22 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  23
  24 # General conveniences
  25 set(CMAKE_AUTOMOC ON)
  26 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  27
  28 # Include various CMake modules...
  29 include(CMakePushCheckState)
  30 include(CheckFunctionExists)
  31 include(CheckIncludeFile)
  32 include(CheckCXXSourceCompiles)
  33 include(CMakeDependentOption)
  34 include(FeatureSummary)
  35
  36 # ... and our own stuff
  37 include(QuasselCompileSettings)
  38 include(QuasselMacros)
  39
  40
  41 # Options and variables that can be set on the command line
  42 #####################################################################
  43
  44 # First, choose a Qt version. We support USE_QT5 and USE_QT4; if neither is set, Qt5 will be used
  45 option(USE_QT5 "Enable support for Qt5" OFF)
  46 if (USE_QT5) # takes precedence
  47     set(USE_QT4 OFF)
  48 else()
  49     if (NOT USE_QT4)
  50         set(USE_QT5 ON)
  51     endif()
  52 endif()
  53
  54 # Select the binaries to build
  55 option(WANT_CORE     "Build the core (server) binary"           ON)
  56 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  57 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  58 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  59 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  60 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  61
  62 # Whether to enable KDE integration (work in progress for Qt5 / KDE Frameworks)
  63 # Note that when building with Qt5, WITH_KDE enables integration with higher-tier KDE frameworks that
  64 # require runtime support. We still optionally make use of certain Tier 1 frameworks even if WITH_KDE
  65 # is disabled.
  66 if (USE_QT4)
  67     option(WITH_KDE "KDE4 integration" OFF)
  68     add_feature_info(WITH_KDE WITH_KDE "Enable KDE4 integration")
  69 else()
  70     option(WITH_KDE "Integration with the KDE Frameworks runtime environment")
  71     add_feature_info(WITH_KDE WITH_KDE "Integrate with the KDE Frameworks runtime environment")
  72 endif()
  73
  74 cmake_dependent_option(WITH_BREEZE "Install Breeze icon theme (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
  75 cmake_dependent_option(WITH_BREEZE_DARK "Install Dark Breeze icon theme (usually shipped with KDE)" OFF "NOT WITH_KDE" OFF)
  76 cmake_dependent_option(WITH_OXYGEN "Install Oxygen icon theme (usually shipped with KDE)" OFF "NOT WITH_KDE" OFF)
  77 if (NOT WITH_KDE)
  78     add_feature_info(WITH_BREEZE WITH_BREEZE "Install Breeze icon theme")
  79     add_feature_info(WITH_BREEZE_DARK WITH_BREEZE_DARK "Install Dark Breeze icon theme")
  80     add_feature_info(WITH_OXYGEN WITH_OXYGEN "Install Oxygen icon theme")
  81 endif()
  82
  83 if (WITH_OXYGEN)
  84     add_definitions(-DWITH_OXYGEN)
  85 endif()
  86 if (WITH_BREEZE)
  87     add_definitions(-DWITH_BREEZE)
  88 endif()
  89 if (WITH_BREEZE_DARK)
  90     add_definitions(-DWITH_BREEZE_DARK)
  91 endif()
  92
  93 # For this, the feature info is added after we know if QtWebkit is installed
  94 option(WITH_WEBKIT "WebKit support (for link previews) (legacy)" OFF)
  95
  96 # For this, the feature info is added after we know if QtWebEngine is installed
  97 option(WITH_WEBENGINE "WebEngine support (for link previews)" ON)
  98
  99 if (APPLE)
 100     # Notification Center is only available in > 10.8, which is Darwin v12
 101     if (NOT CMAKE_SYSTEM_VERSION VERSION_LESS 12)
 102         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
 103         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
 104     endif()
 105     find_library(CARBON_LIBRARY Carbon)
 106     mark_as_advanced(CARBON_LIBRARY)
 107     link_libraries(${CARBON_LIBRARY})
 108 endif()
 109
 110 # Always embed on Windows, OSX or for a static build; never embed when enabling KDE integration
 111 set(EMBED_DEFAULT OFF)
 112 if (STATIC OR WIN32 OR APPLE)
 113     set(EMBED_DEFAULT ON)
 114 endif()
 115 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
 116                                    "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
 117 if (NOT EMBED_DEFAULT)
 118     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
 119 endif()
 120
 121 # The following options are not for end-user consumption, so don't list them in the feature summary
 122 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
 123
 124 # Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
 125 cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
 126
 127 # For static builds, arbitrary extra libs might need to be linked
 128 # Define a comma-separated list here
 129 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 130 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 131 if (LINK_EXTRA)
 132     string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 133     link_libraries(${LINK_EXTRA})
 134 endif()
 135
 136
 137 # List of authenticators and the cmake flags to build them
 138 # (currently that's just LDAP, but more can be added here).
 139 ####################################################################
 140 option(WITH_LDAP "Enable LDAP authentication support if present on system" ON)
 141
 142 # Setup CMake
 143 #####################################################################
 144
 145 if (USE_QT5 AND WITH_KDE)
 146     cmake_minimum_required(VERSION 2.8.12)
 147 else()
 148     cmake_minimum_required(VERSION 2.8.9)
 149 endif()
 150
 151 # Setting COMPILE_DEFINITIONS_<CONFIG> is deprecated since CMake 3.0 in favor of generator expressions.
 152 # These have existed since CMake 2.8.10; until we depend on that, we have to explicitly enable the old policy.
 153 if (POLICY CMP0043)
 154     cmake_policy(SET CMP0043 OLD)
 155 endif()
 156
 157 # Honor visibility settings for all target types
 158 if (POLICY CMP0063)
 159     cmake_policy(SET CMP0063 NEW)
 160 endif()
 161
 162 # Don't automoc generated files
 163 if (POLICY CMP0071)
 164     cmake_policy(SET CMP0071 OLD)
 165 endif()
 166
 167
 168 # Simplify later checks
 169 #####################################################################
 170
 171 if (WANT_MONO OR WANT_QTCLIENT)
 172     set(BUILD_GUI true)
 173 endif()
 174 if (WANT_MONO OR WANT_CORE)
 175     set(BUILD_CORE true)
 176 endif()
 177
 178
 179 # Set up Qt
 180 #####################################################################
 181
 182 # Find package dependencies
 183 #
 184 # Note that you can forcefully disable optional packages
 185 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 186 #####################################################################
 187
 188 if (USE_QT5)
 189     message(STATUS "Building for Qt5...")
 190     set(QT_MIN_VERSION "5.2.0")
 191     add_definitions(-DHAVE_QT5)
 192
 193     find_package(Qt5Core ${QT_MIN_VERSION} QUIET)
 194     set_package_properties(Qt5Core PROPERTIES TYPE REQUIRED
 195         URL "https://www.qt.io/"
 196         DESCRIPTION "contains core functionality for Qt"
 197     )
 198     # find_package without REQUIRED won't check for the version properly; also, older Qt5 versions
 199     # used Qt5Core_VERSION_STRING... let's just make sure here that we bail out here if our Qt5 is not new enough.
 200     if (NOT Qt5Core_VERSION OR Qt5Core_VERSION VERSION_LESS ${QT_MIN_VERSION})
 201         message(FATAL_ERROR "Could NOT find Qt5 >= version ${QT_MIN_VERSION}!")
 202     endif()
 203
 204     find_package(Qt5Network QUIET)
 205     set_package_properties(Qt5Network PROPERTIES TYPE REQUIRED
 206         DESCRIPTION "the network module for Qt5"
 207     )
 208
 209     if (BUILD_GUI)
 210         find_package(Qt5Gui QUIET)
 211         set_package_properties(Qt5Gui PROPERTIES TYPE REQUIRED
 212             DESCRIPTION "the GUI module for Qt5"
 213         )
 214         find_package(Qt5Widgets QUIET)
 215         set_package_properties(Qt5Widgets PROPERTIES TYPE REQUIRED
 216             DESCRIPTION "the widgets module for Qt5"
 217         )
 218
 219         if (NOT WIN32)
 220             find_package(Qt5DBus QUIET)
 221             set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 222                 URL "https://www.qt.io/"
 223                 DESCRIPTION "D-Bus support for Qt5"
 224                 PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 225             )
 226             if (Qt5DBus_FOUND)
 227                 find_package(dbusmenu-qt5 QUIET CONFIG)
 228                 set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 229                     URL "https://launchpad.net/libdbusmenu-qt"
 230                     DESCRIPTION "a library implementing the DBusMenu specification"
 231                     PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 232                 )
 233             endif()
 234         endif()
 235
 236         find_package(Qt5Multimedia QUIET)
 237         set_package_properties(Qt5Multimedia PROPERTIES TYPE RECOMMENDED
 238             URL "https://www.qt.io/"
 239             DESCRIPTION "Multimedia support for Qt5"
 240             PURPOSE     "Required for audio notifications"
 241         )
 242
 243         if (NOT Qt5Multimedia_FOUND)
 244             find_package(Phonon4Qt5 QUIET)
 245             set_package_properties(Phonon4Qt5 PROPERTIES TYPE RECOMMENDED
 246                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 247                 DESCRIPTION "a multimedia abstraction library"
 248                 PURPOSE     "Required for audio notifications"
 249             )
 250         endif()
 251
 252         find_package(LibsnoreQt5 0.7.0 QUIET)
 253         set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
 254             URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 255             DESCRIPTION "a cross-platform notification framework"
 256             PURPOSE     "Enable support for the snorenotify framework"
 257         )
 258         if(LibsnoreQt5_FOUND)
 259             find_package(LibsnoreSettingsQt5)
 260             set_package_properties(LibsnoreSettingsQt5 PROPERTIES TYPE REQUIRED
 261                 URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 262                 DESCRIPTION "a cross-platform notification framework"
 263                 PURPOSE     "Enable support for the snorenotify framework"
 264             )
 265         endif()
 266
 267
 268         if (WITH_WEBKIT)
 269             find_package(Qt5WebKit QUIET)
 270             set_package_properties(Qt5WebKit PROPERTIES TYPE RECOMMENDED
 271                 URL "https://www.qt.io/"
 272                 DESCRIPTION "a WebKit implementation for Qt"
 273                 PURPOSE     "Needed for displaying previews for URLs in chat"
 274             )
 275             if (Qt5WebKit_FOUND)
 276                 find_package(Qt5WebKitWidgets QUIET)
 277                 set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE RECOMMENDED
 278                     URL "https://www.qt.io/"
 279                     DESCRIPTION "widgets for Qt's WebKit implementation"
 280                     PURPOSE     "Needed for displaying previews for URLs in chat"
 281                 )
 282             endif()
 283         endif()
 284
 285         if (WITH_WEBKIT AND Qt5WebKitWidgets_FOUND)
 286             set(HAVE_WEBKIT true)
 287         endif()
 288         add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" HAVE_WEBKIT "Support showing previews for URLs in chat (legacy)")
 289
 290         if (WITH_WEBENGINE)
 291             find_package(Qt5WebEngine QUIET)
 292             set_package_properties(Qt5WebEngine PROPERTIES TYPE RECOMMENDED
 293                 URL "https://www.qt.io/"
 294                 DESCRIPTION "a WebEngine implementation for Qt"
 295                 PURPOSE     "Needed for displaying previews for URLs in chat"
 296             )
 297             if (Qt5WebEngine_FOUND)
 298                 find_package(Qt5WebEngineWidgets QUIET)
 299                 set_package_properties(Qt5WebEngineWidgets PROPERTIES TYPE RECOMMENDED
 300                     URL "https://www.qt.io/"
 301                     DESCRIPTION "widgets for Qt's WebEngine implementation"
 302                     PURPOSE     "Needed for displaying previews for URLs in chat"
 303                 )
 304             endif()
 305         endif()
 306
 307         if (WITH_WEBENGINE AND Qt5WebEngineWidgets_FOUND)
 308             set(HAVE_WEBENGINE true)
 309         endif()
 310         add_feature_info("WITH_WEBENGINE, QtWebEngine and QtWebEngineWidgets modules" HAVE_WEBENGINE "Support showing previews for URLs in chat")
 311
 312         # KDE Frameworks
 313         ################
 314
 315         if (WITH_KDE)
 316             set(ecm_find_type "REQUIRED")
 317         else()
 318             # Even with KDE integration disabled, we optionally use tier1 frameworks if we find them
 319             set(ecm_find_type "RECOMMENDED")
 320         endif()
 321
 322         # extra-cmake-modules
 323         find_package(ECM NO_MODULE QUIET)
 324         set_package_properties(ECM PROPERTIES TYPE ${ecm_find_type}
 325             URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules"
 326             DESCRIPTION "extra modules for CMake, maintained by the KDE project"
 327             PURPOSE     "Required to find KDE Frameworks components"
 328         )
 329
 330         if (ECM_FOUND)
 331             list(APPEND CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
 332             if (WITH_KDE)
 333                 find_package(KF5 COMPONENTS ConfigWidgets CoreAddons Notifications NotifyConfig TextWidgets WidgetsAddons XmlGui QUIET)
 334                 set_package_properties(KF5 PROPERTIES TYPE REQUIRED
 335                     URL "http://www.kde.org"
 336                     DESCRIPTION "KDE Frameworks"
 337                     PURPOSE     "Required for integration into the Plasma desktop"
 338                 )
 339             else()
 340                 find_package(KF5Sonnet QUIET)
 341                 set_package_properties(KF5Sonnet PROPERTIES TYPE RECOMMENDED
 342                     URL "http://api.kde.org/frameworks-api/frameworks5-apidocs/sonnet/html"
 343                     DESCRIPTION "framework for providing spell-checking capabilities"
 344                     PURPOSE "Enables spell-checking support in input widgets"
 345                 )
 346             endif()
 347         endif()
 348
 349     endif()
 350
 351     if (BUILD_CORE)
 352         find_package(Qt5Script QUIET)
 353         set_package_properties(Qt5Script PROPERTIES TYPE REQUIRED
 354             DESCRIPTION "provides scripting support for Qt5"
 355         )
 356         find_package(Qt5Sql QUIET)
 357         set_package_properties(Qt5Sql PROPERTIES TYPE REQUIRED
 358             DESCRIPTION "the database support module for Qt5"
 359         )
 360
 361         find_package(QCA2-QT5)
 362         set_package_properties(QCA2-QT5 PROPERTIES TYPE RECOMMENDED
 363             URL "https://projects.kde.org/projects/kdesupport/qca"
 364             DESCRIPTION "Qt Cryptographic Architecture"
 365             PURPOSE "Required for encryption support"
 366         )
 367
 368     endif()
 369
 370     find_package(Qt5LinguistTools QUIET)
 371     set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 372                            DESCRIPTION "contains tools for handling translation files"
 373                            PURPOSE "Required for having translations"
 374     )
 375
 376     # Some Qt5 versions do not define a target for lconvert, so we need to find it ourselves
 377     if (Qt5LinguistTools_FOUND)
 378         if (NOT TARGET Qt5::lconvert AND TARGET Qt5::lrelease)
 379             get_target_property(_lrelease_location Qt5::lrelease LOCATION)
 380             get_filename_component(_lrelease_path ${_lrelease_location} PATH)
 381             find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 382         elseif(TARGET Qt5::lconvert AND NOT Qt5_LCONVERT_EXECUTABLE)
 383             # Newer Qt5 versions define the target, but not the Qt5_LCONVERT_EXECUTABLE variable for some reason
 384             get_target_property(QT_LCONVERT_EXECUTABLE Qt5::lconvert LOCATION)
 385         endif()
 386
 387         # Compatibility with the Qt4 variables
 388         set(QT_LRELEASE_EXECUTABLE ${Qt5_LRELEASE_EXECUTABLE})
 389         set(QT_LUPDATE_EXECUTABLE ${Qt5_LUPDATE_EXECUTABLE})
 390         if (Qt5_LCONVERT_EXECUTABLE)
 391             set(QT_LCONVERT_EXECUTABLE ${Qt5_LCONVERT_EXECUTABLE})
 392         endif()
 393     endif()
 394
 395 else()
 396     message(STATUS "Building for Qt4...")
 397     set(QT_MIN_VERSION "4.8.0")
 398
 399     find_package(Qt4 ${QT_MIN_VERSION} QUIET REQUIRED)
 400
 401     if (BUILD_GUI)
 402         add_feature_info("QtDBus module" QT_QTDBUS_FOUND "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments")
 403         if (QT_QTDBUS_FOUND)
 404             find_package(dbusmenu-qt QUIET CONFIG)
 405             set_package_properties(dbusmenu-qt PROPERTIES TYPE RECOMMENDED
 406                 URL "https://launchpad.net/libdbusmenu-qt"
 407                 DESCRIPTION "a library implementing the DBusMenu specification"
 408                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 409             )
 410         endif()
 411
 412         if (WITH_WEBKIT AND QT_QTWEBKIT_FOUND)
 413             set(HAVE_WEBKIT true)
 414         endif()
 415         add_feature_info("WITH_WEBKIT and QtWebKit module" HAVE_WEBKIT "Support showing previews for URLs in chat")
 416
 417         if (WITH_KDE)
 418             # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 419             set(_cflags ${CMAKE_C_FLAGS})
 420             find_package(KDE4 4.4 QUIET)
 421             set_package_properties(KDE4 PROPERTIES TYPE REQUIRED
 422                 URL "http://www.kde.org"
 423                 DESCRIPTION "a world-class desktop environment"
 424                 PURPOSE "Enables various bits for improving integration with KDE"
 425             )
 426             set(CMAKE_C_FLAGS ${_cflags})
 427
 428         else()
 429             find_package(Phonon QUIET)
 430             set_package_properties(Phonon PROPERTIES TYPE RECOMMENDED
 431                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 432                 DESCRIPTION "a multimedia abstraction library"
 433                 PURPOSE     "Required for audio notifications"
 434             )
 435         endif()
 436
 437         find_package(IndicateQt QUIET)
 438         set_package_properties(IndicateQt PROPERTIES TYPE OPTIONAL
 439             URL "https://launchpad.net/libindicate-qt/"
 440             DESCRIPTION "a library to raise flags on DBus for other components of the desktop to pick up and visualize"
 441             PURPOSE     "Provides integration into the Ayatana notification system used by e.g. Ubuntu"
 442         )
 443
 444     endif()
 445
 446     if (BUILD_CORE)
 447
 448         find_package(QCA2 QUIET)
 449         set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 450             URL "https://projects.kde.org/projects/kdesupport/qca"
 451             DESCRIPTION "Qt Cryptographic Architecture"
 452             PURPOSE     "Required for encryption support"
 453         )
 454
 455
 456     endif()
 457
 458     # Qt4 does not consider lconvert relevant, so they don't support finding it...
 459     # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 460     if (QT_LRELEASE_EXECUTABLE)
 461         get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 462         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 463     endif()
 464 endif()
 465
 466
 467 # Non-Qt-based packages
 468
 469 # zlib for compression, however we can always fall back to miniz
 470 find_package(ZLIB QUIET)
 471 set_package_properties(ZLIB PROPERTIES TYPE RECOMMENDED
 472     URL "http://www.zlib.net"
 473     DESCRIPTION "a popular compression library"
 474     PURPOSE     "Use the most common library for protocol compression, instead of the bundled miniz implementation"
 475 )
 476
 477
 478 if (NOT WIN32)
 479     # Execinfo is needed for generating backtraces
 480     find_package(ExecInfo QUIET)
 481     set_package_properties(ExecInfo PROPERTIES TYPE OPTIONAL
 482         DESCRIPTION "a library for inspecting backtraces"
 483         PURPOSE "Used for generating backtraces in case of a crash"
 484     )
 485 endif()
 486
 487 # Check for SSL support in Qt
 488 # As there's no easy way to get Qt's configuration in particular for Qt5, let's just compile
 489 # a small test program checking the defines. This works for both Qt4 and Qt5.
 490 cmake_push_check_state(RESET)
 491 set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES} ${Qt5Core_INCLUDE_DIRS})
 492 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Core_EXECUTABLE_COMPILE_FLAGS}")
 493
 494 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 495     set(CMAKE_REQUIRED_FLAGS "-fPIC -DQT_NO_VERSION_TAGGING")
 496 endif()
 497
 498 check_cxx_source_compiles("
 499     #include \"qglobal.h\"
 500     #if defined QT_NO_SSL
 501     #  error \"No SSL support\"
 502     #endif
 503     int main() {}"
 504     HAVE_SSL)
 505 cmake_pop_check_state()
 506
 507 # Additional compile settings
 508 #####################################################################
 509
 510 # This sets -fPIC and friends if required by the installed Qt5 library
 511 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 512     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 513 endif()
 514
 515 # Needed to compile with mingw without kde
 516 if (MINGW AND NOT KDE4_FOUND)
 517     add_definitions(-D_WIN32_WINNT=0x0500)
 518     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 519     # workaround for bug in mingw gcc 4.0
 520     add_definitions(-U__STRICT_ANSI__)
 521 endif()
 522
 523 # Sanitize compiler flags - old versions of KDE set -ansi, which breaks -std=c++11
 524 if (CMAKE_COMPILER_IS_GNUCXX)
 525     string(REPLACE "-ansi" "" CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS})
 526 endif()
 527
 528 # Setup LDAP Authentication support.
 529 #####################################################################
 530 if (WITH_LDAP)
 531     find_package(Ldap)
 532     if (LDAP_FOUND)
 533         message(STATUS "Enabling LDAP authentication support")
 534         set(HAVE_LDAP true)
 535         add_definitions(-DHAVE_LDAP)
 536     else()
 537         message(STATUS "Disabling LDAP authentication support")
 538     endif()
 539 else()
 540     message(STATUS "Not enabling LDAP authentication support")
 541 endif()
 542
 543 # Setup KDE / KDE Frameworks
 544 #####################################################################
 545
 546 # We want to do this up here, so we have the necessary variables and defines set before
 547 # compiling anything
 548
 549 if (KDE4_FOUND)
 550     # We always use external icons for KDE4 support, since we use its iconloader rather than Qt's
 551     set(EMBED_DATA OFF)
 552
 553     # Better have the compile flags global, even for the core, to avoid problems with linking the mono client
 554     add_definitions(-DHAVE_KDE -DHAVE_KDE4 ${KDE4_DEFINITIONS})
 555     set(WITH_KDE4 TRUE)
 556 endif()
 557
 558 if (USE_QT5 AND WITH_KDE)
 559     # If KDE Frameworks are present, they're most probably providing Qt5 integration including icon loading
 560     set(EMBED_DATA OFF)
 561
 562     include(KDEInstallDirs)
 563     include(KDECompilerSettings)
 564     include(KDECMakeSettings)
 565
 566     add_definitions(-DHAVE_KDE -DHAVE_KF5)
 567     set(WITH_KF5 TRUE)
 568 endif()
 569
 570 # This needs to come after setting up KDE integration, so we can use KDE-specific paths
 571 include(QuasselInstallDirs)
 572
 573 # Various config-dependent checks and settings
 574 #####################################################################
 575
 576 if (NOT ZLIB_FOUND)
 577     message(STATUS "zlib NOT found, using bundled miniz for compression")
 578     if (${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 579         message(STATUS "WARNING: This may be slow on 32 bit systems!")
 580     endif()
 581 endif()
 582
 583 if (HAVE_SSL)
 584     add_definitions(-DHAVE_SSL)
 585 endif()
 586 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 587
 588 # Check for syslog support
 589 if (NOT WIN32)
 590     check_include_file(syslog.h HAVE_SYSLOG)
 591     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 592 endif()
 593
 594 add_feature_info("Qt Linguist Tools" QT_LCONVERT_EXECUTABLE "Translation support for Quassel")
 595
 596 if (EMBED_DATA)
 597     message(STATUS "Embedding data files into the binary")
 598 else()
 599     message(STATUS "Installing data files separately")
 600 endif()
 601
 602 if (INDICATEQT_FOUND)
 603     add_definitions(-DXDG_APPS_INSTALL_DIR=${CMAKE_INSTALL_APPDIR})
 604 endif()
 605
 606 if (NOT WIN32)
 607     check_function_exists(umask HAVE_UMASK)
 608     if(HAVE_UMASK)
 609         add_definitions(-DHAVE_UMASK)
 610     endif()
 611 endif()
 612
 613
 614 # Windows-specific stuff
 615 #####################################################################
 616
 617 if (WIN32)
 618     link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 619     if (MSVC)
 620         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /DNOMINMAX")
 621         set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 622         set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 623         set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 624         link_libraries(Version dwmapi shlwapi)
 625         if (USE_QT5)
 626             set(QT_QTMAIN_LIBRARY Qt5::WinMain)
 627         endif()
 628     endif()
 629     if(HAVE_SSL AND STATIC)
 630         find_package(OpenSSL REQUIRED)
 631         link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 632     endif()
 633 endif()
 634
 635
 636 # Static builds (very much non-portable, so don't use -DSTATIC
 637 # unless you know what you do!)
 638 #####################################################################
 639
 640 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 641     set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 642     link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 643     if (HAVE_SSL)
 644         set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 645     endif()
 646 endif()
 647
 648
 649 # Generate version information from Git
 650 #####################################################################
 651
 652 include(GetGitRevisionDescription)
 653 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 654 git_describe(GIT_DESCRIBE --long)
 655
 656 # If in a Git repo we can get the commit-date from a git command
 657 if (GIT_HEAD)
 658     execute_process(
 659         COMMAND git -c log.showsignature=false show -s --format=%ct
 660         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 661         OUTPUT_VARIABLE GIT_COMMIT_DATE
 662         OUTPUT_STRIP_TRAILING_WHITESPACE
 663     )
 664 endif()
 665
 666 # If not in a Git repo try to read GIT_HEAD and GIT_DESCRIBE from
 667 # enviroment
 668 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 669   if (DEFINED ENV{GIT_HEAD})
 670       set(GIT_HEAD $ENV{GIT_HEAD})
 671   endif()
 672   if (DEFINED ENV{GIT_DESCRIBE})
 673      set(GIT_DESCRIBE $ENV{GIT_DESCRIBE})
 674   endif()
 675 endif()
 676
 677 # Sanitize things if we're not in a Git repo
 678 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 679     set(GIT_HEAD "")
 680     set(GIT_DESCRIBE "")
 681     set(GIT_COMMIT_DATE 0)
 682 endif()
 683
 684 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 685
 686 # Prepare the build
 687 #####################################################################
 688
 689 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 690 set(COMMON_DEPS ${RC_WIN32})
 691 set(CORE_DEPS )
 692 set(CLIENT_DEPS )
 693
 694 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 695 add_subdirectory(data)
 696 add_subdirectory(icons)
 697 add_subdirectory(pics)
 698 add_subdirectory(po)
 699
 700
 701 # Set up and display feature summary
 702 #####################################################################
 703
 704 feature_summary(WHAT ALL
 705                 INCLUDE_QUIET_PACKAGES
 706                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 707 )
 708
 709 # Finally, compile the sources
 710 # We want this after displaying the feature summary to avoid ugly
 711 # CMake backtraces in case a required Qt5 module is missing
 712 #####################################################################
 713
 714 add_subdirectory(src)