+# Select the binaries to build
+option(WANT_CORE "Build the core (server) binary" ON)
+option(WANT_QTCLIENT "Build the client-only binary" ON)
+option(WANT_MONO "Build the monolithic (all-in-one) binary" ON)
+add_feature_info(WANT_CORE WANT_CORE "Build the core (server) binary")
+add_feature_info(WANT_QTCLIENT WANT_QTCLIENT "Build the client-only binary (requires a core to connect to)")
+add_feature_info(WANT_MONO WANT_MONO "Build the monolithic (all-in-one) binary")
+
+# Whether to enable KDE integration (pulls in kdelibs and friends as a dependency); requires Qt4 for now
+cmake_dependent_option(WITH_KDE "KDE4 integration" OFF "USE_QT4" OFF)
+add_feature_info(WITH_KDE WITH_KDE "Enable KDE4 integration")
+
+cmake_dependent_option(WITH_OXYGEN "Install Oxygen icon set (usually shipped with KDE)" ON "NOT WITH_KDE" OFF)
+if (NOT WITH_KDE)
+ add_feature_info(WITH_OXYGEN WITH_OXYGEN "Install Oxygen icon set")
+endif()
+
+# For this, the feature info is added after we know if QtWebkit is installed
+option(WITH_WEBKIT "WebKit support (for link previews)" ON)
+
+if (APPLE)
+ # Notification Center is only available in > 10.8, which is Darwin v12
+ if (CMAKE_SYSTEM_VERSION VERSION_GREATER "11.9.9")
+ option(WITH_NOTIFICATION_CENTER "OS X Notification Center support" ON)
+ add_feature_info(WITH_NOTIFICATION_CENTER WITH_NOTIFICATION_CENTER "Use the OS X Notification Center")
+ endif()
+endif()
+
+# Always embed on Windows, OSX or for a static build; never embed when enabling KDE integration
+set(EMBED_DEFAULT OFF)
+if (STATIC OR WIN32 OR APPLE)
+ set(EMBED_DEFAULT ON)
+endif()
+cmake_dependent_option(EMBED_DATA "Embed icons and translations into the binaries instead of installing them" ${EMBED_DEFAULT}
+ "NOT STATIC;NOT WIN32;NOT WITH_KDE" ${EMBED_DEFAULT})
+if (NOT EMBED_DEFAULT)
+ add_feature_info(EMBED_DATA EMBED_DATA "Embed icons and translations in the binaries instead of installing them")
+endif()
+
+# The following options are not for end-user consumption, so don't list them in the feature summary
+cmake_dependent_option(DEPLOY "Add required libs to bundle resources and create a dmg. Note: requires Qt to be built with 10.4u SDK" OFF "APPLE" OFF)
+
+# Handle with care
+set(QT_PATH "" CACHE PATH "Path to a Qt4 installation to use instead of the system Qt (e.g. for static builds)")
+
+# Static builds are not supported and require some manual setup! Don't enable unless you know what you're doing (we don't know either)
+cmake_dependent_option(STATIC "Enable static building (not supported)" OFF "NOT WITH_KDE" OFF)
+
+# For static builds, arbitrary extra libs might need to be linked
+# Define a comma-separated list here
+# e.g. for pgsql, we need -DLINK_EXTRA=pq;crypt
+set(LINK_EXTRA "" CACHE STRING "Semicolon-separated list of libraries to be linked")
+if (LINK_EXTRA)
+ string(REPLACE "," ";" LINK_EXTRA ${LINK_EXTRA})
+ link_libraries(${LINK_EXTRA})
+endif()
+
+
+# Simplify later checks
+#####################################################################
+
+if (WANT_MONO OR WANT_QTCLIENT)
+ set(BUILD_GUI true)
+endif()
+if (WANT_MONO OR WANT_CORE)
+ set(BUILD_CORE true)
+endif()
+
+
+# Set up Qt
+#####################################################################
+
+if (USE_QT5)
+ message(STATUS "Building for Qt5...")
+ set(QT_MIN_VERSION "5.2.0")
+ add_definitions(-DHAVE_QT5)
+else()
+ message(STATUS "Building for Qt4...")
+ if (BUILD_GUI)
+ set(QT_MIN_VERSION "4.6.0")
+ else()
+ set(QT_MIN_VERSION "4.4.0")
+ endif()
+
+ # Select a Qt installation here, if you don't want to use system Qt
+ if(QT_PATH)
+ # FindQt4 will look for the qmake binary in $PATH, so we just prepend QT_PATH
+ set(ENV{PATH} ${QT_PATH}/bin:$ENV{PATH})
+ endif()
+endif()
+
+# Find package dependencies
+#
+# Note that you can forcefully disable optional packages
+# using -DCMAKE_DISABLE_FIND_PACKAGE_<PkgName>=TRUE
+#####################################################################
+
+if(USE_QT5)
+ find_package(Qt5Core ${QT_MIN_VERSION} QUIET)
+ set_package_properties(Qt5Core PROPERTIES TYPE REQUIRED
+ URL "http://qt.digia.com"
+ DESCRIPTION "contains core functionality for Qt"
+ )
+ find_package(Qt5Network QUIET)
+ set_package_properties(Qt5Network PROPERTIES TYPE REQUIRED
+ DESCRIPTION "the network module for Qt5"
+ )
+
+ if (BUILD_GUI)
+ find_package(Qt5Gui QUIET)
+ set_package_properties(Qt5Gui PROPERTIES TYPE REQUIRED
+ DESCRIPTION "the GUI module for Qt5"
+ )
+ find_package(Qt5Widgets QUIET)
+ set_package_properties(Qt5Widgets PROPERTIES TYPE REQUIRED
+ DESCRIPTION "the widgets module for Qt5"
+ )
+
+ find_package(Qt5DBus QUIET)
+ set_package_properties(Qt5DBus PROPERTIES TYPE RECOMMENDED
+ URL "http://qt.digia.com"
+ DESCRIPTION "D-Bus support for Qt5"
+ PURPOSE "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments"
+ )
+ if (Qt5DBus_FOUND)
+ find_package(dbusmenu-qt5 QUIET CONFIG)
+ set_package_properties(dbusmenu-qt5 PROPERTIES TYPE RECOMMENDED
+ URL "https://launchpad.net/libdbusmenu-qt"
+ DESCRIPTION "a library implementing the DBusMenu specification"
+ PURPOSE "Required for having a context menu for the D-Bus-based tray icon"
+ )
+ endif()
+
+ find_package(Phonon4Qt5 QUIET)
+ set_package_properties(Phonon4Qt5 PROPERTIES TYPE RECOMMENDED
+ URL "https://projects.kde.org/projects/kdesupport/phonon"
+ DESCRIPTION "a multimedia abstraction library"
+ PURPOSE "Required for audio notifications"
+ )
+
+ if (WITH_WEBKIT)
+ find_package(Qt5Webkit QUIET)
+ set_package_properties(Qt5Webkit PROPERTIES TYPE RECOMMENDED
+ URL "http://qt.digia.com"
+ DESCRIPTION "a Webkit implementation for Qt"
+ PURPOSE "Needed for displaying previews for URLs in chat"
+ )
+ endif()
+ add_feature_info("WITH_WEBKIT and QtWebkit module" Qt5Webkit_FOUND "Support showing previews for URLs in chat")
+
+ endif(BUILD_GUI)
+ if (BUILD_CORE)
+ find_package(Qt5Script QUIET)
+ set_package_properties(Qt5Script PROPERTIES TYPE REQUIRED
+ DESCRIPTION "provides scripting support for Qt5"
+ )
+ find_package(Qt5Sql QUIET)
+ set_package_properties(Qt5Sql PROPERTIES TYPE REQUIRED
+ DESCRIPTION "the database support module for Qt5"
+ )
+
+ # While QCA2 seems to support Qt5, it is not actually co-installable or distinguishable from the Qt4 version...
+ # In order to avoid linking against the Qt4 version (which is probably the one installed), disable this for now
+ #find_package(QCA2 QUIET)
+ #set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
+ # URL "https://projects.kde.org/projects/kdesupport/qca"
+ # DESCRIPTION "Qt Cryptographic Architecture"
+ # PURPOSE "Required for encryption support"
+ #)
+
+ endif(BUILD_CORE)
+
+ find_package(Qt5LinguistTools QUIET)
+ set_package_properties(Qt5LinguistTools PROPERTIES TYPE RECOMMENDED
+ DESCRIPTION "contains tools for handling translation files"
+ PURPOSE "Required for having translations"
+ )
+ # Qt5 does not define a target for lconvert, so we need to find it ourselves
+ if (Qt5LinguistTools_FOUND)
+ if (NOT TARGET Qt5::lconvert AND TARGET Qt5::lrelease)
+ get_target_property(_lrelease_location Qt5::lrelease LOCATION)
+ get_filename_component(_lrelease_path ${_lrelease_location} PATH)
+ find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt5 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
+ endif()
+ # Compatibility with the Qt4 variables
+ set (QT_LRELEASE_EXECUTABLE ${Qt5_LRELEASE_EXECUTABLE})
+ set (QT_LUPDATE_EXECUTABLE ${Qt5_LUPDATE_EXECUTABLE})
+ endif()
+
+else(USE_QT5)
+ find_package(Qt4 ${QT_MIN_VERSION} QUIET REQUIRED)
+
+ if (BUILD_GUI)
+ add_feature_info("QtDBus module" QT_QTDBUS_FOUND "Needed for supporting D-Bus-based notifications and tray icon, used by most modern desktop environments")
+ if (QT_QTDBUS_FOUND)
+ find_package(dbusmenu-qt QUIET CONFIG)
+ set_package_properties(dbusmenu-qt PROPERTIES TYPE RECOMMENDED
+ URL "https://launchpad.net/libdbusmenu-qt"
+ DESCRIPTION "a library implementing the DBusMenu specification"
+ PURPOSE "Required for having a context menu for the D-Bus-based tray icon"
+ )
+ endif()
+
+ if (WITH_WEBKIT AND QT_QTWEBKIT_FOUND)
+ set(HAVE_WEBKIT true)
+ endif()
+ add_feature_info("WITH_WEBKIT and QtWebkit module" HAVE_WEBKIT "Support showing previews for URLs in chat")
+
+ if (WITH_KDE)
+ # KDE has overzealous CFLAGS making miniz not compile, so save our old flags
+ set(_cflags ${CMAKE_C_FLAGS})
+ find_package(KDE4 4.4 QUIET)
+ set_package_properties(KDE4 PROPERTIES TYPE REQUIRED
+ URL "http://www.kde.org"
+ DESCRIPTION "a world-class desktop environment"
+ PURPOSE "Enables various bits for improving integration with KDE"
+ )
+ set(CMAKE_C_FLAGS ${_cflags})
+
+ else(WITH_KDE)
+ find_package(Phonon QUIET)
+ set_package_properties(Phonon PROPERTIES TYPE RECOMMENDED
+ URL "https://projects.kde.org/projects/kdesupport/phonon"
+ DESCRIPTION "a multimedia abstraction library"
+ PURPOSE "Required for audio notifications"
+ )
+
+ find_package(Libsnore QUIET)
+ set_package_properties(Libsnore PROPERTIES TYPE OPTIONAL
+ URL "https://github.com/TheOneRing/Snorenotify"
+ DESCRIPTION "a cross-platform notification framework"
+ PURPOSE "Enable support for the snorenotify framework"
+ )
+ endif(WITH_KDE)
+
+ find_package(IndicateQt QUIET)
+ set_package_properties(IndicateQt PROPERTIES TYPE OPTIONAL
+ URL "https://launchpad.net/libindicate-qt/"
+ DESCRIPTION "a library to raise flags on DBus for other components of the desktop to pick up and visualize"
+ PURPOSE "Provides integration into the Ayatana notification system used by e.g. Ubuntu"
+ )
+
+ endif(BUILD_GUI)
+ if (BUILD_CORE)
+
+ find_package(QCA2 QUIET)
+ set_package_properties(QCA2 PROPERTIES TYPE RECOMMENDED
+ URL "https://projects.kde.org/projects/kdesupport/qca"
+ DESCRIPTION "Qt Cryptographic Architecture"
+ PURPOSE "Required for encryption support"
+ )
+
+
+ endif()
+
+ # Qt4 does not consider lconvert relevant, so they don't support finding it...
+ # Rather than shipping hacked buildsys files, let's just infer the path from lrelease
+ if (QT_LRELEASE_EXECUTABLE)
+ get_filename_component(_lrelease_path ${QT_LRELEASE_EXECUTABLE} PATH)
+ find_program(QT_LCONVERT_EXECUTABLE NAMES lconvert-qt4 lconvert PATHS ${_lrelease_path} NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
+ endif()
+endif()
+
+
+# Non-Qt-based packages
+
+# zlib for compression, however we can always fall back to miniz
+find_package(ZLIB QUIET)
+set_package_properties(ZLIB PROPERTIES TYPE RECOMMENDED
+ URL "http://www.zlib.net"
+ DESCRIPTION "a popular compression library"
+ PURPOSE "Use the most common library for protocol compression, instead of the bundled miniz implementation"
+)
+
+
+if (NOT WIN32)
+ # Execinfo is needed for generating backtraces
+ find_package(ExecInfo QUIET)
+ set_package_properties(ExecInfo PROPERTIES TYPE OPTIONAL
+ DESCRIPTION "a library for inspecting backtraces"
+ PURPOSE "Used for generating backtraces in case of a crash"
+ )
+endif()
+
+
+# Various checks
+#####################################################################
+
+if (NOT ZLIB_FOUND)
+ message(STATUS "zlib NOT found, using bundled miniz for compression")
+ if (${CMAKE_SIZEOF_VOID_P} EQUAL 4)
+ message(STATUS "WARNING: This may be slow on 32 bit systems!")
+ endif()
+endif()
+
+if (KDE4_FOUND)
+ # We always use external icons for KDE4 support, since we use its iconloader rather than our own
+ set(EMBED_DATA OFF)