CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 project(QuasselIRC)
  10
  11 # Versions
  12 set(QUASSEL_MAJOR  0)
  13 set(QUASSEL_MINOR 13)
  14 set(QUASSEL_PATCH  0)
  15 set(QUASSEL_VERSION_STRING "0.13-pre")
  16
  17 # We want to know CMake's version for debug reasons
  18 message(STATUS "Using CMake ${CMAKE_VERSION}")
  19
  20 # Tell CMake about or own modules
  21 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  22
  23 # General conveniences
  24 set(CMAKE_AUTOMOC ON)
  25 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  26
  27 # Include various CMake modules...
  28 include(CMakePushCheckState)
  29 include(CheckFunctionExists)
  30 include(CheckIncludeFile)
  31 include(CheckCXXSourceCompiles)
  32 include(CMakeDependentOption)
  33 include(FeatureSummary)
  34
  35 # ... and our own stuff
  36 include(QuasselCompileSettings)
  37 include(QuasselMacros)
  38
  39
  40 # Options and variables that can be set on the command line
  41 #####################################################################
  42
  43 # First, choose a Qt version. We support USE_QT4 and USE_QT5; if neither is set, prefer Qt4 for now
  44 option(USE_QT5 "Enable support for Qt5 (disables KDE integration)" OFF)
  45 if (USE_QT4) # takes precedence
  46     set(USE_QT5 OFF)
  47 else()
  48     if (NOT USE_QT5)
  49         set(USE_QT4 ON)
  50     endif()
  51 endif()
  52
  53 # Select the binaries to build
  54 option(WANT_CORE     "Build the core (server) binary"           ON)
  55 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  56 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  57 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  58 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  59 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  60
  61 # Whether to enable KDE integration (work in progress for Qt5 / KDE Frameworks)
  62 # Note that when building with Qt5, WITH_KDE enables integration with higher-tier KDE frameworks that
  63 # require runtime support. We still optionally make use of certain Tier 1 frameworks even if WITH_KDE
  64 # is disabled.
  65 if (USE_QT4)
  66     option(WITH_KDE "KDE4 integration" OFF)
  67     add_feature_info(WITH_KDE WITH_KDE "Enable KDE4 integration")
  68 else()
  69     option(WITH_KDE "Integration with the KDE Frameworks runtime environment")
  70     add_feature_info(WITH_KDE WITH_KDE "Integrate with the KDE Frameworks runtime environment")
  71 endif()
  72
  73 cmake_dependent_option(WITH_OXYGEN "Install Oxygen icon set (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
  74 if (NOT WITH_KDE)
  75     add_feature_info(WITH_OXYGEN WITH_OXYGEN "Install Oxygen icon set")
  76 endif()
  77
  78 # For this, the feature info is added after we know if QtWebkit is installed
  79 option(WITH_WEBKIT "WebKit support (for link previews) (legacy)" ON)
  80
  81 # For this, the feature info is added after we know if QtWebEngine is installed
  82 option(WITH_WEBENGINE "WebEngine support (for link previews)" ON)
  83
  84 if (APPLE)
  85     # Notification Center is only available in > 10.8, which is Darwin v12
  86     if (NOT CMAKE_SYSTEM_VERSION VERSION_LESS 12)
  87         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
  88         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
  89     endif()
  90 endif()
  91
  92 # Always embed on Windows, OSX or for a static build; never embed when enabling KDE integration
  93 set(EMBED_DEFAULT OFF)
  94 if (STATIC OR WIN32 OR APPLE)
  95     set(EMBED_DEFAULT ON)
  96 endif()
  97 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
  98                                    "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
  99 if (NOT EMBED_DEFAULT)
 100     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
 101 endif()
 102
 103 # The following options are not for end-user consumption, so don't list them in the feature summary
 104 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
 105
 106 # Handle with care
 107 set(QT_PATH "" CACHE PATH "Path to a Qt4 installation to use instead of the system Qt (e.g. for static builds)")
 108
 109 # Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
 110 cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
 111
 112 # For static builds, arbitrary extra libs might need to be linked
 113 # Define a comma-separated list here
 114 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 115 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 116 if (LINK_EXTRA)
 117     string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 118     link_libraries(${LINK_EXTRA})
 119 endif()
 120
 121
 122 # Setup CMake
 123 #####################################################################
 124
 125 if (USE_QT5 AND WITH_KDE)
 126     cmake_minimum_required(VERSION 2.8.12)
 127 else()
 128     cmake_minimum_required(VERSION 2.8.9)
 129 endif()
 130
 131 # Setting COMPILE_DEFINITIONS_<CONFIG> is deprecated since CMake 3.0 in favor of generator expressions.
 132 # These have existed since CMake 2.8.10; until we depend on that, we have to explicitly enable the old policy.
 133 if (POLICY CMP0043)
 134     cmake_policy(SET CMP0043 OLD)
 135 endif()
 136
 137 # Honor visibility settings for all target types
 138 if (POLICY CMP0063)
 139     cmake_policy(SET CMP0063 NEW)
 140 endif()
 141
 142
 143 # Simplify later checks
 144 #####################################################################
 145
 146 if (WANT_MONO OR WANT_QTCLIENT)
 147     set(BUILD_GUI true)
 148 endif()
 149 if (WANT_MONO OR WANT_CORE)
 150     set(BUILD_CORE true)
 151 endif()
 152
 153
 154 # Set up Qt
 155 #####################################################################
 156
 157 # Find package dependencies
 158 #
 159 # Note that you can forcefully disable optional packages
 160 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 161 #####################################################################
 162
 163 if (USE_QT5)
 164     message(STATUS "Building for Qt5...")
 165     set(QT_MIN_VERSION "5.2.0")
 166     add_definitions(-DHAVE_QT5)
 167
 168     find_package(Qt5Core ${QT_MIN_VERSION} QUIET)
 169     set_package_properties(Qt5Core PROPERTIES TYPE REQUIRED
 170         URL "http://qt.digia.com"
 171         DESCRIPTION "contains core functionality for Qt"
 172     )
 173     # find_package without REQUIRED won't check for the version properly; also, older Qt5 versions
 174     # used Qt5Core_VERSION_STRING... let's just make sure here that we bail out here if our Qt5 is not new enough.
 175     if (NOT Qt5Core_VERSION OR Qt5Core_VERSION VERSION_LESS ${QT_MIN_VERSION})
 176         message(FATAL_ERROR "Could NOT find Qt5 >= version ${QT_MIN_VERSION}!")
 177     endif()
 178
 179     find_package(Qt5Network QUIET)
 180     set_package_properties(Qt5Network PROPERTIES TYPE REQUIRED
 181         DESCRIPTION "the network module for Qt5"
 182     )
 183
 184     if (BUILD_GUI)
 185         find_package(Qt5Gui QUIET)
 186         set_package_properties(Qt5Gui PROPERTIES TYPE REQUIRED
 187             DESCRIPTION "the GUI module for Qt5"
 188         )
 189         find_package(Qt5Widgets QUIET)
 190         set_package_properties(Qt5Widgets PROPERTIES TYPE REQUIRED
 191             DESCRIPTION "the widgets module for Qt5"
 192         )
 193
 194         if (NOT WIN32)
 195             find_package(Qt5DBus QUIET)
 196             set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 197                 URL "http://qt.digia.com"
 198                 DESCRIPTION "D-Bus support for Qt5"
 199                 PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 200             )
 201             if (Qt5DBus_FOUND)
 202                 find_package(dbusmenu-qt5 QUIET CONFIG)
 203                 set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 204                     URL "https://launchpad.net/libdbusmenu-qt"
 205                     DESCRIPTION "a library implementing the DBusMenu specification"
 206                     PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 207                 )
 208             endif()
 209         endif()
 210
 211         find_package(Qt5Multimedia QUIET)
 212         set_package_properties(Qt5Multimedia PROPERTIES TYPE RECOMMENDED
 213             URL "http://qt.digia.com"
 214             DESCRIPTION "Multimedia support for Qt5"
 215             PURPOSE     "Required for audio notifications"
 216         )
 217
 218         if (NOT Qt5Multimedia_FOUND)
 219             find_package(Phonon4Qt5 QUIET)
 220             set_package_properties(Phonon4Qt5 PROPERTIES TYPE RECOMMENDED
 221                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 222                 DESCRIPTION "a multimedia abstraction library"
 223                 PURPOSE     "Required for audio notifications"
 224             )
 225         endif()
 226
 227         find_package(LibsnoreQt5 0.7.0 QUIET)
 228         set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
 229             URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 230             DESCRIPTION "a cross-platform notification framework"
 231             PURPOSE     "Enable support for the snorenotify framework"
 232         )
 233         if(LibsnoreQt5_FOUND)
 234             find_package(LibsnoreSettingsQt5)
 235             set_package_properties(LibsnoreSettingsQt5 PROPERTIES TYPE REQUIRED
 236                 URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 237                 DESCRIPTION "a cross-platform notification framework"
 238                 PURPOSE     "Enable support for the snorenotify framework"
 239             )
 240         endif()
 241
 242
 243         if (WITH_WEBKIT)
 244             find_package(Qt5WebKit QUIET)
 245             set_package_properties(Qt5WebKit PROPERTIES TYPE RECOMMENDED
 246                 URL "http://qt.digia.com"
 247                 DESCRIPTION "a WebKit implementation for Qt"
 248                 PURPOSE     "Needed for displaying previews for URLs in chat"
 249             )
 250             if (Qt5WebKit_FOUND)
 251                 find_package(Qt5WebKitWidgets QUIET)
 252                 set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE RECOMMENDED
 253                     URL "http://qt.digia.com"
 254                     DESCRIPTION "widgets for Qt's WebKit implementation"
 255                     PURPOSE     "Needed for displaying previews for URLs in chat"
 256                 )
 257             endif()
 258         endif()
 259
 260         if (WITH_WEBKIT AND Qt5WebKitWidgets_FOUND)
 261             set(HAVE_WEBKIT true)
 262         endif()
 263         add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" HAVE_WEBKIT "Support showing previews for URLs in chat (legacy)")
 264
 265         if (WITH_WEBENGINE)
 266             find_package(Qt5WebEngine QUIET)
 267             set_package_properties(Qt5WebEngine PROPERTIES TYPE RECOMMENDED
 268                 URL "http://qt.digia.com"
 269                 DESCRIPTION "a WebEngine implementation for Qt"
 270                 PURPOSE     "Needed for displaying previews for URLs in chat"
 271             )
 272             if (Qt5WebEngine_FOUND)
 273                 find_package(Qt5WebEngineWidgets QUIET)
 274                 set_package_properties(Qt5WebEngineWidgets PROPERTIES TYPE RECOMMENDED
 275                     URL "http://qt.digia.com"
 276                     DESCRIPTION "widgets for Qt's WebEngine implementation"
 277                     PURPOSE     "Needed for displaying previews for URLs in chat"
 278                 )
 279             endif()
 280         endif()
 281
 282         if (WITH_WEBENGINE AND Qt5WebEngineWidgets_FOUND)
 283             set(HAVE_WEBENGINE true)
 284         endif()
 285         add_feature_info("WITH_WEBENGINE, QtWebEngine and QtWebEngineWidgets modules" HAVE_WEBENGINE "Support showing previews for URLs in chat")
 286
 287         # KDE Frameworks
 288         ################
 289
 290         if (WITH_KDE)
 291             set(ecm_find_type "REQUIRED")
 292         else()
 293             # Even with KDE integration disabled, we optionally use tier1 frameworks if we find them
 294             set(ecm_find_type "RECOMMENDED")
 295         endif()
 296
 297         # extra-cmake-modules
 298         find_package(ECM NO_MODULE QUIET)
 299         set_package_properties(ECM PROPERTIES TYPE ${ecm_find_type}
 300             URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules"
 301             DESCRIPTION "extra modules for CMake, maintained by the KDE project"
 302             PURPOSE     "Required to find KDE Frameworks components"
 303         )
 304
 305         if (ECM_FOUND)
 306             list(APPEND CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
 307             if (WITH_KDE)
 308                 find_package(KF5 COMPONENTS ConfigWidgets CoreAddons Notifications NotifyConfig TextWidgets WidgetsAddons XmlGui QUIET)
 309                 set_package_properties(KF5 PROPERTIES TYPE REQUIRED
 310                     URL "http://www.kde.org"
 311                     DESCRIPTION "KDE Frameworks"
 312                     PURPOSE     "Required for integration into the Plasma desktop"
 313                 )
 314             else(WITH_KDE)
 315                 find_package(KF5Sonnet QUIET)
 316                 set_package_properties(KF5Sonnet PROPERTIES TYPE RECOMMENDED
 317                     URL "http://api.kde.org/frameworks-api/frameworks5-apidocs/sonnet/html"
 318                     DESCRIPTION "framework for providing spell-checking capabilities"
 319                     PURPOSE "Enables spell-checking support in input widgets"
 320                 )
 321             endif(WITH_KDE)
 322         endif(ECM_FOUND)
 323
 324     endif(BUILD_GUI)
 325
 326     if (BUILD_CORE)
 327         find_package(Qt5Script QUIET)
 328         set_package_properties(Qt5Script PROPERTIES TYPE REQUIRED
 329             DESCRIPTION "provides scripting support for Qt5"
 330         )
 331         find_package(Qt5Sql QUIET)
 332         set_package_properties(Qt5Sql PROPERTIES TYPE REQUIRED
 333             DESCRIPTION "the database support module for Qt5"
 334         )
 335
 336         find_package(QCA2-QT5)
 337         set_package_properties(QCA2-QT5 PROPERTIES TYPE RECOMMENDED
 338             URL "https://projects.kde.org/projects/kdesupport/qca"
 339             DESCRIPTION "Qt Cryptographic Architecture"
 340             PURPOSE "Required for encryption support"
 341         )
 342
 343     endif(BUILD_CORE)
 344
 345     find_package(Qt5LinguistTools QUIET)
 346     set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 347                            DESCRIPTION "contains tools for handling translation files"
 348                            PURPOSE "Required for having translations"
 349     )
 350
 351     # Some Qt5 versions do not define a target for lconvert, so we need to find it ourselves
 352     if (Qt5LinguistTools_FOUND)
 353         if (NOT TARGET Qt5::lconvert AND TARGET Qt5::lrelease)
 354             get_target_property(_lrelease_location Qt5::lrelease LOCATION)
 355             get_filename_component(_lrelease_path ${_lrelease_location} PATH)
 356             find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 357         elseif(TARGET Qt5::lconvert AND NOT Qt5_LCONVERT_EXECUTABLE)
 358             # Newer Qt5 versions define the target, but not the Qt5_LCONVERT_EXECUTABLE variable for some reason
 359             get_target_property(QT_LCONVERT_EXECUTABLE Qt5::lconvert LOCATION)
 360         endif()
 361
 362         # Compatibility with the Qt4 variables
 363         set(QT_LRELEASE_EXECUTABLE ${Qt5_LRELEASE_EXECUTABLE})
 364         set(QT_LUPDATE_EXECUTABLE ${Qt5_LUPDATE_EXECUTABLE})
 365         if (Qt5_LCONVERT_EXECUTABLE)
 366             set(QT_LCONVERT_EXECUTABLE ${Qt5_LCONVERT_EXECUTABLE})
 367         endif()
 368     endif()
 369
 370 else(USE_QT5)
 371     message(STATUS "Building for Qt4...")
 372     set(QT_MIN_VERSION "4.8.0")
 373
 374     # Select a Qt installation here, if you don't want to use system Qt
 375     if(QT_PATH)
 376         # FindQt4 will look for the qmake binary in $PATH, so we just prepend QT_PATH
 377         set(ENV{PATH} ${QT_PATH}/bin:$ENV{PATH})
 378     endif()
 379
 380     find_package(Qt4 ${QT_MIN_VERSION} QUIET REQUIRED)
 381
 382     if (BUILD_GUI)
 383         add_feature_info("QtDBus module" QT_QTDBUS_FOUND "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments")
 384         if (QT_QTDBUS_FOUND)
 385             find_package(dbusmenu-qt QUIET CONFIG)
 386             set_package_properties(dbusmenu-qt PROPERTIES TYPE RECOMMENDED
 387                 URL "https://launchpad.net/libdbusmenu-qt"
 388                 DESCRIPTION "a library implementing the DBusMenu specification"
 389                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 390             )
 391         endif()
 392
 393         if (WITH_WEBKIT AND QT_QTWEBKIT_FOUND)
 394             set(HAVE_WEBKIT true)
 395         endif()
 396         add_feature_info("WITH_WEBKIT and QtWebKit module" HAVE_WEBKIT "Support showing previews for URLs in chat")
 397
 398         if (WITH_KDE)
 399             # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 400             set(_cflags ${CMAKE_C_FLAGS})
 401             find_package(KDE4 4.4 QUIET)
 402             set_package_properties(KDE4 PROPERTIES TYPE REQUIRED
 403                 URL "http://www.kde.org"
 404                 DESCRIPTION "a world-class desktop environment"
 405                 PURPOSE "Enables various bits for improving integration with KDE"
 406             )
 407             set(CMAKE_C_FLAGS ${_cflags})
 408
 409         else(WITH_KDE)
 410             find_package(Phonon QUIET)
 411             set_package_properties(Phonon PROPERTIES TYPE RECOMMENDED
 412                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 413                 DESCRIPTION "a multimedia abstraction library"
 414                 PURPOSE     "Required for audio notifications"
 415             )
 416         endif(WITH_KDE)
 417
 418         find_package(IndicateQt QUIET)
 419         set_package_properties(IndicateQt PROPERTIES TYPE OPTIONAL
 420             URL "https://launchpad.net/libindicate-qt/"
 421             DESCRIPTION "a library to raise flags on DBus for other components of the desktop to pick up and visualize"
 422             PURPOSE     "Provides integration into the Ayatana notification system used by e.g. Ubuntu"
 423         )
 424
 425     endif(BUILD_GUI)
 426
 427     if (BUILD_CORE)
 428
 429         find_package(QCA2 QUIET)
 430         set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 431             URL "https://projects.kde.org/projects/kdesupport/qca"
 432             DESCRIPTION "Qt Cryptographic Architecture"
 433             PURPOSE     "Required for encryption support"
 434         )
 435
 436
 437     endif()
 438
 439     # Qt4 does not consider lconvert relevant, so they don't support finding it...
 440     # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 441     if (QT_LRELEASE_EXECUTABLE)
 442         get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 443         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 444     endif()
 445 endif()
 446
 447
 448 # Non-Qt-based packages
 449
 450 # zlib for compression, however we can always fall back to miniz
 451 find_package(ZLIB QUIET)
 452 set_package_properties(ZLIB PROPERTIES TYPE RECOMMENDED
 453     URL "http://www.zlib.net"
 454     DESCRIPTION "a popular compression library"
 455     PURPOSE     "Use the most common library for protocol compression, instead of the bundled miniz implementation"
 456 )
 457
 458
 459 if (NOT WIN32)
 460     # Execinfo is needed for generating backtraces
 461     find_package(ExecInfo QUIET)
 462     set_package_properties(ExecInfo PROPERTIES TYPE OPTIONAL
 463         DESCRIPTION "a library for inspecting backtraces"
 464         PURPOSE "Used for generating backtraces in case of a crash"
 465     )
 466 endif()
 467
 468 # Check for SSL support in Qt
 469 # As there's no easy way to get Qt's configuration in particular for Qt5, let's just compile
 470 # a small test program checking the defines. This works for both Qt4 and Qt5.
 471 cmake_push_check_state(RESET)
 472 set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES} ${Qt5Core_INCLUDE_DIRS})
 473 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Core_EXECUTABLE_COMPILE_FLAGS}")
 474
 475 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 476     set(CMAKE_REQUIRED_FLAGS "-fPIC -DQT_NO_VERSION_TAGGING")
 477 endif()
 478
 479 check_cxx_source_compiles("
 480     #include \"qglobal.h\"
 481     #if defined QT_NO_SSL
 482     #  error \"No SSL support\"
 483     #endif
 484     int main() {}"
 485     HAVE_SSL)
 486 cmake_pop_check_state()
 487
 488 # Additional compile settings
 489 #####################################################################
 490
 491 # This sets -fPIC and friends if required by the installed Qt5 library
 492 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 493     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 494 endif()
 495
 496 # Needed to compile with mingw without kde
 497 if (MINGW AND NOT KDE4_FOUND)
 498     add_definitions(-D_WIN32_WINNT=0x0500)
 499     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 500     # workaround for bug in mingw gcc 4.0
 501     add_definitions(-U__STRICT_ANSI__)
 502 endif()
 503
 504 # Sanitize compiler flags - old versions of KDE set -ansi, which breaks -std=c++11
 505 if (CMAKE_COMPILER_IS_GNUCXX)
 506     string(REPLACE "-ansi" "" CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS})
 507 endif()
 508
 509
 510 # Setup KDE / KDE Frameworks
 511 #####################################################################
 512
 513 # We want to do this up here, so we have the necessary variables and defines set before
 514 # compiling anything
 515
 516 if (KDE4_FOUND)
 517     # We always use external icons for KDE4 support, since we use its iconloader rather than Qt's
 518     set(EMBED_DATA OFF)
 519
 520     # Better have the compile flags global, even for the core, to avoid problems with linking the mono client
 521     add_definitions(-DHAVE_KDE -DHAVE_KDE4 ${KDE4_DEFINITIONS})
 522     set(WITH_KDE4 TRUE)
 523 endif()
 524
 525 if (USE_QT5 AND WITH_KDE)
 526     # If KDE Frameworks are present, they're most probably providing Qt5 integration including icon loading
 527     set(EMBED_DATA OFF)
 528
 529     include(KDEInstallDirs)
 530     include(KDECompilerSettings)
 531     include(KDECMakeSettings)
 532
 533     add_definitions(-DHAVE_KDE -DHAVE_KF5)
 534     set(WITH_KF5 TRUE)
 535 endif()
 536
 537 # This needs to come after setting up KDE integration, so we can use KDE-specific paths
 538 include(QuasselInstallDirs)
 539
 540 # Various config-dependent checks and settings
 541 #####################################################################
 542
 543 if (NOT ZLIB_FOUND)
 544     message(STATUS "zlib NOT found, using bundled miniz for compression")
 545     if (${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 546         message(STATUS "WARNING: This may be slow on 32 bit systems!")
 547     endif()
 548 endif()
 549
 550 if (HAVE_SSL)
 551     add_definitions(-DHAVE_SSL)
 552 endif()
 553 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 554
 555 # Check for syslog support
 556 if (NOT WIN32)
 557     check_include_file(syslog.h HAVE_SYSLOG)
 558     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 559 endif()
 560
 561 add_feature_info("Qt Linguist Tools" QT_LCONVERT_EXECUTABLE "Translation support for Quassel")
 562
 563 if (EMBED_DATA)
 564     message(STATUS "Embedding data files into the binary")
 565 else()
 566     message(STATUS "Installing data files separately")
 567 endif()
 568
 569 if (INDICATEQT_FOUND)
 570     add_definitions(-DXDG_APPS_INSTALL_DIR=${CMAKE_INSTALL_APPDIR})
 571 endif()
 572
 573 if (NOT WIN32)
 574     check_function_exists(umask HAVE_UMASK)
 575     if(HAVE_UMASK)
 576         add_definitions(-DHAVE_UMASK)
 577     endif(HAVE_UMASK)
 578 endif()
 579
 580
 581 # Windows-specific stuff
 582 #####################################################################
 583
 584 if (WIN32)
 585     link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 586     if (MSVC)
 587         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /DNOMINMAX")
 588         set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 589         set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 590         set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 591         link_libraries(Version dwmapi shlwapi)
 592         if (USE_QT5)
 593             set(QT_QTMAIN_LIBRARY Qt5::WinMain)
 594         endif()
 595     endif()
 596     if(HAVE_SSL AND STATIC)
 597         find_package(OpenSSL REQUIRED)
 598         link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 599     endif()
 600 endif()
 601
 602
 603 # Static builds (very much non-portable, so don't use -DSTATIC
 604 # unless you know what you do!)
 605 #####################################################################
 606
 607 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 608     set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 609     link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 610     if (HAVE_SSL)
 611         set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 612     endif()
 613 endif()
 614
 615
 616 # Generate version information from Git
 617 #####################################################################
 618
 619 include(GetGitRevisionDescription)
 620 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 621 git_describe(GIT_DESCRIBE --long)
 622
 623 # If in a Git repo we can get the commit-date from a git command
 624 if (GIT_HEAD)
 625     execute_process(
 626         COMMAND git show -s --format=%ct
 627         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 628         OUTPUT_VARIABLE GIT_COMMIT_DATE
 629         OUTPUT_STRIP_TRAILING_WHITESPACE
 630     )
 631 endif()
 632
 633 # If not in a Git repo try to read GIT_HEAD and GIT_DESCRIBE from
 634 # enviroment
 635 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 636   if (DEFINED ENV{GIT_HEAD})
 637       set(GIT_HEAD $ENV{GIT_HEAD})
 638   endif ()
 639   if (DEFINED ENV{GIT_DESCRIBE})
 640      set(GIT_DESCRIBE $ENV{GIT_DESCRIBE})
 641   endif()
 642 endif()
 643
 644 # Sanitize things if we're not in a Git repo
 645 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 646     set(GIT_HEAD "")
 647     set(GIT_DESCRIBE "")
 648     set(GIT_COMMIT_DATE 0)
 649 endif()
 650
 651 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 652
 653 # Prepare the build
 654 #####################################################################
 655
 656 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 657 set(COMMON_DEPS ${RC_WIN32})
 658 set(CORE_DEPS )
 659 set(CLIENT_DEPS )
 660
 661 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 662 add_subdirectory(data)
 663 add_subdirectory(icons)
 664 add_subdirectory(pics)
 665 add_subdirectory(po)
 666
 667
 668 # Set up and display feature summary
 669 #####################################################################
 670
 671 feature_summary(WHAT ALL
 672                 INCLUDE_QUIET_PACKAGES
 673                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 674 )
 675
 676 # Finally, compile the sources
 677 # We want this after displaying the feature summary to avoid ugly
 678 # CMake backtraces in case a required Qt5 module is missing
 679 #####################################################################
 680
 681 add_subdirectory(src)