CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 project(QuasselIRC)
  10
  11 # Versions
  12 set(QUASSEL_MAJOR  0)
  13 set(QUASSEL_MINOR 13)
  14 set(QUASSEL_PATCH  0)
  15 set(QUASSEL_VERSION_STRING "0.13-pre")
  16
  17 # We want to know CMake's version for debug reasons
  18 message(STATUS "Using CMake ${CMAKE_VERSION}")
  19
  20 # Tell CMake about or own modules
  21 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  22
  23 # General conveniences
  24 set(CMAKE_AUTOMOC ON)
  25 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  26
  27 # Include various CMake modules...
  28 include(CMakePushCheckState)
  29 include(CheckFunctionExists)
  30 include(CheckIncludeFile)
  31 include(CheckCXXSourceCompiles)
  32 include(CMakeDependentOption)
  33 include(FeatureSummary)
  34
  35 # ... and our own stuff
  36 include(QuasselCompileSettings)
  37 include(QuasselMacros)
  38
  39
  40 # Options and variables that can be set on the command line
  41 #####################################################################
  42
  43 # First, choose a Qt version. We support USE_QT4 and USE_QT5; if neither is set, prefer Qt4 for now
  44 option(USE_QT5 "Enable support for Qt5 (disables KDE integration)" OFF)
  45 if (USE_QT4) # takes precedence
  46     set(USE_QT5 OFF)
  47 else()
  48     if (NOT USE_QT5)
  49         set(USE_QT4 ON)
  50     endif()
  51 endif()
  52
  53 # Select the binaries to build
  54 option(WANT_CORE     "Build the core (server) binary"           ON)
  55 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  56 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  57 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  58 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  59 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  60
  61 # Whether to enable KDE integration (work in progress for Qt5 / KDE Frameworks)
  62 # Note that when building with Qt5, WITH_KDE enables integration with higher-tier KDE frameworks that
  63 # require runtime support. We still optionally make use of certain Tier 1 frameworks even if WITH_KDE
  64 # is disabled.
  65 if (USE_QT4)
  66     option(WITH_KDE "KDE4 integration" OFF)
  67     add_feature_info(WITH_KDE WITH_KDE "Enable KDE4 integration")
  68 else()
  69     option(WITH_KDE "Integration with the KDE Frameworks runtime environment")
  70     add_feature_info(WITH_KDE WITH_KDE "Integrate with the KDE Frameworks runtime environment")
  71 endif()
  72
  73 cmake_dependent_option(WITH_OXYGEN "Install Oxygen icon set (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
  74 if (NOT WITH_KDE)
  75     add_feature_info(WITH_OXYGEN WITH_OXYGEN "Install Oxygen icon set")
  76 endif()
  77
  78 # For this, the feature info is added after we know if QtWebkit is installed
  79 option(WITH_WEBKIT "WebKit support (for link previews)" ON)
  80
  81 if (APPLE)
  82     # Notification Center is only available in > 10.8, which is Darwin v12
  83     if (CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  84         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
  85         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
  86     endif()
  87 endif()
  88
  89 # Always embed on Windows, OSX or for a static build; never embed when enabling KDE integration
  90 set(EMBED_DEFAULT OFF)
  91 if (STATIC OR WIN32 OR APPLE)
  92     set(EMBED_DEFAULT ON)
  93 endif()
  94 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
  95                                    "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
  96 if (NOT EMBED_DEFAULT)
  97     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
  98 endif()
  99
 100 # The following options are not for end-user consumption, so don't list them in the feature summary
 101 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
 102
 103 # Handle with care
 104 set(QT_PATH "" CACHE PATH "Path to a Qt4 installation to use instead of the system Qt (e.g. for static builds)")
 105
 106 # Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
 107 cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
 108
 109 # For static builds, arbitrary extra libs might need to be linked
 110 # Define a comma-separated list here
 111 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 112 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 113 if (LINK_EXTRA)
 114     string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 115     link_libraries(${LINK_EXTRA})
 116 endif()
 117
 118
 119 # Setup CMake
 120 #####################################################################
 121
 122 if (USE_QT5 AND WITH_KDE)
 123     cmake_minimum_required(VERSION 2.8.12)
 124 else()
 125     cmake_minimum_required(VERSION 2.8.9)
 126 endif()
 127
 128 # Setting COMPILE_DEFINITIONS_<CONFIG> is deprecated since CMake 3.0 in favor of generator expressions.
 129 # These have existed since CMake 2.8.10; until we depend on that, we have to explicitly enable the old policy.
 130 if (CMAKE_MAJOR_VERSION GREATER 2)
 131     cmake_policy(SET CMP0043 OLD)
 132 endif()
 133
 134 # Honor visibility settings for all target types
 135 if (CMAKE_VERSION VERSION_GREATER 3.3)
 136     cmake_policy(SET CMP0063 NEW)
 137 endif()
 138
 139
 140 # Simplify later checks
 141 #####################################################################
 142
 143 if (WANT_MONO OR WANT_QTCLIENT)
 144     set(BUILD_GUI true)
 145 endif()
 146 if (WANT_MONO OR WANT_CORE)
 147     set(BUILD_CORE true)
 148 endif()
 149
 150
 151 # Set up Qt
 152 #####################################################################
 153
 154 if (USE_QT5)
 155     message(STATUS "Building for Qt5...")
 156     set(QT_MIN_VERSION "5.2.0")
 157     add_definitions(-DHAVE_QT5)
 158 else()
 159     message(STATUS "Building for Qt4...")
 160     set(QT_MIN_VERSION "4.8.0")
 161
 162     # Select a Qt installation here, if you don't want to use system Qt
 163     if(QT_PATH)
 164         # FindQt4 will look for the qmake binary in $PATH, so we just prepend QT_PATH
 165         set(ENV{PATH} ${QT_PATH}/bin:$ENV{PATH})
 166     endif()
 167 endif()
 168
 169
 170 # Find package dependencies
 171 #
 172 # Note that you can forcefully disable optional packages
 173 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 174 #####################################################################
 175
 176 if (USE_QT5)
 177     find_package(Qt5Core ${QT_MIN_VERSION} QUIET)
 178     set_package_properties(Qt5Core PROPERTIES TYPE REQUIRED
 179         URL "http://qt.digia.com"
 180         DESCRIPTION "contains core functionality for Qt"
 181     )
 182     # find_package without REQUIRED won't check for the version properly; also, older Qt5 versions
 183     # used Qt5Core_VERSION_STRING... let's just make sure here that we bail out here if our Qt5 is not new enough.
 184     if (NOT Qt5Core_VERSION OR Qt5Core_VERSION VERSION_LESS ${QT_MIN_VERSION})
 185         message(FATAL_ERROR "Could NOT find Qt5 >= version ${QT_MIN_VERSION}!")
 186     endif()
 187
 188     find_package(Qt5Network QUIET)
 189     set_package_properties(Qt5Network PROPERTIES TYPE REQUIRED
 190         DESCRIPTION "the network module for Qt5"
 191     )
 192
 193     if (BUILD_GUI)
 194         find_package(Qt5Gui QUIET)
 195         set_package_properties(Qt5Gui PROPERTIES TYPE REQUIRED
 196             DESCRIPTION "the GUI module for Qt5"
 197         )
 198         find_package(Qt5Widgets QUIET)
 199         set_package_properties(Qt5Widgets PROPERTIES TYPE REQUIRED
 200             DESCRIPTION "the widgets module for Qt5"
 201         )
 202
 203         find_package(Qt5DBus QUIET)
 204         set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 205             URL "http://qt.digia.com"
 206             DESCRIPTION "D-Bus support for Qt5"
 207             PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 208         )
 209         if (Qt5DBus_FOUND)
 210             find_package(dbusmenu-qt5 QUIET CONFIG)
 211             set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 212                 URL "https://launchpad.net/libdbusmenu-qt"
 213                 DESCRIPTION "a library implementing the DBusMenu specification"
 214                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 215             )
 216         endif()
 217
 218         find_package(Qt5Multimedia QUIET)
 219         set_package_properties(Qt5Multimedia PROPERTIES TYPE RECOMMENDED
 220             URL "http://qt.digia.com"
 221             DESCRIPTION "Multimedia support for Qt5"
 222             PURPOSE     "Required for audio notifications"
 223         )
 224
 225         if (NOT Qt5Multimedia_FOUND)
 226             find_package(Phonon4Qt5 QUIET)
 227             set_package_properties(Phonon4Qt5 PROPERTIES TYPE RECOMMENDED
 228                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 229                 DESCRIPTION "a multimedia abstraction library"
 230                 PURPOSE     "Required for audio notifications"
 231             )
 232         endif()
 233
 234         find_package(LibsnoreQt5 0.7.0 QUIET)
 235         set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
 236             URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 237             DESCRIPTION "a cross-platform notification framework"
 238             PURPOSE     "Enable support for the snorenotify framework"
 239         )
 240         if(LibsnoreQt5_FOUND)
 241             find_package(LibsnoreSettingsQt5)
 242             set_package_properties(LibsnoreSettingsQt5 PROPERTIES TYPE REQUIRED
 243                 URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 244                 DESCRIPTION "a cross-platform notification framework"
 245                 PURPOSE     "Enable support for the snorenotify framework"
 246             )
 247         endif()
 248
 249
 250         if (WITH_WEBKIT)
 251             find_package(Qt5WebKit QUIET)
 252             set_package_properties(Qt5WebKit PROPERTIES TYPE RECOMMENDED
 253                 URL "http://qt.digia.com"
 254                 DESCRIPTION "a WebKit implementation for Qt"
 255                 PURPOSE     "Needed for displaying previews for URLs in chat"
 256             )
 257             if (Qt5WebKit_FOUND)
 258                 find_package(Qt5WebKitWidgets QUIET)
 259                 set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE RECOMMENDED
 260                     URL "http://qt.digia.com"
 261                     DESCRIPTION "widgets for Qt's WebKit implementation"
 262                     PURPOSE     "Needed for displaying previews for URLs in chat"
 263                 )
 264             endif()
 265         endif()
 266
 267         if (WITH_WEBKIT AND Qt5WebKitWidgets_FOUND)
 268             set(HAVE_WEBKIT true)
 269         endif()
 270         add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" HAVE_WEBKIT "Support showing previews for URLs in chat")
 271
 272         # KDE Frameworks
 273         ################
 274
 275         if (WITH_KDE)
 276             set(ecm_find_type "REQUIRED")
 277         else()
 278             # Even with KDE integration disabled, we optionally use tier1 frameworks if we find them
 279             set(ecm_find_type "RECOMMENDED")
 280         endif()
 281
 282         # extra-cmake-modules
 283         find_package(ECM NO_MODULE QUIET)
 284         set_package_properties(ECM PROPERTIES TYPE ${ecm_find_type}
 285             URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules"
 286             DESCRIPTION "extra modules for CMake, maintained by the KDE project"
 287             PURPOSE     "Required to find KDE Frameworks components"
 288         )
 289
 290         if (ECM_FOUND)
 291             list(APPEND CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
 292             if (WITH_KDE)
 293                 find_package(KF5 COMPONENTS ConfigWidgets CoreAddons Notifications NotifyConfig TextWidgets WidgetsAddons XmlGui QUIET)
 294                 set_package_properties(KF5 PROPERTIES TYPE REQUIRED
 295                     URL "http://www.kde.org"
 296                     DESCRIPTION "KDE Frameworks"
 297                     PURPOSE     "Required for integration into the Plasma desktop"
 298                 )
 299             else(WITH_KDE)
 300                 find_package(KF5Sonnet QUIET)
 301                 set_package_properties(KF5Sonnet PROPERTIES TYPE RECOMMENDED
 302                     URL "http://api.kde.org/frameworks-api/frameworks5-apidocs/sonnet/html"
 303                     DESCRIPTION "framework for providing spell-checking capabilities"
 304                     PURPOSE "Enables spell-checking support in input widgets"
 305                 )
 306             endif(WITH_KDE)
 307         endif(ECM_FOUND)
 308
 309     endif(BUILD_GUI)
 310
 311     if (BUILD_CORE)
 312         find_package(Qt5Script QUIET)
 313         set_package_properties(Qt5Script PROPERTIES TYPE REQUIRED
 314             DESCRIPTION "provides scripting support for Qt5"
 315         )
 316         find_package(Qt5Sql QUIET)
 317         set_package_properties(Qt5Sql PROPERTIES TYPE REQUIRED
 318             DESCRIPTION "the database support module for Qt5"
 319         )
 320
 321         find_package(QCA2-QT5)
 322         set_package_properties(QCA2-QT5 PROPERTIES TYPE RECOMMENDED
 323             URL "https://projects.kde.org/projects/kdesupport/qca"
 324             DESCRIPTION "Qt Cryptographic Architecture"
 325             PURPOSE "Required for encryption support"
 326         )
 327
 328     endif(BUILD_CORE)
 329
 330     find_package(Qt5LinguistTools QUIET)
 331     set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 332                            DESCRIPTION "contains tools for handling translation files"
 333                            PURPOSE "Required for having translations"
 334     )
 335
 336     # Some Qt5 versions do not define a target for lconvert, so we need to find it ourselves
 337     if (Qt5LinguistTools_FOUND)
 338         if (NOT TARGET Qt5::lconvert AND TARGET Qt5::lrelease)
 339             get_target_property(_lrelease_location Qt5::lrelease LOCATION)
 340             get_filename_component(_lrelease_path ${_lrelease_location} PATH)
 341             find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 342         elseif(TARGET Qt5::lconvert AND NOT Qt5_LCONVERT_EXECUTABLE)
 343             # Newer Qt5 versions define the target, but not the Qt5_LCONVERT_EXECUTABLE variable for some reason
 344             get_target_property(QT_LCONVERT_EXECUTABLE Qt5::lconvert LOCATION)
 345         endif()
 346
 347         # Compatibility with the Qt4 variables
 348         set(QT_LRELEASE_EXECUTABLE ${Qt5_LRELEASE_EXECUTABLE})
 349         set(QT_LUPDATE_EXECUTABLE ${Qt5_LUPDATE_EXECUTABLE})
 350         if (Qt5_LCONVERT_EXECUTABLE)
 351             set(QT_LCONVERT_EXECUTABLE ${Qt5_LCONVERT_EXECUTABLE})
 352         endif()
 353     endif()
 354
 355 else(USE_QT5)
 356     find_package(Qt4 ${QT_MIN_VERSION} QUIET REQUIRED)
 357
 358     if (BUILD_GUI)
 359         add_feature_info("QtDBus module" QT_QTDBUS_FOUND "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments")
 360         if (QT_QTDBUS_FOUND)
 361             find_package(dbusmenu-qt QUIET CONFIG)
 362             set_package_properties(dbusmenu-qt PROPERTIES TYPE RECOMMENDED
 363                 URL "https://launchpad.net/libdbusmenu-qt"
 364                 DESCRIPTION "a library implementing the DBusMenu specification"
 365                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 366             )
 367         endif()
 368
 369         if (WITH_WEBKIT AND QT_QTWEBKIT_FOUND)
 370             set(HAVE_WEBKIT true)
 371         endif()
 372         add_feature_info("WITH_WEBKIT and QtWebKit module" HAVE_WEBKIT "Support showing previews for URLs in chat")
 373
 374         if (WITH_KDE)
 375             # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 376             set(_cflags ${CMAKE_C_FLAGS})
 377             find_package(KDE4 4.4 QUIET)
 378             set_package_properties(KDE4 PROPERTIES TYPE REQUIRED
 379                 URL "http://www.kde.org"
 380                 DESCRIPTION "a world-class desktop environment"
 381                 PURPOSE "Enables various bits for improving integration with KDE"
 382             )
 383             set(CMAKE_C_FLAGS ${_cflags})
 384
 385         else(WITH_KDE)
 386             find_package(Phonon QUIET)
 387             set_package_properties(Phonon PROPERTIES TYPE RECOMMENDED
 388                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 389                 DESCRIPTION "a multimedia abstraction library"
 390                 PURPOSE     "Required for audio notifications"
 391             )
 392         endif(WITH_KDE)
 393
 394         find_package(IndicateQt QUIET)
 395         set_package_properties(IndicateQt PROPERTIES TYPE OPTIONAL
 396             URL "https://launchpad.net/libindicate-qt/"
 397             DESCRIPTION "a library to raise flags on DBus for other components of the desktop to pick up and visualize"
 398             PURPOSE     "Provides integration into the Ayatana notification system used by e.g. Ubuntu"
 399         )
 400
 401     endif(BUILD_GUI)
 402
 403     if (BUILD_CORE)
 404
 405         find_package(QCA2 QUIET)
 406         set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 407             URL "https://projects.kde.org/projects/kdesupport/qca"
 408             DESCRIPTION "Qt Cryptographic Architecture"
 409             PURPOSE     "Required for encryption support"
 410         )
 411
 412
 413     endif()
 414
 415     # Qt4 does not consider lconvert relevant, so they don't support finding it...
 416     # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 417     if (QT_LRELEASE_EXECUTABLE)
 418         get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 419         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 420     endif()
 421 endif()
 422
 423
 424 # Non-Qt-based packages
 425
 426 # zlib for compression, however we can always fall back to miniz
 427 find_package(ZLIB QUIET)
 428 set_package_properties(ZLIB PROPERTIES TYPE RECOMMENDED
 429     URL "http://www.zlib.net"
 430     DESCRIPTION "a popular compression library"
 431     PURPOSE     "Use the most common library for protocol compression, instead of the bundled miniz implementation"
 432 )
 433
 434
 435 if (NOT WIN32)
 436     # Execinfo is needed for generating backtraces
 437     find_package(ExecInfo QUIET)
 438     set_package_properties(ExecInfo PROPERTIES TYPE OPTIONAL
 439         DESCRIPTION "a library for inspecting backtraces"
 440         PURPOSE "Used for generating backtraces in case of a crash"
 441     )
 442 endif()
 443
 444 # Check for SSL support in Qt
 445 # As there's no easy way to get Qt's configuration in particular for Qt5, let's just compile
 446 # a small test program checking the defines. This works for both Qt4 and Qt5.
 447 cmake_push_check_state(RESET)
 448 set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES} ${Qt5Core_INCLUDE_DIRS})
 449 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Core_EXECUTABLE_COMPILE_FLAGS}")
 450
 451 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 452     set(CMAKE_REQUIRED_FLAGS "-fPIC -DQT_NO_VERSION_TAGGING")
 453 endif()
 454
 455 check_cxx_source_compiles("
 456     #include \"qglobal.h\"
 457     #if defined QT_NO_SSL
 458     #  error \"No SSL support\"
 459     #endif
 460     int main() {}"
 461     HAVE_SSL)
 462 cmake_pop_check_state()
 463
 464 # Additional compile settings
 465 #####################################################################
 466
 467 # This sets -fPIC and friends if required by the installed Qt5 library
 468 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 469     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 470 endif()
 471
 472 # Needed to compile with mingw without kde
 473 if (MINGW AND NOT KDE4_FOUND)
 474     add_definitions(-D_WIN32_WINNT=0x0500)
 475     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 476     # workaround for bug in mingw gcc 4.0
 477     add_definitions(-U__STRICT_ANSI__)
 478 endif()
 479
 480 # Sanitize compiler flags - old versions of KDE set -ansi, which breaks -std=c++11
 481 if (CMAKE_COMPILER_IS_GNUCXX)
 482     string(REPLACE "-ansi" "" CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS})
 483 endif()
 484
 485
 486 # Setup KDE / KDE Frameworks
 487 #####################################################################
 488
 489 # We want to do this up here, so we have the necessary variables and defines set before
 490 # compiling anything
 491
 492 if (KDE4_FOUND)
 493     # We always use external icons for KDE4 support, since we use its iconloader rather than Qt's
 494     set(EMBED_DATA OFF)
 495
 496     # Better have the compile flags global, even for the core, to avoid problems with linking the mono client
 497     add_definitions(-DHAVE_KDE -DHAVE_KDE4 ${KDE4_DEFINITIONS})
 498     set(WITH_KDE4 TRUE)
 499 endif()
 500
 501 if (USE_QT5 AND WITH_KDE)
 502     # If KDE Frameworks are present, they're most probably providing Qt5 integration including icon loading
 503     set(EMBED_DATA OFF)
 504
 505     include(KDEInstallDirs)
 506     include(KDECompilerSettings)
 507     include(KDECMakeSettings)
 508
 509     add_definitions(-DHAVE_KDE -DHAVE_KF5)
 510     set(WITH_KF5 TRUE)
 511 endif()
 512
 513 # This needs to come after setting up KDE integration, so we can use KDE-specific paths
 514 include(QuasselInstallDirs)
 515
 516 # Various config-dependent checks and settings
 517 #####################################################################
 518
 519 if (NOT ZLIB_FOUND)
 520     message(STATUS "zlib NOT found, using bundled miniz for compression")
 521     if (${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 522         message(STATUS "WARNING: This may be slow on 32 bit systems!")
 523     endif()
 524 endif()
 525
 526 if (HAVE_SSL)
 527     add_definitions(-DHAVE_SSL)
 528 endif()
 529 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 530
 531 # Check for syslog support
 532 if (NOT WIN32)
 533     check_include_file(syslog.h HAVE_SYSLOG)
 534     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 535 endif()
 536
 537 add_feature_info("Qt Linguist Tools" QT_LCONVERT_EXECUTABLE "Translation support for Quassel")
 538
 539 if (EMBED_DATA)
 540     message(STATUS "Embedding data files into the binary")
 541 else()
 542     message(STATUS "Installing data files separately")
 543 endif()
 544
 545 if (INDICATEQT_FOUND)
 546     add_definitions(-DXDG_APPS_INSTALL_DIR=${CMAKE_INSTALL_APPDIR})
 547 endif()
 548
 549 if (NOT WIN32)
 550     check_function_exists(umask HAVE_UMASK)
 551     if(HAVE_UMASK)
 552         add_definitions(-DHAVE_UMASK)
 553     endif(HAVE_UMASK)
 554 endif()
 555
 556
 557 # Windows-specific stuff
 558 #####################################################################
 559
 560 if (WIN32)
 561     link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 562     if (MSVC)
 563         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /DNOMINMAX")
 564         set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 565         set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 566         set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 567         link_libraries(Version dwmapi shlwapi)
 568         if (USE_QT5)
 569             set(QT_QTMAIN_LIBRARY Qt5::WinMain)
 570         endif()
 571     endif()
 572     if(HAVE_SSL AND STATIC)
 573         find_package(OpenSSL REQUIRED)
 574         link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 575     endif()
 576 endif()
 577
 578
 579 # Static builds (very much non-portable, so don't use -DSTATIC
 580 # unless you know what you do!)
 581 #####################################################################
 582
 583 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 584     set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 585     link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 586     if (HAVE_SSL)
 587         set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 588     endif()
 589 endif()
 590
 591
 592 # Generate version information from Git
 593 #####################################################################
 594
 595 include(GetGitRevisionDescription)
 596 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 597 git_describe(GIT_DESCRIBE --long)
 598
 599 # If in a Git repo we can get the commit-date from a git command
 600 if (GIT_HEAD)
 601     execute_process(
 602         COMMAND git show -s --format=%ct
 603         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 604         OUTPUT_VARIABLE GIT_COMMIT_DATE
 605         OUTPUT_STRIP_TRAILING_WHITESPACE
 606     )
 607 endif()
 608
 609 # If not in a Git repo try to read GIT_HEAD and GIT_DESCRIBE from
 610 # enviroment
 611 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 612   if (DEFINED ENV{GIT_HEAD})
 613       set(GIT_HEAD $ENV{GIT_HEAD})
 614   endif ()
 615   if (DEFINED ENV{GIT_DESCRIBE})
 616      set(GIT_DESCRIBE $ENV{GIT_DESCRIBE})
 617   endif()
 618 endif()
 619
 620 # Sanitize things if we're not in a Git repo
 621 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 622     set(GIT_HEAD "")
 623     set(GIT_DESCRIBE "")
 624     set(GIT_COMMIT_DATE 0)
 625 endif()
 626
 627 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 628
 629 # Prepare the build
 630 #####################################################################
 631
 632 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 633 set(COMMON_DEPS ${RC_WIN32})
 634 set(CORE_DEPS )
 635 set(CLIENT_DEPS )
 636
 637 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 638 add_subdirectory(data)
 639 add_subdirectory(icons)
 640 add_subdirectory(pics)
 641 add_subdirectory(po)
 642
 643
 644 # Set up and display feature summary
 645 #####################################################################
 646
 647 feature_summary(WHAT ALL
 648                 INCLUDE_QUIET_PACKAGES
 649                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 650 )
 651
 652 # Finally, compile the sources
 653 # We want this after displaying the feature summary to avoid ugly
 654 # CMake backtraces in case a required Qt5 module is missing
 655 #####################################################################
 656
 657 add_subdirectory(src)