CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 cmake_minimum_required(VERSION 3.5)
  10
  11 # Tell CMake about or own modules
  12 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  13
  14 # Versions
  15 set(QUASSEL_MAJOR  0)
  16 set(QUASSEL_MINOR 13)
  17 set(QUASSEL_PATCH 50)
  18 set(QUASSEL_VERSION_STRING "0.14-pre")
  19
  20 # Output CMake and Quassel versions as well as build type for debug reasons
  21 message(STATUS "Building Quassel ${QUASSEL_VERSION_STRING}...")
  22 message(STATUS "Using CMake ${CMAKE_VERSION}")
  23
  24 # Set up build type rather early
  25 include(BuildType)
  26
  27 # Support ccache if found
  28 # This should happen before calling project(), so compiler settings are validated.
  29 option(USE_CCACHE "Enable support for ccache if available" ON)
  30 if (USE_CCACHE)
  31     message(STATUS "Checking for ccache")
  32     find_program(CCACHE_PROGRAM ccache)
  33     if (CCACHE_PROGRAM)
  34         set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_PROGRAM}")
  35         message(STATUS "Checking for ccache - enabled")
  36     else()
  37         message(STATUS "Checking for ccache - not found")
  38     endif()
  39 endif()
  40
  41 # Set up project
  42 project(Quassel CXX)
  43
  44 # General conveniences
  45 set(CMAKE_AUTOMOC ON)
  46 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  47
  48 # Include various CMake modules...
  49 include(CMakePushCheckState)
  50 include(CheckFunctionExists)
  51 include(CheckIncludeFileCXX)
  52 include(CheckCXXSourceCompiles)
  53 include(CMakeDependentOption)
  54 include(FeatureSummary)
  55
  56 # ... and our own
  57 include(QuasselCompileSettings)
  58 include(QuasselMacros)
  59
  60 # Options and variables that can be set on the command line
  61 #####################################################################
  62
  63 # Select the binaries to build
  64 option(WANT_CORE     "Build the core (server) binary"           ON)
  65 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  66 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  67 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  68 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  69 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  70
  71 # Whether to enable integration with higher-tier KDE frameworks that require runtime support.
  72 # We still optionally make use of certain Tier 1 frameworks even if WITH_KDE is disabled.
  73 option(WITH_KDE "Integration with the KDE Frameworks runtime environment")
  74 add_feature_info(WITH_KDE WITH_KDE "Integrate with the KDE Frameworks runtime environment")
  75
  76 # Icon theme support. By default, install the Breeze icon theme (may be disabled if a system installation is present)
  77 option(WITH_BUNDLED_ICONS "Install required icons from the Breeze icon theme" ON)
  78 add_feature_info(WITH_BUNDLED_ICONS WITH_BUNDLED_ICONS "Install required icons from the Breeze icon theme")
  79
  80 option(WITH_OXYGEN_ICONS "Support the Oxygen icon theme (KDE4)" OFF)
  81 add_feature_info(WITH_OXYGEN_ICONS WITH_OXYGEN_ICONS "Support the Oxygen icon theme (KDE4)")
  82
  83 if (WITH_BUNDLED_ICONS)
  84     add_definitions(-DWITH_BUNDLED_ICONS)
  85 endif()
  86 if (WITH_OXYGEN_ICONS)
  87     add_definitions(-DWITH_OXYGEN_ICONS)
  88 endif()
  89
  90 # For this, the feature info is added after we know if QtWebkit is installed
  91 option(WITH_WEBKIT "WebKit support (for link previews) (legacy)" OFF)
  92
  93 # For this, the feature info is added after we know if QtWebEngine is installed
  94 option(WITH_WEBENGINE "WebEngine support (for link previews)" ON)
  95
  96 if (APPLE)
  97     # Notification Center is only available in > 10.8, which is Darwin v12
  98     if (NOT CMAKE_SYSTEM_VERSION VERSION_LESS 12)
  99         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
 100         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
 101     endif()
 102     find_library(CARBON_LIBRARY Carbon)
 103     mark_as_advanced(CARBON_LIBRARY)
 104     link_libraries(${CARBON_LIBRARY})
 105 endif()
 106
 107 # Always embed on Windows or OSX; never embed when enabling KDE integration
 108 set(EMBED_DEFAULT OFF)
 109 if (WIN32 OR APPLE)
 110     set(EMBED_DEFAULT ON)
 111 endif()
 112 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
 113                                    "NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
 114 if (NOT EMBED_DEFAULT)
 115     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
 116 endif()
 117
 118 # The following options are not for end-user consumption, so don't list them in the feature summary
 119 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
 120
 121
 122 # List of authenticators and the cmake flags to build them
 123 # (currently that's just LDAP, but more can be added here).
 124 ####################################################################
 125 option(WITH_LDAP "Enable LDAP authentication support if present on system" ON)
 126
 127 # Setup CMake
 128 #####################################################################
 129
 130 # Setting COMPILE_DEFINITIONS_<CONFIG> is deprecated since CMake 3.0 in favor of generator expressions.
 131 # These have existed since CMake 2.8.10; until we depend on that, we have to explicitly enable the old policy.
 132 if (POLICY CMP0043)
 133     cmake_policy(SET CMP0043 OLD)
 134 endif()
 135
 136 # Honor visibility settings for all target types
 137 if (POLICY CMP0063)
 138     cmake_policy(SET CMP0063 NEW)
 139 endif()
 140
 141 # Don't automoc generated files
 142 if (POLICY CMP0071)
 143     cmake_policy(SET CMP0071 OLD)
 144 endif()
 145
 146
 147 # Simplify later checks
 148 #####################################################################
 149
 150 if (WANT_MONO OR WANT_QTCLIENT)
 151     set(BUILD_GUI true)
 152 endif()
 153 if (WANT_MONO OR WANT_CORE)
 154     set(BUILD_CORE true)
 155 endif()
 156
 157
 158 # Set up Qt
 159 #####################################################################
 160
 161 # Find package dependencies
 162 #
 163 # Note that you can forcefully disable optional packages
 164 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 165 #####################################################################
 166
 167 set(QT_MIN_VERSION "5.5.0")
 168 add_definitions(-DHAVE_QT5)
 169
 170 find_package(Qt5Core ${QT_MIN_VERSION} QUIET)
 171 set_package_properties(Qt5Core PROPERTIES TYPE REQUIRED
 172     URL "https://www.qt.io/"
 173     DESCRIPTION "contains core functionality for Qt"
 174 )
 175
 176 # find_package without REQUIRED won't check for the version properly; also, older Qt5 versions
 177 # used Qt5Core_VERSION_STRING... let's just make sure here that we bail out here if our Qt5 is not new enough.
 178 if (NOT Qt5Core_VERSION OR Qt5Core_VERSION VERSION_LESS ${QT_MIN_VERSION})
 179     message(FATAL_ERROR "Could NOT find Qt5 >= version ${QT_MIN_VERSION}!")
 180 endif()
 181
 182 find_package(Qt5Network QUIET)
 183 set_package_properties(Qt5Network PROPERTIES TYPE REQUIRED
 184     DESCRIPTION "the network module for Qt5"
 185 )
 186
 187 if (BUILD_GUI)
 188     find_package(Qt5Gui QUIET)
 189     set_package_properties(Qt5Gui PROPERTIES TYPE REQUIRED
 190         DESCRIPTION "the GUI module for Qt5"
 191     )
 192     find_package(Qt5Widgets QUIET)
 193     set_package_properties(Qt5Widgets PROPERTIES TYPE REQUIRED
 194         DESCRIPTION "the widgets module for Qt5"
 195     )
 196
 197     if (NOT WIN32)
 198         find_package(Qt5DBus QUIET)
 199         set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 200             URL "https://www.qt.io/"
 201             DESCRIPTION "D-Bus support for Qt5"
 202             PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 203         )
 204         if (Qt5DBus_FOUND)
 205             find_package(dbusmenu-qt5 QUIET CONFIG)
 206             set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 207                 URL "https://launchpad.net/libdbusmenu-qt"
 208                 DESCRIPTION "a library implementing the DBusMenu specification"
 209                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 210             )
 211         endif()
 212     endif()
 213
 214     find_package(Qt5Multimedia QUIET)
 215     set_package_properties(Qt5Multimedia PROPERTIES TYPE RECOMMENDED
 216         URL "https://www.qt.io/"
 217         DESCRIPTION "Multimedia support for Qt5"
 218         PURPOSE     "Required for audio notifications"
 219     )
 220
 221     find_package(LibsnoreQt5 0.7.0 QUIET)
 222     set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
 223         URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 224         DESCRIPTION "a cross-platform notification framework"
 225         PURPOSE     "Enable support for the snorenotify framework"
 226     )
 227     if(LibsnoreQt5_FOUND)
 228         find_package(LibsnoreSettingsQt5)
 229         set_package_properties(LibsnoreSettingsQt5 PROPERTIES TYPE REQUIRED
 230             URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 231             DESCRIPTION "a cross-platform notification framework"
 232             PURPOSE     "Enable support for the snorenotify framework"
 233         )
 234     endif()
 235
 236     if (WITH_WEBKIT)
 237         find_package(Qt5WebKit QUIET)
 238         set_package_properties(Qt5WebKit PROPERTIES TYPE RECOMMENDED
 239             URL "https://www.qt.io/"
 240             DESCRIPTION "a WebKit implementation for Qt"
 241             PURPOSE     "Needed for displaying previews for URLs in chat"
 242         )
 243         if (Qt5WebKit_FOUND)
 244             find_package(Qt5WebKitWidgets QUIET)
 245             set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE RECOMMENDED
 246                 URL "https://www.qt.io/"
 247                 DESCRIPTION "widgets for Qt's WebKit implementation"
 248                 PURPOSE     "Needed for displaying previews for URLs in chat"
 249             )
 250         endif()
 251     endif()
 252
 253     if (WITH_WEBKIT AND Qt5WebKitWidgets_FOUND)
 254         set(HAVE_WEBKIT true)
 255     endif()
 256     add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" HAVE_WEBKIT "Support showing previews for URLs in chat (legacy)")
 257
 258     if (WITH_WEBENGINE)
 259         find_package(Qt5WebEngine QUIET)
 260         set_package_properties(Qt5WebEngine PROPERTIES TYPE RECOMMENDED
 261             URL "https://www.qt.io/"
 262             DESCRIPTION "a WebEngine implementation for Qt"
 263             PURPOSE     "Needed for displaying previews for URLs in chat"
 264         )
 265         if (Qt5WebEngine_FOUND)
 266             find_package(Qt5WebEngineWidgets QUIET)
 267             set_package_properties(Qt5WebEngineWidgets PROPERTIES TYPE RECOMMENDED
 268                 URL "https://www.qt.io/"
 269                 DESCRIPTION "widgets for Qt's WebEngine implementation"
 270                 PURPOSE     "Needed for displaying previews for URLs in chat"
 271             )
 272         endif()
 273     endif()
 274
 275     if (WITH_WEBENGINE AND Qt5WebEngineWidgets_FOUND)
 276         set(HAVE_WEBENGINE true)
 277     endif()
 278     add_feature_info("WITH_WEBENGINE, QtWebEngine and QtWebEngineWidgets modules" HAVE_WEBENGINE "Support showing previews for URLs in chat")
 279
 280     # KDE Frameworks
 281     ################
 282
 283     if (WITH_KDE)
 284         set(ecm_find_type "REQUIRED")
 285     else()
 286         # Even with KDE integration disabled, we optionally use tier1 frameworks if we find them
 287         set(ecm_find_type "RECOMMENDED")
 288     endif()
 289
 290     # extra-cmake-modules
 291     find_package(ECM NO_MODULE QUIET)
 292     set_package_properties(ECM PROPERTIES TYPE ${ecm_find_type}
 293         URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules"
 294         DESCRIPTION "extra modules for CMake, maintained by the KDE project"
 295         PURPOSE     "Required to find KDE Frameworks components"
 296     )
 297
 298     if (ECM_FOUND)
 299         list(APPEND CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
 300         if (WITH_KDE)
 301             find_package(KF5 COMPONENTS ConfigWidgets CoreAddons Notifications NotifyConfig Sonnet TextWidgets WidgetsAddons XmlGui QUIET)
 302             set_package_properties(KF5 PROPERTIES TYPE REQUIRED
 303                 URL "http://www.kde.org"
 304                 DESCRIPTION "KDE Frameworks"
 305                 PURPOSE     "Required for integration into the Plasma desktop"
 306             )
 307         else()
 308             find_package(KF5Sonnet QUIET)
 309             set_package_properties(KF5Sonnet PROPERTIES TYPE RECOMMENDED
 310                 URL "http://api.kde.org/frameworks-api/frameworks5-apidocs/sonnet/html"
 311                 DESCRIPTION "framework for providing spell-checking capabilities"
 312                 PURPOSE "Enables spell-checking support in input widgets"
 313             )
 314         endif()
 315     endif()
 316
 317 endif()
 318
 319 if (BUILD_CORE)
 320     find_package(Qt5Script QUIET)
 321     set_package_properties(Qt5Script PROPERTIES TYPE REQUIRED
 322         DESCRIPTION "provides scripting support for Qt5"
 323     )
 324     find_package(Qt5Sql QUIET)
 325     set_package_properties(Qt5Sql PROPERTIES TYPE REQUIRED
 326         DESCRIPTION "the database support module for Qt5"
 327     )
 328
 329     find_package(Qca-qt5 2.0)
 330     set_package_properties(Qca-qt5 PROPERTIES TYPE RECOMMENDED
 331         URL "https://projects.kde.org/projects/kdesupport/qca"
 332         DESCRIPTION "Qt Cryptographic Architecture"
 333         PURPOSE "Required for encryption support"
 334     )
 335
 336 endif()
 337
 338 find_package(Qt5LinguistTools QUIET)
 339 set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 340     DESCRIPTION "contains tools for handling translation files"
 341     PURPOSE "Required for having translations"
 342 )
 343
 344 # Some Qt5 versions do not define a target for lconvert, so we need to find it ourselves
 345 if (Qt5LinguistTools_FOUND)
 346     if (NOT TARGET Qt5::lconvert AND TARGET Qt5::lrelease)
 347         get_target_property(_lrelease_location Qt5::lrelease LOCATION)
 348         get_filename_component(_lrelease_path ${_lrelease_location} PATH)
 349         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 350     elseif(TARGET Qt5::lconvert AND NOT Qt5_LCONVERT_EXECUTABLE)
 351         # Newer Qt5 versions define the target, but not the Qt5_LCONVERT_EXECUTABLE variable for some reason
 352         get_target_property(QT_LCONVERT_EXECUTABLE Qt5::lconvert LOCATION)
 353     endif()
 354
 355     # Compatibility with the Qt4 variables
 356     set(QT_LRELEASE_EXECUTABLE ${Qt5_LRELEASE_EXECUTABLE})
 357     set(QT_LUPDATE_EXECUTABLE ${Qt5_LUPDATE_EXECUTABLE})
 358     if (Qt5_LCONVERT_EXECUTABLE)
 359         set(QT_LCONVERT_EXECUTABLE ${Qt5_LCONVERT_EXECUTABLE})
 360     endif()
 361 endif()
 362
 363 # Non-Qt-based packages
 364
 365 find_package(ZLIB REQUIRED)
 366 set_package_properties(ZLIB PROPERTIES TYPE REQUIRED
 367     URL "http://www.zlib.net"
 368     DESCRIPTION "a popular compression library"
 369     PURPOSE     "Used for protocol compression"
 370 )
 371
 372 if (NOT WIN32)
 373     # Needed for generating backtraces
 374     find_package(Backtrace QUIET)
 375     set_package_properties(Backtrace PROPERTIES TYPE RECOMMENDED
 376         DESCRIPTION "a header (and possibly library) for inspecting backtraces"
 377         PURPOSE "Used for generating backtraces in case of a crash"
 378     )
 379 endif()
 380
 381 # Check for SSL support in Qt
 382 # As there's no easy way to get Qt's configuration in particular for Qt5, let's just compile
 383 # a small test program checking the defines. This works for both Qt4 and Qt5.
 384 cmake_push_check_state(RESET)
 385 set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES} ${Qt5Core_INCLUDE_DIRS})
 386 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Core_EXECUTABLE_COMPILE_FLAGS}")
 387
 388 if (Qt5_POSITION_INDEPENDENT_CODE)
 389     set(CMAKE_REQUIRED_FLAGS "-fPIC -DQT_NO_VERSION_TAGGING")
 390 endif()
 391
 392 check_cxx_source_compiles("
 393     #include \"qglobal.h\"
 394     #if defined QT_NO_SSL
 395     #  error \"No SSL support\"
 396     #endif
 397     int main() {}"
 398     HAVE_SSL)
 399 cmake_pop_check_state()
 400
 401 # Additional compile settings
 402 #####################################################################
 403
 404 # This sets -fPIC and friends if required by the installed Qt5 library
 405 if (Qt5_POSITION_INDEPENDENT_CODE)
 406     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 407     set(CMAKE_REQUIRED_FLAGS "-DQT_NO_VERSION_TAGGING")
 408 endif()
 409
 410 # Needed to compile with mingw without kde
 411 if (MINGW AND NOT WITH_KDE)
 412     add_definitions(-D_WIN32_WINNT=0x0500)
 413     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 414     # workaround for bug in mingw gcc 4.0
 415     add_definitions(-U__STRICT_ANSI__)
 416 endif()
 417
 418 # Sanitize compiler flags - old versions of KDE set -ansi, which breaks -std=c++11
 419 if (CMAKE_COMPILER_IS_GNUCXX)
 420     string(REPLACE "-ansi" "" CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS})
 421 endif()
 422
 423 # Setup LDAP Authentication support.
 424 #####################################################################
 425 if (WITH_LDAP)
 426     find_package(Ldap)
 427     if (LDAP_FOUND)
 428         message(STATUS "Enabling LDAP authentication support")
 429         set(HAVE_LDAP true)
 430         add_definitions(-DHAVE_LDAP)
 431     else()
 432         message(STATUS "Disabling LDAP authentication support")
 433     endif()
 434 else()
 435     message(STATUS "Not enabling LDAP authentication support")
 436 endif()
 437
 438 # Setup support for KDE Frameworks
 439 #####################################################################
 440
 441 # We want to do this up here, so we have the necessary variables and defines set before
 442 # compiling anything
 443
 444 if (WITH_KDE)
 445     # If KDE Frameworks are present, they're most probably providing Qt5 integration including icon loading
 446     set(EMBED_DATA OFF)
 447
 448     include(KDEInstallDirs)
 449     include(KDECompilerSettings)
 450     include(KDECMakeSettings)
 451
 452     kde_enable_exceptions()
 453     add_definitions(-DHAVE_KDE -DHAVE_KF5)
 454     set(WITH_KF5 TRUE)
 455 endif()
 456
 457 # This needs to come after setting up KDE integration, so we can use KDE-specific paths
 458 include(QuasselInstallDirs)
 459
 460 # Various config-dependent checks and settings
 461 #####################################################################
 462
 463 if (HAVE_SSL)
 464     add_definitions(-DHAVE_SSL)
 465 endif()
 466 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 467
 468 # Check for syslog support
 469 if (NOT WIN32)
 470     check_include_file_cxx(syslog.h HAVE_SYSLOG)
 471     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 472 endif()
 473
 474 add_feature_info("Qt Linguist Tools" QT_LCONVERT_EXECUTABLE "Translation support for Quassel")
 475
 476 if (EMBED_DATA)
 477     message(STATUS "Embedding data files into the binary")
 478 else()
 479     message(STATUS "Installing data files separately")
 480 endif()
 481
 482 if (NOT WIN32)
 483     check_function_exists(umask HAVE_UMASK)
 484     if(HAVE_UMASK)
 485         add_definitions(-DHAVE_UMASK)
 486     endif()
 487 endif()
 488
 489
 490 # Windows-specific stuff
 491 #####################################################################
 492
 493 if (WIN32)
 494     link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 495     if (MSVC)
 496         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /DNOMINMAX")
 497         set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 498         set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 499         set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 500         link_libraries(Version dwmapi shlwapi)
 501         set(QT_QTMAIN_LIBRARY Qt5::WinMain)
 502     endif()
 503 endif()
 504
 505
 506 # Generate version information from Git
 507 #####################################################################
 508
 509 include(GetGitRevisionDescription)
 510 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 511 git_describe(GIT_DESCRIBE --long)
 512
 513 # If in a Git repo we can get the commit-date from a git command
 514 if (GIT_HEAD)
 515     execute_process(
 516         COMMAND git -c log.showsignature=false show -s --format=%ct
 517         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 518         OUTPUT_VARIABLE GIT_COMMIT_DATE
 519         OUTPUT_STRIP_TRAILING_WHITESPACE
 520     )
 521 endif()
 522
 523 # If not in a Git repo try to read GIT_HEAD and GIT_DESCRIBE from
 524 # enviroment
 525 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 526   if (DEFINED ENV{GIT_HEAD})
 527       set(GIT_HEAD $ENV{GIT_HEAD})
 528   endif()
 529   if (DEFINED ENV{GIT_DESCRIBE})
 530      set(GIT_DESCRIBE $ENV{GIT_DESCRIBE})
 531   endif()
 532 endif()
 533
 534 # Sanitize things if we're not in a Git repo
 535 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 536     set(GIT_HEAD "")
 537     set(GIT_DESCRIBE "")
 538     set(GIT_COMMIT_DATE 0)
 539 endif()
 540
 541 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 542
 543 # Prepare the build
 544 #####################################################################
 545
 546 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 547 set(COMMON_DEPS ${RC_WIN32})
 548 set(CORE_DEPS )
 549 set(CLIENT_DEPS )
 550
 551 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 552 add_subdirectory(data)
 553 add_subdirectory(icons)
 554 add_subdirectory(pics)
 555 add_subdirectory(po)
 556
 557
 558 # Set up and display feature summary
 559 #####################################################################
 560
 561 feature_summary(WHAT ALL
 562                 INCLUDE_QUIET_PACKAGES
 563                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 564 )
 565
 566 # Finally, compile the sources
 567 # We want this after displaying the feature summary to avoid ugly
 568 # CMake backtraces in case a required Qt5 module is missing
 569 #####################################################################
 570
 571 add_subdirectory(src)