CMakeLists.txt

   1 # Main CMake file for building Quassel IRC
   2 #
   3 # See INSTALL for possible CMake options (or read the code, Luke)
   4 #####################################################################
   5
   6 # General setup
   7 #####################################################################
   8
   9 project(QuasselIRC)
  10
  11 # Versions
  12 set(QUASSEL_MAJOR  0)
  13 set(QUASSEL_MINOR 12)
  14 set(QUASSEL_PATCH  4)
  15 set(QUASSEL_VERSION_STRING "0.12.4")
  16
  17 # We want to know CMake's version for debug reasons
  18 message(STATUS "Using CMake ${CMAKE_VERSION}")
  19
  20 # Tell CMake about or own modules
  21 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  22
  23 # General conveniences
  24 set(CMAKE_AUTOMOC ON)
  25 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  26
  27 # Include various CMake modules...
  28 include(CMakePushCheckState)
  29 include(CheckFunctionExists)
  30 include(CheckIncludeFile)
  31 include(CheckCXXSourceCompiles)
  32 include(CMakeDependentOption)
  33 include(FeatureSummary)
  34
  35 # ... and our own stuff
  36 include(QuasselCompileSettings)
  37 include(QuasselMacros)
  38
  39
  40 # Options and variables that can be set on the command line
  41 #####################################################################
  42
  43 # First, choose a Qt version. We support USE_QT4 and USE_QT5; if neither is set, prefer Qt4 for now
  44 option(USE_QT5 "Enable support for Qt5 (disables KDE integration)" OFF)
  45 if (USE_QT4) # takes precedence
  46     set(USE_QT5 OFF)
  47 else()
  48     if (NOT USE_QT5)
  49         set(USE_QT4 ON)
  50     endif()
  51 endif()
  52
  53 # Select the binaries to build
  54 option(WANT_CORE     "Build the core (server) binary"           ON)
  55 option(WANT_QTCLIENT "Build the client-only binary"             ON)
  56 option(WANT_MONO     "Build the monolithic (all-in-one) binary" ON)
  57 add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
  58 add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
  59 add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
  60
  61 # Whether to enable KDE integration (work in progress for Qt5 / KDE Frameworks)
  62 # Note that when building with Qt5, WITH_KDE enables integration with higher-tier KDE frameworks that
  63 # require runtime support. We still optionally make use of certain Tier 1 frameworks even if WITH_KDE
  64 # is disabled.
  65 if (USE_QT4)
  66     option(WITH_KDE "KDE4 integration" OFF)
  67     add_feature_info(WITH_KDE WITH_KDE "Enable KDE4 integration")
  68 else()
  69     option(WITH_KDE "Integration with the KDE Frameworks runtime environment")
  70     add_feature_info(WITH_KDE WITH_KDE "Integrate with the KDE Frameworks runtime environment")
  71 endif()
  72
  73 cmake_dependent_option(WITH_OXYGEN "Install Oxygen icon set (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
  74 if (NOT WITH_KDE)
  75     add_feature_info(WITH_OXYGEN WITH_OXYGEN "Install Oxygen icon set")
  76 endif()
  77
  78 # For this, the feature info is added after we know if QtWebkit is installed
  79 option(WITH_WEBKIT "WebKit support (for link previews) (legacy)" OFF)
  80
  81 # For this, the feature info is added after we know if QtWebEngine is installed
  82 option(WITH_WEBENGINE "WebEngine support (for link previews)" ON)
  83
  84 if (APPLE)
  85     # Notification Center is only available in > 10.8, which is Darwin v12
  86     if (NOT CMAKE_SYSTEM_VERSION VERSION_LESS 12)
  87         option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
  88         add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
  89     endif()
  90 endif()
  91
  92 # Always embed on Windows, OSX or for a static build; never embed when enabling KDE integration
  93 set(EMBED_DEFAULT OFF)
  94 if (STATIC OR WIN32 OR APPLE)
  95     set(EMBED_DEFAULT ON)
  96 endif()
  97 cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
  98                                    "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
  99 if (NOT EMBED_DEFAULT)
 100     add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
 101 endif()
 102
 103 # The following options are not for end-user consumption, so don't list them in the feature summary
 104 cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
 105
 106 # Handle with care
 107 set(QT_PATH "" CACHE PATH "Path to a Qt4 installation to use instead of the system Qt (e.g. for static builds)")
 108
 109 # Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
 110 cmake_dependent_option(STATIC      "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
 111
 112 # For static builds, arbitrary extra libs might need to be linked
 113 # Define a comma-separated list here
 114 # e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
 115 set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
 116 if (LINK_EXTRA)
 117     string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
 118     link_libraries(${LINK_EXTRA})
 119 endif()
 120
 121
 122 # Setup CMake
 123 #####################################################################
 124
 125 if (USE_QT5 AND WITH_KDE)
 126     cmake_minimum_required(VERSION 2.8.12)
 127 else()
 128     cmake_minimum_required(VERSION 2.8.9)
 129 endif()
 130
 131 # Setting COMPILE_DEFINITIONS_<CONFIG> is deprecated since CMake 3.0 in favor of generator expressions.
 132 # These have existed since CMake 2.8.10; until we depend on that, we have to explicitly enable the old policy.
 133 if (POLICY CMP0043)
 134     cmake_policy(SET CMP0043 OLD)
 135 endif()
 136
 137 # Honor visibility settings for all target types
 138 if (POLICY CMP0063)
 139     cmake_policy(SET CMP0063 NEW)
 140 endif()
 141
 142
 143 # Simplify later checks
 144 #####################################################################
 145
 146 if (WANT_MONO OR WANT_QTCLIENT)
 147     set(BUILD_GUI true)
 148 endif()
 149 if (WANT_MONO OR WANT_CORE)
 150     set(BUILD_CORE true)
 151 endif()
 152
 153
 154 # Set up Qt
 155 #####################################################################
 156
 157 # Find package dependencies
 158 #
 159 # Note that you can forcefully disable optional packages
 160 # using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
 161 #####################################################################
 162
 163 if (USE_QT5)
 164     message(STATUS "Building for Qt5...")
 165     set(QT_MIN_VERSION "5.2.0")
 166     add_definitions(-DHAVE_QT5)
 167
 168     find_package(Qt5Core ${QT_MIN_VERSION} QUIET)
 169     set_package_properties(Qt5Core PROPERTIES TYPE REQUIRED
 170         URL "http://qt.digia.com"
 171         DESCRIPTION "contains core functionality for Qt"
 172     )
 173     # find_package without REQUIRED won't check for the version properly; also, older Qt5 versions
 174     # used Qt5Core_VERSION_STRING... let's just make sure here that we bail out here if our Qt5 is not new enough.
 175     if (NOT Qt5Core_VERSION OR Qt5Core_VERSION VERSION_LESS ${QT_MIN_VERSION})
 176         message(FATAL_ERROR "Could NOT find Qt5 >= version ${QT_MIN_VERSION}!")
 177     endif()
 178
 179     find_package(Qt5Network QUIET)
 180     set_package_properties(Qt5Network PROPERTIES TYPE REQUIRED
 181         DESCRIPTION "the network module for Qt5"
 182     )
 183
 184     if (BUILD_GUI)
 185         find_package(Qt5Gui QUIET)
 186         set_package_properties(Qt5Gui PROPERTIES TYPE REQUIRED
 187             DESCRIPTION "the GUI module for Qt5"
 188         )
 189         find_package(Qt5Widgets QUIET)
 190         set_package_properties(Qt5Widgets PROPERTIES TYPE REQUIRED
 191             DESCRIPTION "the widgets module for Qt5"
 192         )
 193
 194         if (NOT WIN32)
 195             find_package(Qt5DBus QUIET)
 196             set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
 197                 URL "http://qt.digia.com"
 198                 DESCRIPTION "D-Bus support for Qt5"
 199                 PURPOSE     "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
 200             )
 201             if (Qt5DBus_FOUND)
 202                 find_package(dbusmenu-qt5 QUIET CONFIG)
 203                 set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
 204                     URL "https://launchpad.net/libdbusmenu-qt"
 205                     DESCRIPTION "a library implementing the DBusMenu specification"
 206                     PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 207                 )
 208             endif()
 209         endif()
 210
 211         find_package(Phonon4Qt5 QUIET)
 212         set_package_properties(Phonon4Qt5 PROPERTIES TYPE RECOMMENDED
 213             URL "https://projects.kde.org/projects/kdesupport/phonon"
 214             DESCRIPTION "a multimedia abstraction library"
 215             PURPOSE     "Required for audio notifications"
 216         )
 217
 218         find_package(LibsnoreQt5 0.7.0 QUIET)
 219         set_package_properties(LibsnoreQt5 PROPERTIES TYPE OPTIONAL
 220             URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 221             DESCRIPTION "a cross-platform notification framework"
 222             PURPOSE     "Enable support for the snorenotify framework"
 223         )
 224         if(LibsnoreQt5_FOUND)
 225             find_package(LibsnoreSettingsQt5)
 226             set_package_properties(LibsnoreSettingsQt5 PROPERTIES TYPE REQUIRED
 227                 URL "https://projects.kde.org/projects/playground/libs/snorenotify"
 228                 DESCRIPTION "a cross-platform notification framework"
 229                 PURPOSE     "Enable support for the snorenotify framework"
 230             )
 231         endif()
 232
 233
 234         if (WITH_WEBKIT)
 235             find_package(Qt5WebKit QUIET)
 236             set_package_properties(Qt5WebKit PROPERTIES TYPE RECOMMENDED
 237                 URL "http://qt.digia.com"
 238                 DESCRIPTION "a WebKit implementation for Qt"
 239                 PURPOSE     "Needed for displaying previews for URLs in chat"
 240             )
 241             if (Qt5WebKit_FOUND)
 242                 find_package(Qt5WebKitWidgets QUIET)
 243                 set_package_properties(Qt5WebKitWidgets PROPERTIES TYPE RECOMMENDED
 244                     URL "http://qt.digia.com"
 245                     DESCRIPTION "widgets for Qt's WebKit implementation"
 246                     PURPOSE     "Needed for displaying previews for URLs in chat"
 247                 )
 248             endif()
 249         endif()
 250
 251         if (WITH_WEBKIT AND Qt5WebKitWidgets_FOUND)
 252             set(HAVE_WEBKIT true)
 253         endif()
 254         add_feature_info("WITH_WEBKIT, QtWebKit and QtWebKitWidgets modules" HAVE_WEBKIT "Support showing previews for URLs in chat (legacy)")
 255
 256         if (WITH_WEBENGINE)
 257             find_package(Qt5WebEngine QUIET)
 258             set_package_properties(Qt5WebEngine PROPERTIES TYPE RECOMMENDED
 259                 URL "http://qt.digia.com"
 260                 DESCRIPTION "a WebEngine implementation for Qt"
 261                 PURPOSE     "Needed for displaying previews for URLs in chat"
 262             )
 263             if (Qt5WebEngine_FOUND)
 264                 find_package(Qt5WebEngineWidgets QUIET)
 265                 set_package_properties(Qt5WebEngineWidgets PROPERTIES TYPE RECOMMENDED
 266                     URL "http://qt.digia.com"
 267                     DESCRIPTION "widgets for Qt's WebEngine implementation"
 268                     PURPOSE     "Needed for displaying previews for URLs in chat"
 269                 )
 270             endif()
 271         endif()
 272
 273         if (WITH_WEBENGINE AND Qt5WebEngineWidgets_FOUND)
 274             set(HAVE_WEBENGINE true)
 275         endif()
 276         add_feature_info("WITH_WEBENGINE, QtWebEngine and QtWebEngineWidgets modules" HAVE_WEBENGINE "Support showing previews for URLs in chat")
 277
 278         # KDE Frameworks
 279         ################
 280
 281         if (WITH_KDE)
 282             set(ecm_find_type "REQUIRED")
 283         else()
 284             # Even with KDE integration disabled, we optionally use tier1 frameworks if we find them
 285             set(ecm_find_type "RECOMMENDED")
 286         endif()
 287
 288         # extra-cmake-modules
 289         find_package(ECM NO_MODULE QUIET)
 290         set_package_properties(ECM PROPERTIES TYPE ${ecm_find_type}
 291             URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules"
 292             DESCRIPTION "extra modules for CMake, maintained by the KDE project"
 293             PURPOSE     "Required to find KDE Frameworks components"
 294         )
 295
 296         if (ECM_FOUND)
 297             list(APPEND CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
 298         endif()
 299
 300         if (WITH_KDE)
 301             find_package(KF5 COMPONENTS ConfigWidgets CoreAddons Notifications NotifyConfig TextWidgets WidgetsAddons XmlGui QUIET)
 302             set_package_properties(KF5 PROPERTIES TYPE REQUIRED
 303                 URL "http://www.kde.org"
 304                 DESCRIPTION "KDE Frameworks"
 305                 PURPOSE     "Required for integration into the Plasma desktop"
 306             )
 307
 308         endif()
 309
 310     endif(BUILD_GUI)
 311
 312     if (BUILD_CORE)
 313         find_package(Qt5Script QUIET)
 314         set_package_properties(Qt5Script PROPERTIES TYPE REQUIRED
 315             DESCRIPTION "provides scripting support for Qt5"
 316         )
 317         find_package(Qt5Sql QUIET)
 318         set_package_properties(Qt5Sql PROPERTIES TYPE REQUIRED
 319             DESCRIPTION "the database support module for Qt5"
 320         )
 321
 322         find_package(QCA2-QT5)
 323         set_package_properties(QCA2-QT5 PROPERTIES TYPE RECOMMENDED
 324             URL "https://projects.kde.org/projects/kdesupport/qca"
 325             DESCRIPTION "Qt Cryptographic Architecture"
 326             PURPOSE "Required for encryption support"
 327         )
 328
 329     endif(BUILD_CORE)
 330
 331     find_package(Qt5LinguistTools QUIET)
 332     set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
 333                            DESCRIPTION "contains tools for handling translation files"
 334                            PURPOSE "Required for having translations"
 335     )
 336
 337     # Some Qt5 versions do not define a target for lconvert, so we need to find it ourselves
 338     if (Qt5LinguistTools_FOUND)
 339         if (NOT TARGET Qt5::lconvert AND TARGET Qt5::lrelease)
 340             get_target_property(_lrelease_location Qt5::lrelease LOCATION)
 341             get_filename_component(_lrelease_path ${_lrelease_location} PATH)
 342             find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 343         elseif(TARGET Qt5::lconvert AND NOT Qt5_LCONVERT_EXECUTABLE)
 344             # Newer Qt5 versions define the target, but not the Qt5_LCONVERT_EXECUTABLE variable for some reason
 345             get_target_property(QT_LCONVERT_EXECUTABLE Qt5::lconvert LOCATION)
 346         endif()
 347
 348         # Compatibility with the Qt4 variables
 349         set(QT_LRELEASE_EXECUTABLE ${Qt5_LRELEASE_EXECUTABLE})
 350         set(QT_LUPDATE_EXECUTABLE ${Qt5_LUPDATE_EXECUTABLE})
 351         if (Qt5_LCONVERT_EXECUTABLE)
 352             set(QT_LCONVERT_EXECUTABLE ${Qt5_LCONVERT_EXECUTABLE})
 353         endif()
 354     endif()
 355
 356 else(USE_QT5)
 357     message(STATUS "Building for Qt4...")
 358     set(QT_MIN_VERSION "4.8.0")
 359
 360     # Select a Qt installation here, if you don't want to use system Qt
 361     if(QT_PATH)
 362         # FindQt4 will look for the qmake binary in $PATH, so we just prepend QT_PATH
 363         set(ENV{PATH} ${QT_PATH}/bin:$ENV{PATH})
 364     endif()
 365
 366     find_package(Qt4 ${QT_MIN_VERSION} QUIET REQUIRED)
 367
 368     if (BUILD_GUI)
 369         add_feature_info("QtDBus module" QT_QTDBUS_FOUND "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments")
 370         if (QT_QTDBUS_FOUND)
 371             find_package(dbusmenu-qt QUIET CONFIG)
 372             set_package_properties(dbusmenu-qt PROPERTIES TYPE RECOMMENDED
 373                 URL "https://launchpad.net/libdbusmenu-qt"
 374                 DESCRIPTION "a library implementing the DBusMenu specification"
 375                 PURPOSE     "Required for having a context menu for the D-Bus-based tray icon"
 376             )
 377         endif()
 378
 379         if (WITH_WEBKIT AND QT_QTWEBKIT_FOUND)
 380             set(HAVE_WEBKIT true)
 381         endif()
 382         add_feature_info("WITH_WEBKIT and QtWebKit module" HAVE_WEBKIT "Support showing previews for URLs in chat")
 383
 384         if (WITH_KDE)
 385             # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
 386             set(_cflags ${CMAKE_C_FLAGS})
 387             find_package(KDE4 4.4 QUIET)
 388             set_package_properties(KDE4 PROPERTIES TYPE REQUIRED
 389                 URL "http://www.kde.org"
 390                 DESCRIPTION "a world-class desktop environment"
 391                 PURPOSE "Enables various bits for improving integration with KDE"
 392             )
 393             set(CMAKE_C_FLAGS ${_cflags})
 394
 395         else(WITH_KDE)
 396             find_package(Phonon QUIET)
 397             set_package_properties(Phonon PROPERTIES TYPE RECOMMENDED
 398                 URL "https://projects.kde.org/projects/kdesupport/phonon"
 399                 DESCRIPTION "a multimedia abstraction library"
 400                 PURPOSE     "Required for audio notifications"
 401             )
 402         endif(WITH_KDE)
 403
 404         find_package(IndicateQt QUIET)
 405         set_package_properties(IndicateQt PROPERTIES TYPE OPTIONAL
 406             URL "https://launchpad.net/libindicate-qt/"
 407             DESCRIPTION "a library to raise flags on DBus for other components of the desktop to pick up and visualize"
 408             PURPOSE     "Provides integration into the Ayatana notification system used by e.g. Ubuntu"
 409         )
 410
 411     endif(BUILD_GUI)
 412
 413     if (BUILD_CORE)
 414
 415         find_package(QCA2 QUIET)
 416         set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
 417             URL "https://projects.kde.org/projects/kdesupport/qca"
 418             DESCRIPTION "Qt Cryptographic Architecture"
 419             PURPOSE     "Required for encryption support"
 420         )
 421
 422
 423     endif()
 424
 425     # Qt4 does not consider lconvert relevant, so they don't support finding it...
 426     # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
 427     if (QT_LRELEASE_EXECUTABLE)
 428         get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
 429         find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
 430     endif()
 431 endif()
 432
 433
 434 # Non-Qt-based packages
 435
 436 # zlib for compression, however we can always fall back to miniz
 437 find_package(ZLIB QUIET)
 438 set_package_properties(ZLIB PROPERTIES TYPE RECOMMENDED
 439     URL "http://www.zlib.net"
 440     DESCRIPTION "a popular compression library"
 441     PURPOSE     "Use the most common library for protocol compression, instead of the bundled miniz implementation"
 442 )
 443
 444
 445 if (NOT WIN32)
 446     # Execinfo is needed for generating backtraces
 447     find_package(ExecInfo QUIET)
 448     set_package_properties(ExecInfo PROPERTIES TYPE OPTIONAL
 449         DESCRIPTION "a library for inspecting backtraces"
 450         PURPOSE "Used for generating backtraces in case of a crash"
 451     )
 452 endif()
 453
 454 # Check for SSL support in Qt
 455 # As there's no easy way to get Qt's configuration in particular for Qt5, let's just compile
 456 # a small test program checking the defines. This works for both Qt4 and Qt5.
 457 cmake_push_check_state(RESET)
 458 set(CMAKE_REQUIRED_INCLUDES ${QT_INCLUDES} ${Qt5Core_INCLUDE_DIRS})
 459 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Core_EXECUTABLE_COMPILE_FLAGS}")
 460
 461 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 462     set(CMAKE_REQUIRED_FLAGS "-fPIC -DQT_NO_VERSION_TAGGING")
 463 endif()
 464
 465 check_cxx_source_compiles("
 466     #include \"qglobal.h\"
 467     #if defined QT_NO_SSL
 468     #  error \"No SSL support\"
 469     #endif
 470     int main() {}"
 471     HAVE_SSL)
 472 cmake_pop_check_state()
 473
 474 # Additional compile settings
 475 #####################################################################
 476
 477 # This sets -fPIC and friends if required by the installed Qt5 library
 478 if (USE_QT5 AND Qt5_POSITION_INDEPENDENT_CODE)
 479     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 480 endif()
 481
 482 # Needed to compile with mingw without kde
 483 if (MINGW AND NOT KDE4_FOUND)
 484     add_definitions(-D_WIN32_WINNT=0x0500)
 485     message(STATUS "Added _WIN32_WINNT=0x0500 definition for MinGW")
 486     # workaround for bug in mingw gcc 4.0
 487     add_definitions(-U__STRICT_ANSI__)
 488 endif()
 489
 490 # Sanitize compiler flags - old versions of KDE set -ansi, which breaks -std=c++11
 491 if (CMAKE_COMPILER_IS_GNUCXX)
 492     string(REPLACE "-ansi" "" CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS})
 493 endif()
 494
 495
 496 # Setup KDE / KDE Frameworks
 497 #####################################################################
 498
 499 # We want to do this up here, so we have the necessary variables and defines set before
 500 # compiling anything
 501
 502 if (KDE4_FOUND)
 503     # We always use external icons for KDE4 support, since we use its iconloader rather than Qt's
 504     set(EMBED_DATA OFF)
 505
 506     # Better have the compile flags global, even for the core, to avoid problems with linking the mono client
 507     add_definitions(-DHAVE_KDE -DHAVE_KDE4 ${KDE4_DEFINITIONS})
 508     set(WITH_KDE4 TRUE)
 509 endif()
 510
 511 if (USE_QT5 AND WITH_KDE)
 512     # If KDE Frameworks are present, they're most probably providing Qt5 integration including icon loading
 513     set(EMBED_DATA OFF)
 514
 515     include(KDEInstallDirs)
 516     include(KDECompilerSettings)
 517     include(KDECMakeSettings)
 518
 519     add_definitions(-DHAVE_KDE -DHAVE_KF5)
 520     set(WITH_KF5 TRUE)
 521 endif()
 522
 523 # This needs to come after setting up KDE integration, so we can use KDE-specific paths
 524 include(QuasselInstallDirs)
 525
 526 # Various config-dependent checks and settings
 527 #####################################################################
 528
 529 if (NOT ZLIB_FOUND)
 530     message(STATUS "zlib NOT found, using bundled miniz for compression")
 531     if (${CMAKE_SIZEOF_VOID_P} EQUAL 4)
 532         message(STATUS "WARNING: This may be slow on 32 bit systems!")
 533     endif()
 534 endif()
 535
 536 if (HAVE_SSL)
 537     add_definitions(-DHAVE_SSL)
 538 endif()
 539 add_feature_info("SSL support in Qt" HAVE_SSL "Use secure network connections")
 540
 541 # Check for syslog support
 542 if (NOT WIN32)
 543     check_include_file(syslog.h HAVE_SYSLOG)
 544     add_feature_info("syslog.h" HAVE_SYSLOG "Provide support for logging to the syslog")
 545 endif()
 546
 547 add_feature_info("Qt Linguist Tools" QT_LCONVERT_EXECUTABLE "Translation support for Quassel")
 548
 549 if (EMBED_DATA)
 550     message(STATUS "Embedding data files into the binary")
 551 else()
 552     message(STATUS "Installing data files separately")
 553 endif()
 554
 555 if (INDICATEQT_FOUND)
 556     add_definitions(-DXDG_APPS_INSTALL_DIR=${CMAKE_INSTALL_APPDIR})
 557 endif()
 558
 559 if (NOT WIN32)
 560     check_function_exists(umask HAVE_UMASK)
 561     if(HAVE_UMASK)
 562         add_definitions(-DHAVE_UMASK)
 563     endif(HAVE_UMASK)
 564 endif()
 565
 566
 567 # Windows-specific stuff
 568 #####################################################################
 569
 570 if (WIN32)
 571     link_libraries(imm32 winmm dbghelp Secur32)  # missing by default :/
 572     if (MSVC)
 573         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /DNOMINMAX")
 574         set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBUGINFO "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt /DEFAULTLIB:msvcrt")
 575         set(CMAKE_EXE_LINKER_FLAGS_DEBUG "/debug /INCREMENTAL:YES /NODEFAULTLIB:libcmt")
 576         set(CMAKE_EXE_LINKER_FLAGS_DEBUGFULL "${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 577         link_libraries(Version dwmapi shlwapi)
 578         if (USE_QT5)
 579             set(QT_QTMAIN_LIBRARY Qt5::WinMain)
 580         endif()
 581     endif()
 582     if(HAVE_SSL AND STATIC)
 583         find_package(OpenSSL REQUIRED)
 584         link_libraries(${OPENSSL_LIBRARIES} ${OPENSSL_EAY_LIBRARIES})
 585     endif()
 586 endif()
 587
 588
 589 # Static builds (very much non-portable, so don't use -DSTATIC
 590 # unless you know what you do!)
 591 #####################################################################
 592
 593 if(STATIC AND CMAKE_COMPILER_IS_GNUCXX)
 594     set(CMAKE_CXX_FLAGS "-static-libgcc ${CMAKE_CXX_FLAGS}")
 595     link_directories(${CMAKE_BINARY_DIR}/staticlibs) # override dynamic libs
 596     if (HAVE_SSL)
 597         set(QUASSEL_SSL_LIBRARIES ssl crypto)  # these miss in static builds
 598     endif()
 599 endif()
 600
 601
 602 # Generate version information from Git
 603 #####################################################################
 604
 605 include(GetGitRevisionDescription)
 606 get_git_head_revision(GIT_REFSPEC GIT_HEAD)
 607 git_describe(GIT_DESCRIBE --long)
 608
 609 # If in a Git repo we can get the commit-date from a git command
 610 if (GIT_HEAD)
 611     execute_process(
 612         COMMAND git show -s --format=%ct
 613         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 614         OUTPUT_VARIABLE GIT_COMMIT_DATE
 615         OUTPUT_STRIP_TRAILING_WHITESPACE
 616     )
 617 endif()
 618
 619 # If not in a Git repo try to read GIT_HEAD and GIT_DESCRIBE from
 620 # enviroment
 621 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 622   if (DEFINED ENV{GIT_HEAD})
 623       set(GIT_HEAD $ENV{GIT_HEAD})
 624   endif ()
 625   if (DEFINED ENV{GIT_DESCRIBE})
 626      set(GIT_DESCRIBE $ENV{GIT_DESCRIBE})
 627   endif()
 628 endif()
 629
 630 # Sanitize things if we're not in a Git repo
 631 if (NOT GIT_HEAD OR NOT GIT_DESCRIBE)
 632     set(GIT_HEAD "")
 633     set(GIT_DESCRIBE "")
 634     set(GIT_COMMIT_DATE 0)
 635 endif()
 636
 637 configure_file(version.h.in ${CMAKE_BINARY_DIR}/version.h @ONLY)
 638
 639 # Prepare the build
 640 #####################################################################
 641
 642 # These variables will be added to the main targets (CORE, QTCLIENT, MONO)
 643 set(COMMON_DEPS ${RC_WIN32})
 644 set(CORE_DEPS )
 645 set(CLIENT_DEPS )
 646
 647 # Add needed subdirs - the order is important, since src needs some vars set by other dirs
 648 add_subdirectory(data)
 649 add_subdirectory(icons)
 650 add_subdirectory(pics)
 651 add_subdirectory(po)
 652
 653
 654 # Set up and display feature summary
 655 #####################################################################
 656
 657 feature_summary(WHAT ALL
 658                 INCLUDE_QUIET_PACKAGES
 659                 FATAL_ON_MISSING_REQUIRED_PACKAGES
 660 )
 661
 662 # Finally, compile the sources
 663 # We want this after displaying the feature summary to avoid ugly
 664 # CMake backtraces in case a required Qt5 module is missing
 665 #####################################################################
 666
 667 add_subdirectory(src)