CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 cmake_minimum_required(VERSION 2.8.9)
  10 project(QuasselIRC)
  11
  12
  13 # Versions
  14 set(QUASSEL_MAJOR  0)
  15 set(QUASSEL_MINOR 11)
  16 set(QUASSEL_PATCH  0)
  17 set(QUASSEL_VERSION_STRING "0.11-pre")
  18
  19
  20 # Tell CMake about or own modules
  21 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  22
  23 # General conveniences
  24 set(CMAKE_AUTOMOC ON)
  25 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  26
  27
  28 # Moar stuff
  29 include(CheckFunctionExists)
  30 include(CheckIncludeFile)
  31
  32 include(QuasselCompileSettings)
  33 include(QuasselMacros)
  34
  35 include(CMakeDependentOption)
  36
  37
  38 # Options and variables that can be set on the command line
  39 #####################################################################
  40
  41
  42 # First, choose a Qt version. We support USE_QT4 and USE_QT5; if neither is set, prefer Qt4 for now
  43 option(USE_QT5 "Enable support for Qt5 (disables KDE integration)" OFF)
  44 if (USE_QT4) # takes precedence
  45     set(USE_QT5 OFF)
  46 else()
  47     if (NOT USE_QT5)
  48         set(USE_QT4 ON)
  49     endif()
  50 endif()
  51
  52 # Select the binaries to build
  53 option(WANT_CORE     "Build the core (server) binary"           ON)
  54 option(WANT_QTCLIENT "Build the Qt4 GUI client binary"          ON)
  55 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  56
  57
  58 # Whether to enable KDE integration (pulls in kdelibs and friends as a dependency); requires Qt4 for now
  59 cmake_dependent_option(WITH_KDE      "KDE4 integration" OFF "USE_QT4" OFF)
  60
  61 # Some options don't make sense with KDE
  62 cmake_dependent_option(WITH_PHONON   "Phonon support (for audio notifications)"           ON "NOT WITH_KDE" OFF)
  63 cmake_dependent_option(WITH_SNORE    "Snore notification support"                        OFF "NOT WITH_KDE" OFF)
  64 cmake_dependent_option(WITH_OXYGEN   "Install Oxygen icon set (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
  65
  66 # Misc features
  67 option(WITH_OPENSSL     "OpenSSL support (secure networking)"             ON)
  68 option(WITH_DBUS        "Use D-Bus for the tray icon (StatusNotifier)"    ON)
  69 option(WITH_WEBKIT      "WebKit support (for link previews)"              ON)
  70 option(WITH_CRYPT       "Encryption support (QCA)"                        ON)
  71 option(WITH_LIBINDICATE "Ayatana (libindicate) notification support"      ON)
  72 cmake_dependent_option(WITH_SYSLOG   "Support logging to syslog"          ON "NOT WIN32" OFF)
  73
  74 if (APPLE)
  75     # Notification Center is only available in > 10.8, which is Darwin v12
  76     if (CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
  77         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
  78     endif()
  79 endif()
  80
  81 # Always embed on Windows or for a static build; never embed when enabling KDE integration
  82 set(EMBED_DEFAULT OFF)
  83 if (STATIC OR WIN32)
  84     set(EMBED_DEFAULT ON)
  85 endif()
  86 cmake_dependent_option(EMBED_DATA "Embed icons and translations in the binaries instead of installing them" ${EMBED_DEFAULT}
  87                                    "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
  88
  89 cmake_dependent_option(DEPLOY      "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
  90
  91 # Handle with care
  92 set(QT_PATH "" CACHE PATH "Path to a Qt4 installation to use instead of the system Qt (e.g. for static builds)")
  93
  94
  95 # Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
  96 cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
  97
  98 # For static builds, arbitrary extra libs might need to be linked
  99 # Define a comma-separated list here
 100 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 101 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 102 if (LINK_EXTRA)
 103     string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 104     link_libraries(${LINK_EXTRA})
 105 endif()
 106
 107
 108 # Simplify later checks
 109 if (WANT_MONO OR WANT_QTCLIENT)
 110     set(BUILD_GUI true)
 111 endif()
 112 if (WANT_MONO OR WANT_CORE)
 113     set(BUILD_CORE true)
 114 endif()
 115
 116
 117 # Set up Qt
 118 #####################################################################
 119
 120
 121 if (USE_QT5)
 122     message(STATUS "Building with the Qt5 libraries...")
 123     set(QT_MIN_VERSION "5.2.0")
 124     add_definitions(-DHAVE_QT5)
 125 else()
 126     message(STATUS "Building with the Qt4 libraries...")
 127     if (BUILD_GUI)
 128         set(QT_MIN_VERSION "4.6.0")
 129     else()
 130         set(QT_MIN_VERSION "4.4.0")
 131     endif()
 132 endif()
 133
 134
 135 if (USE_QT5)
 136     find_package(Qt5Core ${QT_MIN_VERSION} REQUIRED)
 137     # We need QtWidgets
 138     set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} Widgets)
 139
 140     # Setup the i18n-related variables
 141     find_package(Qt5LinguistTools)
 142
 143 else()
 144     # Select a Qt installation here, if you don't want to use system Qt
 145     if(QT_PATH)
 146         # FindQt4 will look for the qmake binary in $PATH, so we just prepend the Qt dir
 147         set(ENV{PATH} ${QT}/bin:$ENV{PATH})
 148     endif()
 149
 150     # Now that we have the correct $PATH, lets find Qt!
 151     find_package(Qt4 ${QT_MIN_VERSION} REQUIRED)
 152 endif()
 153
 154
 155 # Neither Qt4 nor Qt5 consider lconvert relevant, so they don't support finding it...
 156 # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 157 if (QT_LRELEASE_EXECUTABLE)
 158     get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 159     if (USE_QT5)
 160         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 161     else()
 162         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 163     endif()
 164 endif()
 165
 166
 167 # Dependencies
 168 #####################################################################
 169
 170 # zlib for compression, however we can always fall back to miniz
 171 find_package(ZLIB)
 172 if(ZLIB_FOUND)
 173   message(STATUS "Using system zlib for compression")
 174   add_definitions(-DHAVE_ZLIB)
 175   include_directories(${ZLIB_INCLUDE_DIRS})
 176   set(COMMON_LIBRARIES ${COMMON_LIBRARIES} ${ZLIB_LIBRARIES})
 177 else()
 178   message(STATUS "zlib NOT found, using bundled miniz for compression")
 179   if(${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 180     message(STATUS "WARNING: This may be slow on 32 bit systems!")
 181   endif()
 182 endif()
 183
 184
 185 # Execinfo is needed for generating backtraces
 186 find_package(ExecInfo)
 187 if(EXECINFO_FOUND)
 188   add_definitions(-DHAVE_EXECINFO)
 189   include_directories(${EXECINFO_INCLUDES})
 190   link_libraries(${EXECINFO_LIBRARIES})
 191 endif(EXECINFO_FOUND)
 192
 193
 194 # PkgConfig isn't strictly required.
 195 # However, some optional deps might not be found if it's not present, so warn!
 196 find_package(PkgConfig)
 197 if(NOT PKG_CONFIG_FOUND)
 198   message(STATUS "WARNING: PkgConfig not available! Some dependencies for optional features might not be found.")
 199   message(STATUS "         Affected features might include encryption support, DBus menus and Ayatana notifications.")
 200 endif(NOT PKG_CONFIG_FOUND)
 201
 202
 203 # Setup OpenSSL
 204 # We don't link to or include OpenSSL ourselves, but use exclusively the Qt API.
 205 # Thus, we simply check if OpenSSL support is present in Qt's config and enable our
 206 # own SSL stuff in this case. Qt should care for adding what it needs itself.
 207 if(WITH_OPENSSL)
 208   if(QT_QCONFIG MATCHES "openssl")
 209     message(STATUS "Found OpenSSL support in Qt, enabling SSL")
 210     add_definitions(-DHAVE_SSL)
 211     set(HAVE_SSL true)
 212   else(QT_QCONFIG MATCHES "openssl")
 213     message(STATUS "No OpenSSL support found in Qt, disabling SSL")
 214     add_definitions(-DQT_NO_OPENSSL)
 215   endif(QT_QCONFIG MATCHES "openssl")
 216 else(WITH_OPENSSL)
 217   message(STATUS "Not enabling OpenSSL support")
 218 endif(WITH_OPENSSL)
 219
 220
 221 # Check for GUI specific stuff
 222 if(BUILD_GUI)
 223
 224   # Setup D-Bus support
 225   if(WITH_DBUS)
 226     if (USE_QT5)
 227       find_package(Qt5DBus ${QT_MIN_VERSION})
 228       find_package(Qt5DBusTools)
 229     endif()
 230
 231     if(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 232       message(STATUS "Found QtDBus, enabling D-Bus support")
 233       add_definitions(-DHAVE_DBUS)
 234       set(HAVE_DBUS true)
 235       set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} DBus)
 236
 237       # check if we have dbusmenu as well
 238       if (NOT USE_QT5)
 239         find_package(DBusMenuQt)
 240         if(DBUSMENUQT_FOUND)
 241           message(STATUS "Enabling support for exporting the tray menu via D-Bus")
 242           add_definitions(-DHAVE_DBUSMENU)
 243           include_directories(${DBUSMENUQT_INCLUDE_DIR})
 244           set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${DBUSMENUQT_LIBRARIES})
 245           set(CLIENT_COMPILE_FLAGS "${CLIENT_COMPILE_FLAGS} ${DBUSMENUQT_DEFINITIONS}")
 246         else(DBUSMENUQT_FOUND)
 247           message(STATUS "Disabling support for exporting the tray menu via D-Bus")
 248         endif(DBUSMENUQT_FOUND)
 249       endif()
 250
 251     else(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 252       message(STATUS "QtDBus not found, disabling D-Bus support")
 253     endif(QT_QTDBUS_FOUND OR (Qt5DBus_FOUND AND Qt5DBusTools_FOUND))
 254   else(WITH_DBUS)
 255     message(STATUS "Not enabling D-Bus support")
 256   endif(WITH_DBUS)
 257
 258   # Setup QtWebkit support
 259   if(WITH_WEBKIT)
 260     if (USE_QT5)
 261       find_package(Qt5Webkit ${QT_MIN_VERSION} QUIET)
 262     endif()
 263     if(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 264       message(STATUS "Found QtWebKit, enabling WebKit support")
 265       add_definitions(-DHAVE_WEBKIT)
 266       set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} Webkit XmlPatterns)
 267       set(HAVE_WEBKIT true)
 268     else(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 269       message(STATUS "QtWebkit not found, disabling Webkit support")
 270     endif(QT_QTWEBKIT_FOUND OR Qt5Webkit_FOUND)
 271   else(WITH_WEBKIT)
 272     message(STATUS "Not enabling Webkit support")
 273   endif(WITH_WEBKIT)
 274
 275   # Setup KDE4 support
 276   if(WITH_KDE AND NOT USE_QT5)
 277     # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 278     set(_cflags ${CMAKE_C_FLAGS})
 279     find_package(KDE4)
 280     if(KDE4_FOUND)
 281       message(STATUS "Enabling KDE4 integration")
 282       include_directories(${KDE4_INCLUDES})
 283       add_definitions(-DHAVE_KDE ${KDE4_DEFINITIONS})
 284       set(HAVE_KDE 1)
 285       set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${KDE4_KDECORE_LIBS} ${KDE4_KDEUI_LIBRARY} ${KDE4_SOLID_LIBS} ${KDE4_KNOTIFYCONFIG_LIBRARY})
 286       # We always use external icons for KDE4 support, since we use its iconloader rather than our own
 287       set(EMBED_DATA OFF)
 288       # Restore our old CFLAGS
 289       set(CMAKE_C_FLAGS ${_cflags})
 290     else(KDE4_FOUND)
 291       message(STATUS "KDE4 not found, disabling KDE integration")
 292     endif(KDE4_FOUND)
 293   else(WITH_KDE AND NOT USE_QT5)
 294     message(STATUS "Not enabling KDE4 integration")
 295   endif(WITH_KDE AND NOT USE_QT5)
 296
 297   # Setup Phonon support - we only need this if we don't have or want KDE4
 298   if(NOT HAVE_KDE)
 299     if(WITH_PHONON)
 300       if(USE_QT5)
 301         find_package(Qt5phonon)
 302         if(Qt5phonon_FOUND)
 303           message(STATUS "Enabling Phonon support")
 304           add_definitions(-DHAVE_PHONON)
 305           set(HAVE_PHONON true)
 306           set(CLIENT_QT_MODULES ${CLIENT_QT_MODULES} phonon)
 307         else(Qt5phonon_FOUND)
 308           message(STATUS "Phonon not found, disabling audio notifications")
 309         endif(Qt5phonon_FOUND)
 310       else(USE_QT5)
 311         find_package(Phonon)
 312         if(PHONON_FOUND)
 313           message(STATUS "Enabling Phonon support")
 314           add_definitions(-DHAVE_PHONON)
 315           include_directories(${PHONON_INCLUDES})
 316           set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${PHONON_LIBS})
 317           set(HAVE_PHONON true)
 318         else(PHONON_FOUND)
 319           message(STATUS "Phonon not found, disabling audio notifications")
 320         endif(PHONON_FOUND)
 321       endif(USE_QT5)
 322     else(WITH_PHONON)
 323       message(STATUS "Not enabling Phonon support")
 324     endif(WITH_PHONON)
 325
 326     find_package(Libsnore)
 327     if(LIBSNORE_FOUND)
 328         add_definitions(-DHAVE_LIBSNORE)
 329         set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${LIBSNORE_LIBRARIES})
 330         set(HAVE_SNORENOTIFY true)
 331     endif(LIBSNORE_FOUND)
 332   endif(NOT HAVE_KDE)
 333
 334   # Setup libindicate-qt support
 335   if(WITH_LIBINDICATE AND NOT USE_QT5)
 336     pkg_check_modules(INDICATEQT QUIET indicate-qt>=0.2.1)
 337     if(INDICATEQT_FOUND)
 338       message(STATUS "Enabling Ayatana notification support")
 339       set(HAVE_INDICATEQT true)
 340       add_definitions(-DHAVE_INDICATEQT)
 341       link_directories(${INDICATEQT_LIBRARY_DIRS})
 342       set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES} ${INDICATEQT_LIBRARIES})
 343     else(INDICATEQT_FOUND)
 344       message(STATUS "Disabling Ayatana notification support")
 345     endif(INDICATEQT_FOUND)
 346   else(WITH_LIBINDICATE AND NOT USE_QT5)
 347     message(STATUS "Not enabling Ayatana notification support")
 348     # We don't want to link against it even if another package has found it
 349     set(INDICATEQT_LIBRARIES "")
 350   endif(WITH_LIBINDICATE AND NOT USE_QT5)
 351
 352   # Setup OS X notification center support
 353   if(WITH_NOTIFICATION_CENTER AND APPLE)
 354     set(HAVE_NOTIFICATION_CENTER true)
 355     add_definitions(-DHAVE_NOTIFICATION_CENTER)
 356     set(CLIENT_LIBRARIES ${CLIENT_LIBRARIES}
 357       /System/Library/Frameworks/Foundation.framework
 358     )
 359   endif()
 360 endif(BUILD_GUI)
 361
 362 # Core-only deps
 363 if(BUILD_CORE)
 364
 365   # Setup encryption support
 366   if(WITH_CRYPT AND NOT USE_QT5)
 367     find_package(QCA2)
 368     if(QCA2_FOUND)
 369       message(STATUS "Enabling encryption support")
 370       add_definitions(-DHAVE_QCA2)
 371       set(LINK_QCA2 QCA2)
 372       set(HAVE_QCA2 true)
 373       set(MOC_DEFINES ${MOC_DEFINES} -DHAVE_QCA2)
 374     else(QCA2_FOUND)
 375       message(STATUS "Disabling encryption support")
 376     endif(QCA2_FOUND)
 377   else(WITH_CRYPT AND NOT USE_QT5)
 378     message(STATUS "Not enabling encryption support")
 379   endif(WITH_CRYPT AND NOT USE_QT5)
 380
 381   # Setup syslog support
 382   if(WITH_SYSLOG)
 383     check_include_file(syslog.h HAVE_SYSLOG_H)
 384     if(HAVE_SYSLOG_H)
 385       message(STATUS "Enabling syslog support")
 386       set(HAVE_SYSLOG true)
 387       add_definitions(-DHAVE_SYSLOG)
 388     else(HAVE_SYSLOG_H)
 389       message(STATUS "Disabling syslog support")
 390     endif(HAVE_SYSLOG_H)
 391   else(WITH_SYSLOG)
 392     message(STATUS "Not enabling syslog support")
 393   endif(WITH_SYSLOG)
 394
 395 endif(BUILD_CORE)
 396
 397
 398 # Various settings
 399 ##################
 400
 401 # needed to compile with mingw without kde
 402 if(MINGW AND NOT HAVE_KDE)
 403     add_definitions(-D_WIN32_WINNT=0x0500)
 404     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 405 # workaround for bug in mingw gcc 4.0
 406     add_definitions(-U__STRICT_ANSI__)
 407 endif(MINGW AND NOT HAVE_KDE)
 408
 409 # Now set up install locations; those are set by KDE if integration is enabled
 410 if(NOT HAVE_KDE)
 411   if(WIN32)
 412     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX} CACHE FILEPATH "Install path for binaries")
 413     set(DATA_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/apps CACHE FILEPATH "Install path for data files")
 414     set(ICON_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/icons CACHE FILEPATH "Global icon install path")
 415     set(XDG_APPS_INSTALL_DIR $ENV{APPDATA}/quassel-irc.org/share/applications CACHE FILEPATH "Install path for .desktop files")
 416   else(WIN32)
 417     set(BIN_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/bin CACHE FILEPATH "Install path for binaries")
 418     set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/apps CACHE FILEPATH "Install path for data files")
 419     set(ICON_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/icons CACHE FILEPATH "Global icon install path")
 420     set(XDG_APPS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/applications CACHE FILEPATH "Install path for .desktop files")
 421   endif(WIN32)
 422 endif(NOT HAVE_KDE)
 423
 424 if(EMBED_DATA)
 425   message(STATUS "Embedding data files into the binary")
 426 else(EMBED_DATA)
 427   message(STATUS "Installing data files separately")
 428 endif(EMBED_DATA)
 429
 430 # RPATH needs to be set correctly
 431 # Do this down here, since otherwise KDE wants to handle it itself, and fails
 432 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH 1)
 433 set(CMAKE_BUILD_WITH_INSTALL_RPATH 1)
 434
 435 # Set global buildflags
 436 # This is very much non-portable, so don't use -DSTATIC until you know what
 437 # you do.
 438 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 439   set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 440   link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 441   if(HAVE_SSL)
 442     set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 443   endif(HAVE_SSL)
 444 endif(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 445
 446 if(WIN32)
 447   link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 448   if(MSVC)
 449     set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 450     set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 451     set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 452     link_libraries(Version dwmapi shlwapi)
 453   endif(MSVC)
 454   if(HAVE_SSL AND STATIC)
 455      find_package(OpenSSL REQUIRED)
 456      link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 457   endif(HAVE_SSL AND STATIC)
 458 endif(WIN32)
 459
 460 if(HAVE_INDICATEQT)
 461   add_definitions(-DXDG_APPS_INSTALL_DIR=${XDG_APPS_INSTALL_DIR})
 462 endif(HAVE_INDICATEQT)
 463
 464 if(NOT WIN32)
 465   check_function_exists(umask HAVE_UMASK)
 466   if(HAVE_UMASK)
 467     add_definitions(-DHAVE_UMASK)
 468   endif(HAVE_UMASK)
 469 endif(NOT WIN32)
 470
 471 # Generate version information from Git
 472 include(GetGitRevisionDescription)
 473 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 474 git_describe(GIT_DESCRIBE --long)
 475
 476 # Sanitize things if we're not in a Git repo
 477 if(NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 478     set(GIT_HEAD "")
 479     set(GIT_DESCRIBE "")
 480 endif()
 481
 482 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 483
 484 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 485 set(COMMON_DEPS ${RC_WIN32})
 486 set(CORE_DEPS )
 487 set(CLIENT_DEPS )
 488
 489 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 490 add_subdirectory(data)
 491 add_subdirectory(icons)
 492 add_subdirectory(pics)
 493 add_subdirectory(po)
 494 add_subdirectory(src)